C_SlsInqryForCreateWithRefVH

@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: {
  representativeKey: 'SalesInquiry',
  dataCategory:#VALUE_HELP,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M
  }
}

@AccessControl.privilegedAssociations: ['_CreatedByUser']
@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK

@UI.presentationVariant: [{
  sortOrder: [{ 
    by: 'SalesInquiry',
    direction: #DESC 
  }]
}]

@EndUserText.label: 'Sales Inquiry for Create with Reference'
define view entity C_SlsInqryForCreateWithRefVH
  as select from I_SalesInquiry as SalesInquiry

  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus = _OverallSDProcessStatusText.OverallSDProcessStatus
  association [0..*] to I_OverallSDDocReferenceStatusT as _OverallSDDocReferenceStatusT on $projection.OverallSDDocReferenceStatus = _OverallSDDocReferenceStatusT.OverallSDDocReferenceStatus
  association [0..*] to I_SalesOrganizationText        as _SalesOrganizationText        on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText      as _DistributionChannelText      on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText                 as _DivisionText                 on $projection.OrganizationDivision = _DivisionText.Division
{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key SalesInquiry.SalesInquiry,

      @UI: {
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Sales Organization',
        entity: { name:    'C_SalesDocSalesOrganizationVH',
                  element: 'SalesOrganization' }}]
      @ObjectModel.text.association: '_SalesOrganizationText'
      SalesInquiry.SalesOrganization,


      @UI: {
        selectionField: [{ position: 30 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Distribution Channel',
        entity: { name:    'C_Dischannelvaluehelp',
                  element: 'DistributionChannel' },
        additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT}]
      }]
      @ObjectModel.text.association: '_DistributionChannelText'
      SalesInquiry.DistributionChannel,

      @UI: {
        selectionField: [{ position: 40 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        label: 'Division',
        entity: { name:    'C_OrgDivisionValueHelp',
                  element: 'Division' },
        additionalBinding: [{element: 'SalesOrganization', localElement: 'SalesOrganization', usage: #FILTER_AND_RESULT},
                            {element: 'DistributionChannel',localElement: 'DistributionChannel', usage: #FILTER_AND_RESULT}]
      }]
      @ObjectModel.text.association: '_DivisionText'
      SalesInquiry.OrganizationDivision,

      @UI: {
        selectionField: [{ position: 50 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_SoldToValueHelp',
          element: 'Customer'
        }
      }]
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesInquiry.SoldToParty,

      @Semantics.text:true
      @EndUserText.label : 'Sold-to Party Name'
      @UI.hidden: true
      _SoldToParty.CustomerName as SoldToPartyName,

      @UI: {
        selectionField: [{ position: 60 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      SalesInquiry.PurchaseOrderByCustomer,

      @UI: {
        selectionField: [{ position: 70 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDProcessStatusText'
      SalesInquiry.OverallSDProcessStatus,

      @UI: {
      selectionField: [{ position: 80 }],
      textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDDocReferenceStatus',
          element: 'OverallSDDocReferenceStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDDocReferenceStatusT'
      SalesInquiry.OverallSDDocReferenceStatus,

      @UI: {
      selectionField: [{ position: 90 }],
      textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
      label: 'Created By',
      entity: {
           name: 'C_SalesDocumentUserVH',
           element: 'UserID'
          }
      }]
      @ObjectModel.text.association: '_CreatedByUser'
      SalesInquiry.CreatedByUser,

      //For DCL

      @UI.hidden: true
      SalesInquiry.SalesInquiryType,

      @Consumption.filter.hidden: true
      _SalesOrganizationText,
      @Consumption.filter.hidden: true
      _DistributionChannelText,
      @Consumption.filter.hidden: true
      _DivisionText,
      _CreatedByUser,
      _SoldToParty,
      _OverallSDProcessStatusText,
      _OverallSDDocReferenceStatusT

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_SALESINQUIRY"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_OVERALLSDDOCREFERENCESTATUST",
"I_OVERALLSDPROCESSSTATUSTEXT",
"I_SALESORGANIZATIONTEXT",
"I_USER"
],
"BASE":
[
"I_SALESINQUIRY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/