C_ServiceOrderTypeVH

@AbapCatalog.sqlViewName: 'CSERVORDTYPEVH'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@Search.searchable: true
@EndUserText.label: 'Service Order Type'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #S
@ObjectModel.resultSet.sizeCategory: #XS
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.supportedCapabilities: [#VALUE_HELP_PROVIDER]
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@UI.headerInfo:{
  typeName:       'Service Order Type',
  typeNamePlural: 'Service Order Types'
}
@Consumption.ranked:true
//This view is used for default values in Launchpad

define view C_ServiceOrderTypeVH
  as select distinct from I_ServiceOrderTypeVH as OrderType

    inner join            I_ServiceDocumentType        on  I_ServiceDocumentType.ServiceDocumentType = OrderType.ServiceDocumentType
                                                       and I_ServiceDocumentType.ServiceDocumentTemplateType != 'D'

    inner join            I_SrvcTransactionCopyControl on  I_SrvcTransactionCopyControl.SrvcTargetTransactionType = OrderType.ServiceDocumentType
    //To Remove In House Repair Orders from Service order value help. Check : Predecessor for Repair Order shouldnt be Object Type BUS2000256

                                                       and I_SrvcTransactionCopyControl.ServiceDocPredecessorObjType != 'BUS2000256'
                                                       and I_SrvcTransactionCopyControl.ServiceDocPredecessorObjType != 'BUS2000116'
  //To Remove In House Repair Orders from Service order value help.

    inner join            P_SrvcTransactionType        on  P_SrvcTransactionType.ServiceDocumentType        = OrderType.ServiceDocumentType
                                                       and P_SrvcTransactionType.RefInHouseRepairIsExisting is null

{
      @Search: { defaultSearchElement: true, ranking: #HIGH }
      @EndUserText.label : 'Service Order type'
      @ObjectModel.text.element: ['ServiceOrderTypeName']
      @UI.textArrangement: #TEXT_FIRST
      @Consumption.filter.hidden: true
  key cast( OrderType.ServiceDocumentType  as crms4_srvo_process_type preserving type )          as ServiceOrderType,
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @Consumption.filter.hidden: true
      OrderType.ServiceObjectType,
      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @Consumption.filter.hidden: true
      _ServiceDocumentTypeText[1:Language=$session.system_language].ServiceDocumentTypeName      as ServiceOrderTypeName,
      @Search: { defaultSearchElement: true, ranking: #LOW }
      @Consumption.filter.hidden: true
      _ServiceDocumentTypeText[1:Language=$session.system_language].ServiceDocumentTypeShortName as ServiceOrderTypeShortName,
      @Consumption.filter.hidden: true
      _ServiceDocumentTypeText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTTYPE",
"I_SERVICEDOCUMENTTYPETEXT",
"I_SERVICEORDERTYPEVH",
"I_SRVCTRANSACTIONCOPYCONTROL",
"P_SRVCTRANSACTIONTYPE"
],
"ASSOCIATED":
[
"I_SERVICEDOCUMENTTYPETEXT"
],
"BASE":
[
"I_SERVICEORDERTYPEVH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/