C_ServiceDocumentShipToPartyVH

@AbapCatalog.sqlViewName: 'CSERVDOCSHIPTOVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking :#REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'Value Help for Ship To Party'
@AbapCatalog.preserveKey:true 
@VDM: {
  viewType: #CONSUMPTION
}

@Search: {
  searchable: true
}
@Consumption.ranked:true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey: 'BusinessPartner'
@ObjectModel.dataCategory: #VALUE_HELP
  
define view C_ServiceDocumentShipToPartyVH
  as select from I_BusinessPartner as ShipToParty
{

      @Search.defaultSearchElement: true
      @EndUserText.label: 'Business Partner'
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element:  [ 'BusinessPartnerName' ]
  key ShipToParty.BusinessPartner,
      @Semantics.text:true
      @EndUserText.label: 'Name'
      ShipToParty.BusinessPartnerName,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.FirstName,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.LastName,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.GroupBusinessPartnerName1,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.GroupBusinessPartnerName2,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.OrganizationBPName1,

      @UI.hidden:true
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.8 }
      ShipToParty.OrganizationBPName2,

      @Search.defaultSearchElement: true
      _CurrentDefaultAddress._Address.PostalCode,

      @Search.defaultSearchElement: true
      _CurrentDefaultAddress._Address.CityName,

      @Search.defaultSearchElement: true
      _CurrentDefaultAddress._Address.Country,

      @Search.defaultSearchElement: true
      _CurrentDefaultAddress._Address._Country._Text[1:Language=$session.system_language].CountryName,

      @UI.hidden: true
      AuthorizationGroup,

      @UI.hidden: true
      IsBusinessPurposeCompleted,
      
      
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      DataController1,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController2,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController3,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController4,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      DataController6,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController7,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController8,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController9,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      DataController10
      
     
}
where
  BusinessPartnerIsBlocked != 'X'
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_COUNTRY",
"I_COUNTRYTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/