C_SlsOrdReqCustomerAddressVH

@EndUserText.label: 'Customer by Sales Area and Address'

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking:#REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XXL,
    dataClass: #MASTER
  },
  dataCategory: #VALUE_HELP,
  representativeKey:'Customer'
}

@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true
@Consumption.ranked: true

define view entity C_SlsOrdReqCustomerAddressVH
  as select from I_CustomerSalesArea
  association [0..*] to I_SalesOrganizationText   as _SalesOrganizationText   on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText as _DistributionChannelText on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText            as _DivisionText            on $projection.Division = _DivisionText.Division
{
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9
      }
      @ObjectModel.text.element:  [ 'CustomerName' ]
      @UI: {
       lineItem: [{ position: 10, importance: #HIGH }],
       selectionField: [{ position: 10 }],
       textArrangement: #TEXT_FIRST }
  key Customer,

      @ObjectModel.text.association: '_SalesOrganizationText'
      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 30, importance: #HIGH }],
       selectionField: [{ position: 30 }],
       textArrangement: #TEXT_FIRST }
  key SalesOrganization,

      @ObjectModel.text.association: '_DistributionChannelText'
      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 40, importance: #HIGH }],
       selectionField: [{ position: 40 }],
       textArrangement: #TEXT_FIRST }
  key DistributionChannel,

      @ObjectModel.text.association: '_DivisionText'
      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 50, importance: #HIGH }],
       selectionField: [{ position: 50 }],
       textArrangement: #TEXT_FIRST }
  key Division,

      @UI.hidden: true
      _Customer.AddressID,

      @Semantics.text: true
      _Customer.CustomerName,
      
      @Semantics.text: true
      @UI.hidden: true      
      _SalesOrganizationText[1:Language = $session.system_language].SalesOrganizationName,
      
      @Semantics.text: true
      @UI.hidden: true      
      _DistributionChannelText[1:Language = $session.system_language].DistributionChannelName,
      
      @Semantics.text: true
      @UI.hidden: true      
      _DivisionText[1:Language = $session.system_language].DivisionName,

      @UI.hidden: true
      @Search: {
         defaultSearchElement: true,
         ranking: #LOW,
         fuzzinessThreshold: 0.8
      }
      _Customer.OrganizationBPName1,

      @UI.hidden: true
      @Search: {
         defaultSearchElement: true,
         ranking: #LOW,
         fuzzinessThreshold: 0.8
      }
      _Customer.OrganizationBPName2,

      @UI: {
      lineItem: [{ position: 80, importance: #LOW }],
      selectionField: [{ position: 80 }]
      }
      @Semantics.address.zipCode:true
      @Search.defaultSearchElement: true
      _Customer._AddressRepresentation.PostalCode,

      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 90, importance: #HIGH }],
       selectionField: [{ position: 90 }] }
      _Customer._AddressRepresentation.CityName,

      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 100, importance: #HIGH }],
       selectionField: [{ position: 100 }] }
      _Customer._AddressRepresentation.Country,

      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 60, importance: #HIGH }],
       selectionField: [{ position: 60 }] }
      _Customer._AddressRepresentation.StreetName,

      @Search.defaultSearchElement: true
      @UI: {
       lineItem: [{ position: 70, importance: #HIGH }],
       selectionField: [{ position: 70 }] }
      _Customer._AddressRepresentation.HouseNumber,

      @Consumption.hidden: true
      //     For DCL Purposes

      AuthorizationGroup,

      @Consumption.hidden: true
      @Semantics.booleanIndicator: true
      IsBusinessPurposeCompleted,

      @Consumption.hidden: true
      _Customer,

      @Consumption.hidden: true
      _SalesOrganizationText,

      @Consumption.hidden: true
      _DistributionChannelText,

      @Consumption.hidden: true
      _DivisionText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS_2",
"I_CUSTOMER",
"I_CUSTOMERSALESAREA",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_SALESORGANIZATIONTEXT"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_SALESORGANIZATIONTEXT"
],
"BASE":
[
"I_CUSTOMERSALESAREA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/