C_SimulationLogStatusCount

@AbapCatalog.sqlViewName: 'CSIMLNSTSCNT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {dataClass: #TRANSACTIONAL, serviceQuality: #C, sizeCategory: #L}
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Count error, wrng msgs in app log'
@AccessControl.privilegedAssociations: ['_MassUpdtPurgDocsMsgDets', '_MassUpdtCntrlCtrMsgDets', '_MassUpdtCntrlCtrHierMsgDets', '_MassUpdtPHRPRqItmMsgDet']

define view C_SimulationLogStatusCount
  as select from P_SimlnLogSingleSuccess
  association [1..1] to P_PurchasingDocSimulationJob  as _PurchasingDocSimulationJob  on  $projection.SimulationJobUUID = _PurchasingDocSimulationJob.SimulationJobUUID
  association [1..*] to C_MassUpdtPurgDocsMsgDets     as _MassUpdtPurgDocsMsgDets     on  $projection.SimulationJobUUID           = _MassUpdtPurgDocsMsgDets.SimulationJobUUID
                                                                                      and $projection.SystemMessageNumber         = _MassUpdtPurgDocsMsgDets.SystemMessageNumber
                                                                                      and $projection.SystemMessageIdentification = _MassUpdtPurgDocsMsgDets.SystemMessageIdentification
                                                                                      and $projection.SystemMessageType           = _MassUpdtPurgDocsMsgDets.SystemMessageType
                                                                                      and $projection.SystemMessageVariable1      = _MassUpdtPurgDocsMsgDets.SystemMessageVariable1
                                                                                      and $projection.SystemMessageVariable2      = _MassUpdtPurgDocsMsgDets.SystemMessageVariable2
                                                                                      and $projection.SystemMessageVariable3      = _MassUpdtPurgDocsMsgDets.SystemMessageVariable3
                                                                                      and $projection.SystemMessageVariable4      = _MassUpdtPurgDocsMsgDets.SystemMessageVariable4
  association [1..*] to C_MassUpdtCntrlCtrMsgDets     as _MassUpdtCntrlCtrMsgDets     on  $projection.SimulationJobUUID           = _MassUpdtCntrlCtrMsgDets.SimulationJobUUID
                                                                                      and $projection.SystemMessageNumber         = _MassUpdtCntrlCtrMsgDets.SystemMessageNumber
                                                                                      and $projection.SystemMessageIdentification = _MassUpdtCntrlCtrMsgDets.SystemMessageIdentification
                                                                                      and $projection.SystemMessageType           = _MassUpdtCntrlCtrMsgDets.SystemMessageType
                                                                                      and $projection.SystemMessageVariable1      = _MassUpdtCntrlCtrMsgDets.SystemMessageVariable1
                                                                                      and $projection.SystemMessageVariable2      = _MassUpdtCntrlCtrMsgDets.SystemMessageVariable2
                                                                                      and $projection.SystemMessageVariable3      = _MassUpdtCntrlCtrMsgDets.SystemMessageVariable3
                                                                                      and $projection.SystemMessageVariable4      = _MassUpdtCntrlCtrMsgDets.SystemMessageVariable4
  association [1..*] to C_MassUpdtCntrlCtrHierMsgDets as _MassUpdtCntrlCtrHierMsgDets on  $projection.SimulationJobUUID           = _MassUpdtCntrlCtrHierMsgDets.SimulationJobUUID
                                                                                      and $projection.SystemMessageNumber         = _MassUpdtCntrlCtrHierMsgDets.SystemMessageNumber
                                                                                      and $projection.SystemMessageIdentification = _MassUpdtCntrlCtrHierMsgDets.SystemMessageIdentification
                                                                                      and $projection.SystemMessageType           = _MassUpdtCntrlCtrHierMsgDets.SystemMessageType
                                                                                      and $projection.SystemMessageVariable1      = _MassUpdtCntrlCtrHierMsgDets.SystemMessageVariable1
                                                                                      and $projection.SystemMessageVariable2      = _MassUpdtCntrlCtrHierMsgDets.SystemMessageVariable2
                                                                                      and $projection.SystemMessageVariable3      = _MassUpdtCntrlCtrHierMsgDets.SystemMessageVariable3
                                                                                      and $projection.SystemMessageVariable4      = _MassUpdtCntrlCtrHierMsgDets.SystemMessageVariable4
  association [1..*] to C_MassUpdtPHRPRqItmMsgDet     as _MassUpdtPHRPRqItmMsgDet     on  $projection.SimulationJobUUID           = _MassUpdtPHRPRqItmMsgDet.SimulationJobUUID
                                                                                      and $projection.SystemMessageIdentification = _MassUpdtPHRPRqItmMsgDet.SystemMessageIdentification
                                                                                      and $projection.SystemMessageType           = _MassUpdtPHRPRqItmMsgDet.SystemMessageType
                                                                                      and $projection.SystemMessageVariable1      = _MassUpdtPHRPRqItmMsgDet.SystemMessageVariable1
                                                                                      and $projection.SystemMessageVariable2      = _MassUpdtPHRPRqItmMsgDet.SystemMessageVariable2
                                                                                      and $projection.SystemMessageVariable3      = _MassUpdtPHRPRqItmMsgDet.SystemMessageVariable3
                                                                                      and $projection.SystemMessageVariable4      = _MassUpdtPHRPRqItmMsgDet.SystemMessageVariable4
{
    @UI.facet:
    [
        {
            purpose: #STANDARD,
            id: 'MessageDetail',
            position: 1,
            importance: #HIGH,
            label: 'Message Details',
            type: #LINEITEM_REFERENCE,
            targetQualifier: 'MessageDetailTable',
            targetElement: '_MassUpdtPurgDocsMsgDets',
            hidden: #(PurchaseOrderIsNotActive)
        },
        {
            purpose: #STANDARD,
            id: 'CctrMessageDetail',
            position: 2,
            importance: #HIGH,
            label: 'Message Details',
            type: #LINEITEM_REFERENCE,
            targetQualifier: 'CctrMessageDetailTable',
            targetElement: '_MassUpdtCntrlCtrMsgDets',
            hidden: #(CntrlPurContrIsNotActv)
        },
        {
            purpose: #STANDARD,
            id: 'HctrMessageDetail',
            position: 3,
            importance: #HIGH,
            label: 'Message Details',
            type: #LINEITEM_REFERENCE,
            targetQualifier: 'HctrMessageDetailTable',
            targetElement: '_MassUpdtCntrlCtrHierMsgDets',
            hidden: #(CntrlPurContrHierIsNotActv)
        },
        {
            purpose: #STANDARD,
            id: 'CentralPRMessageDetail',
            position: 4,
            importance: #HIGH,
            label: 'Message Details',
            type: #LINEITEM_REFERENCE,
            targetQualifier: 'CentralPRMessageDetailTable',
            targetElement: '_MassUpdtPHRPRqItmMsgDet',
            hidden: #(CntrlPurReqnIsNotActv)
        }
  ]

  key       SimulationJobUUID,
  key       SystemMessageNumber,
  key       SystemMessageIdentification,

            @UI.lineItem: [{
            position: 10,
            qualifier: 'ErrorMessagesTable',
            criticality: 'Criticality',
            criticalityRepresentation: #WITHOUT_ICON}]
            @EndUserText: {
              label: 'Status'
            }
            @ObjectModel.text.element: ['StatusMessageText']
            @UI.textArrangement: #TEXT_ONLY
  key       SystemMessageType,
  key       SystemMessageVariable1,
  key       SystemMessageVariable2,
  key       SystemMessageVariable3,
  key       SystemMessageVariable4,

            @UI.lineItem: [{position: 20 ,qualifier: 'ErrorMessagesTable'}]
            @ObjectModel.sort.enabled: false
            @EndUserText.label: 'Message Text'
            cast('' as bapi_msg)                  as SystemMessageText,

            cast('' as abap.char( 32 ))           as StatusMessageText,

            @UI.hidden: true
            case SystemMessageType
                when 'E'    then    1
                when 'W'    then    2
                when 'S'    then    3
                else 0 end                        as Criticality,

            case SystemMessageType
                when 'E'  then '1'
                when 'W'  then '2'
                when 'S'  then '3'
                else '4' end                      as IndicatorValue,

            @UI.lineItem: [{position: 60 ,qualifier: 'ErrorMessagesTable'}]
            @EndUserText: {
             label: 'Documents'
            }
            @ObjectModel.sort.enabled: false
            cast(count(*)  as srtcm_d_executions) as NumberOfOccurrences,

            @UI.hidden: true
            cast ('' as ebeln)                    as PurchasingDocument,

            _PurchasingDocSimulationJob.PurchasingDocumentCategory,
            _PurchasingDocSimulationJob.PurchasingDocumentSubtype,
            @UI.hidden: true
            _PurchasingDocSimulationJob.CntrlPurContrIsNotActv,
            @UI.hidden: true
            _PurchasingDocSimulationJob.CntrlPurReqnIsNotActv,
            @UI.hidden: true
            _PurchasingDocSimulationJob.CntrlPurContrHierIsNotActv,
            @UI.hidden: true
            _PurchasingDocSimulationJob.PurchaseOrderIsNotActive,
            _MassUpdtPurgDocsMsgDets,
            _MassUpdtCntrlCtrMsgDets,
            _MassUpdtCntrlCtrHierMsgDets,
            _MassUpdtPHRPRqItmMsgDet
}
group by
  SimulationJobUUID,
  SystemMessageNumber,
  SystemMessageIdentification,
  SystemMessageType,
  SystemMessageVariable1,
  SystemMessageVariable2,
  SystemMessageVariable3,
  SystemMessageVariable4,
  _PurchasingDocSimulationJob.PurchasingDocumentCategory,
  _PurchasingDocSimulationJob.PurchasingDocumentSubtype,
  _PurchasingDocSimulationJob.CntrlPurContrIsNotActv,
  _PurchasingDocSimulationJob.CntrlPurReqnIsNotActv,
  _PurchasingDocSimulationJob.CntrlPurContrHierIsNotActv,
  _PurchasingDocSimulationJob.PurchaseOrderIsNotActive
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PURCHASINGDOCSIMULATIONJOB",
"P_SIMLNLOGSINGLESUCCESS"
],
"ASSOCIATED":
[
"C_MASSUPDTCNTRLCTRHIERMSGDETS",
"C_MASSUPDTCNTRLCTRMSGDETS",
"C_MASSUPDTPHRPRQITMMSGDET",
"C_MASSUPDTPURGDOCSMSGDETS",
"P_PURCHASINGDOCSIMULATIONJOB"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/