C_SrvcDocChangeDocument

@AbapCatalog.sqlViewName: 'CSRVCDOCCD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Documents For Service'
@UI.presentationVariant: [{requestAtLeast: ['ChangeDocObjectClass','SrvcMgmtObjectStatus','TableChangeLogTableFieldName']}]
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@VDM: {
  viewType: #CONSUMPTION
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName:#LOCAL
@Metadata.allowExtensions:true
define view C_SrvcDocChangeDocument
  as select from I_SrvcDocChangeDocument
  association [0..1] to I_ChangeDocChangeIndT  as _ChangeInd on  $projection.ChangeDocChangeType = _ChangeInd.Value
                                                             and _ChangeInd.Language             = $session.system_language
  association [0..1] to I_ChangeDocFieldNamesT as _FieldName on  _FieldName.DatabaseTable = $projection.DatabaseTable
                                                             and _FieldName.Value         = $projection.ChangeDocDatabaseTableField
                                                             and _FieldName.Language      = $session.system_language
  association [0..1] to I_ChangeDocUser        as _User      on  $projection.CreatedByUser = _User.UserName

{
  key ChangeDocument,
  key ChangeDocObject,
  key DatabaseTable,
  key ChangeDocTableKey,
      @ObjectModel.text.element: ['TableChangeLogTableFieldName']
      //@ObjectModel.filter.enabled : false

  key ChangeDocDatabaseTableField,

      //@ObjectModel.text.association: '_ChangeInd'

      @ObjectModel.text.element: ['ChangeDocChangeTypeText']
  key ChangeDocChangeType,

  key SrvcMgmtObjectStatus,


      ChangeDocNewFieldValue,


      ChangeDocPreviousFieldValue,


      ServiceDocChangedDateTime,

      @ObjectModel.text.element: ['CreatedByUserName']
      CreatedByUser,


      @ObjectModel.filter.enabled : false
      ChangeDocObjectDescription,

      @ObjectModel.filter.enabled : false
      ChangeDocObjectClass,

      _FieldName.Text  as TableChangeLogTableFieldName,

      _User.NAME_TEXTC as CreatedByUserName,

      _ChangeInd.Text  as ChangeDocChangeTypeText,

      _ChangeInd,
      _FieldName

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCCHANGEINDT",
"I_CHANGEDOCFIELDNAMEST",
"I_CHANGEDOCUSER",
"I_SRVCDOCCHANGEDOCUMENT"
],
"ASSOCIATED":
[
"I_CHANGEDOCCHANGEINDT",
"I_CHANGEDOCFIELDNAMEST",
"I_CHANGEDOCUSER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/