C_SlsDocItemSupplyIssue

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.semanticKey: ['SalesDocument', 'SalesDocumentItem']
@ObjectModel.representativeKey: 'SalesDocumentItem'

@EndUserText.label: 'Sales Doc Item Supply Issue'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@Search.searchable: false
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.allowExtensions: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CSLSDOCITEMSO08'


define view C_SlsDocItemSupplyIssue

  as select from I_SalesDocumentItemBasic  as Item

    inner join   I_SalesOrderMisgPurgOrder as Issue on  Item.SalesDocument     = Issue.SalesOrder
                                                    and Item.SalesDocumentItem = Issue.SalesOrderItem

  //Extensibility

  association [0..1] to E_SalesDocumentItemBasic as _Extension on  $projection.SalesDocument     = _Extension.SalesDocument
                                                               and $projection.SalesDocumentItem = _Extension.SalesDocumentItem

{
      //Key

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_SalesDocumentStdVH', element: 'SalesDocument' }}]
      @ObjectModel.foreignKey.association: '_SalesDocumentBasic'
  key Item.SalesDocument,
  key cast(Item.SalesDocumentItem as sales_doc_item preserving type)            as SalesDocumentItem,

      ////DueDays

      @DefaultAggregation: #NONE
      Issue.DueDays,

      //Category

      Item.SalesDocumentItemCategory,

      //Product

      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' }}]
      @Consumption.semanticObject: 'Material'
      Item.Product,
      Item.ProductGroup,
      @Consumption.semanticObject: 'Batch'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BatchStdVH',
                     element: 'Batch' },
          additionalBinding: [{ localElement: 'Plant',
                                element: 'Plant' },
                              { localElement: 'Product',
                                element: 'Material' }]
        }]
      Item.Batch,
      Item.Plant,
      Item.MaterialByCustomer,

      //Sales

      Item.SalesDocumentItemText,
      @DefaultAggregation: #NONE
      Item.RequestedQuantity,
      Item.RequestedQuantityUnit,

      @DefaultAggregation: #NONE
      Item.ConfdDelivQtyInOrderQtyUnit,
      Item.OrderQuantityUnit,

      //Pricing

      @DefaultAggregation: #NONE
      Item.NetAmount,
      Item.TransactionCurrency,

      //Shipping

      cast( Item.RequestedDeliveryDate as reqd_deliv_date)                      as RequestedDeliveryDate,

      //Status

      @ObjectModel.foreignKey.association: '_PurchaseConfirmationStatus'
      cast(Item.PurchaseConfirmationStatus as purchaseconfsts preserving type ) as PurchaseConfirmationStatus,
      Item.DeliveryStatus,
      Item.SDProcessStatus,
      Item.OrderRelatedBillingStatus,

      //Criticality

      @UI.hidden: true
      cast(
      case
          when PurchaseConfirmationStatus = ''                     then 9 //no Icon

          when PurchaseConfirmationStatus <> 'C' and DueDays > 0   then 2
          when PurchaseConfirmationStatus <> 'C' and DueDays <= 0  then 1
                                                                   else 3
      end as abap.int1
      )                                                                         as PurchaseConfStatusCriticality,

      //Associations

      @Consumption.filter.hidden: true
      _SalesDocumentBasic,
      @Consumption.filter.hidden: true
      _ItemCategory,
      @Consumption.filter.hidden: true
      _Plant,
      @Consumption.filter.hidden: true
      _Product,
      @Consumption.filter.hidden: true
      _ProductGroup,
      @Consumption.filter.hidden: true
      _PurchaseConfirmationStatus,
      @Consumption.filter.hidden: true
      _DeliveryStatus,
      @Consumption.filter.hidden: true
      _SDProcessStatus,
      @Consumption.filter.hidden: true
      _OrderRelatedBillingStatus,
      @Consumption.filter.hidden: true
      _TransactionCurrency,
      @Consumption.filter.hidden: true
      _RequestedQuantityUnit,
      @Consumption.filter.hidden: true
      _OrderQuantityUnit

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMBASIC",
"I_SALESORDERMISGPURGORDER"
],
"ASSOCIATED":
[
"E_SALESDOCUMENTITEMBASIC",
"I_CURRENCY",
"I_DELIVERYSTATUS",
"I_ORDERRELATEDBILLINGSTATUS",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTGROUP_2",
"I_PURCHASECONFIRMATIONSTATUS",
"I_SALESDOCUMENTBASIC",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SDPROCESSSTATUS",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_SALESDOCUMENTITEMBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/