C_SlsDocWrkFlwRecipientVH

@AbapCatalog: {
   sqlViewName: 'CSLSDOCWFRCPNTVH',
   compiler.compareFilter: true
}
@AccessControl:{
  personalData.blocking: #BLOCKED_DATA_EXCLUDED,
  authorizationCheck: #CHECK
}

@EndUserText.label: 'Sales Document Work Flow Recipient VH'

@Search.searchable: true

@Consumption.ranked: true

@VDM: {
  viewType: #CONSUMPTION
}
@ObjectModel:{
  usageType:{
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M
  },
  representativeKey: 'UserID'
}

define view C_SlsDocWrkFlwRecipientVH
  as select distinct from I_PersonWorkAgrmtOrglDetails as EmployOrgDet

    inner join            I_PersonWorkAgrmtStatus      as _EmployStatDet       on  EmployOrgDet.PersonWorkAgreement =  _EmployStatDet.PersonWorkAgreement
                                                                               and _EmployStatDet.StartDate         <= EmployOrgDet.EndDate
                                                                               and _EmployStatDet.EndDate           >= EmployOrgDet.StartDate

    inner join            I_PersonWorkAgreement_1      as _PersonWorkAgreement on  _EmployStatDet.PersonWorkAgreement= _PersonWorkAgreement.PersonWorkAgreement
    
    inner join            I_WorkforcePerson            as _Employee            on  _PersonWorkAgreement.Person  = _Employee.Person

    inner join            I_User                       as _User                on  _Employee.BusinessPartnerUUID = _User.BusinessPartnerUUID

    inner join            P_SlsDocWrkFlwPotntlApprvr   as _PotntlApprvr        on  _User.UserID = _PotntlApprvr.UserID

{

      @ObjectModel.text.element: 'FullName'
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH
      }
  key _User.UserID                                      as UserID,

      @Semantics.text: true
      case
        when _Employee.PersonFullName is initial
          then _Employee.LastName 
          else _Employee.PersonFullName
        end                                             as FullName,
      
      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.9
      }
      _Employee.LastName,
      
      @UI.hidden: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.9
      }
      _Employee.PersonFullName,
      // For Access control

      @Consumption.hidden: true
      @UI.hidden:true
      _Employee.AuthorizationGroup,
      @Consumption.hidden: true
      @UI.hidden:true
      _Employee.IsBusinessPurposeCompleted,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _Employee.DataController10

}
where
      EmployOrgDet.EndDate               >= $session.system_date
  and _EmployStatDet.WorkAgreementStatus = '1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGRMTORGLDETAILS",
"I_PERSONWORKAGRMTSTATUS",
"I_USER",
"I_WORKFORCEPERSON",
"P_SLSDOCWRKFLWPOTNTLAPPRVR"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/