C_SlsOrdWorkflowEmailTemplate

DDL: C_SLSORDWORKFLOWEMAILTEMPLATE SQL: CSDSOWFEMLTMPL Type: view CONSUMPTION

Sales Order Workflow Email Template

C_SlsOrdWorkflowEmailTemplate is a Consumption CDS View that provides data about "Sales Order Workflow Email Template" in SAP S/4HANA. It reads from 1 data source (I_WorkflowTask) and exposes 20 fields with key field WorkflowTaskInternalID.

1 data source(s) 20 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkflowTask Workflowtask from

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName CSDSOWFEMLTMPL view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
EndUserText.label Sales Order Workflow Email Template view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY WorkflowTaskInternalID I_WorkflowTask WorkflowTaskInternalID
SalesOrder SalesOrder SalesOrder
SalesOrganizationName
SalesOrganization SalesOrder SalesOrganization
DistributionChannelName
DistributionChannel SalesOrder DistributionChannel
DivisionName
OrganizationDivision SalesOrder OrganizationDivision
SalesOrderTypeName
SalesOrderType SalesOrder SalesOrderType
SalesOrderDate SalesOrder SalesOrderDate
SDDocumentReasonText
SDDocumentReason SalesOrder SDDocumentReason
CustomerName _SoldToParty CustomerName
SoldToParty SalesOrder SoldToParty
TransactionCurrency SalesOrder TransactionCurrency
TotalNetAmount SalesOrder TotalNetAmount
WorkflowTaskPriority I_WorkflowTask WorkflowTaskPriority
WorkflowTaskStatus I_WorkflowTask WorkflowTaskStatus
WorkflowTaskURL _WorkflowTaskURL WorkflowTaskURL 
@AbapCatalog.sqlViewName: 'CSDSOWFEMLTMPL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : { 
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@EndUserText.label: 'Sales Order Workflow Email Template'
define view C_SlsOrdWorkflowEmailTemplate as select from   I_WorkflowTask as Workflowtask
  left outer to one join  I_WorkflowTaskApplObject     as WorkflowTaskApplObject       on  WorkflowTaskApplObject.WorkflowTaskInternalID = Workflowtask.WorkflowTaskInternalID
                                                                                       and WorkflowTaskApplObject.SAPObjectNodeRepresentation = 'SalesOrder'
                                                                                       and WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
  left outer to one join I_SalesOrder                  as SalesOrder                   on  SalesOrder.SalesOrder = WorkflowTaskApplObject.TechnicalWrkflwObject
  association[0..1] to   I_SalesOrderType              as _SalesOrderType              on  _SalesOrderType.SalesOrderType = SalesOrder.SalesOrderType
  association[0..1] to   I_WorkflowTaskURL             as _WorkflowTaskURL             on  _WorkflowTaskURL.WorkflowTaskInternalID = Workflowtask.WorkflowTaskInternalID
{
  key Workflowtask.WorkflowTaskInternalID,
      SalesOrder.SalesOrder,
      
      _SalesOrganization._Text[1: Language=$session.system_language ].SalesOrganizationName,
      SalesOrder.SalesOrganization,
      
      _DistributionChannel._Text[1: Language=$session.system_language ].DistributionChannelName,
      SalesOrder.DistributionChannel,
      
      _OrganizationDivision._Text[1: Language=$session.system_language ].DivisionName,
      SalesOrder.OrganizationDivision,
      
      cast(_SalesOrderType._Text[1:Language=$session.system_language].SalesDocumentTypeName as salesdocumenttypename preserving type) as SalesOrderTypeName,
      SalesOrder.SalesOrderType,

      SalesOrder.SalesOrderDate,
      
      _SDDocumentReason._Text[1:Language=$session.system_language].SDDocumentReasonText,
      SalesOrder.SDDocumentReason,
      
      _SoldToParty.CustomerName as CustomerName,
      SalesOrder.SoldToParty,
      
      @Semantics.currencyCode:true
      SalesOrder.TransactionCurrency,
      
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesOrder.TotalNetAmount,
      
      Workflowtask.WorkflowTaskPriority,
      Workflowtask.WorkflowTaskStatus,
      _WorkflowTaskURL.WorkflowTaskURL
}
    
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISION",
"I_DIVISIONTEXT",
"I_SALESDOCUMENTTYPETEXT",
"I_SALESORDER",
"I_SALESORDERTYPE",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONTEXT",
"I_SDDOCUMENTREASON",
"I_SDDOCUMENTREASONTEXT",
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKURL"
],
"ASSOCIATED":
[
"I_SALESORDERTYPE",
"I_WORKFLOWTASKURL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More