C_SerialNumbersForGdsMvtVH

@AbapCatalog.sqlViewName: 'CSRNRGDSMVTVH'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #CONSUMPTION

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ObjectModel.dataCategory:#VALUE_HELP

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Value Help for Serial numbers for Goods Movement'

@Search.searchable: true
@Consumption.ranked: true

define view C_SerialNumbersForGdsMvtVH
  as select from I_Equipment
  association [0..1] to I_EquipmentStockSegment as _stocksegment on $projection.Equipment = _stocksegment.Equipment

{
        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Search.ranking: #HIGH
  key   SerialNumber,
  key   Material,
  key   Equipment,
        EquipmentHasStockInformation,
        Batch,
        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Search.ranking: #LOW
        _stocksegment.Plant                                                                       as Plant,
        @Search.defaultSearchElement: true
        @Search.fuzzinessThreshold: 0.8
        @Search.ranking: #LOW
        _stocksegment.StorageLocation                                                             as StorageLocation,

        _stocksegment.InventoryStockType                                                          as InventoryStockType,

        _stocksegment.InventorySpecialStockType                                                   as InventorySpecialStockType,

        _stocksegment.Batch                                                                       as StockIdentifyingBatch,

        _stocksegment.Supplier                                                                    as SpecialStockIdfgSupplier,

        @UI.hidden: true
        @ObjectModel.foreignKey.association: null
        _stocksegment.SalesOrder                                                                  as SalesOrder,
        @UI.hidden: true
        @ObjectModel.foreignKey.association: null
        _stocksegment.SalesOrderItem                                                              as SalesOrderItem,
        @UI.hidden: true
         _stocksegment._WBSElementByInternalKey.WBSElementExternalID                              as WBSElement,

        /* Associations */
        @Consumption.hidden: true
        AuthorizationGroup,

        @Consumption.hidden: true
        Customer,

        @Consumption.hidden: true
        Supplier,

        @Consumption.hidden: true
        _Customer,
        @Consumption.hidden: true
        _Supplier,

        @Consumption.hidden: true
        _Material



}
where
  SerialNumber <> ' ' // AND SerialNumber is not null.

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_EQUIPMENTSTOCKSEGMENT",
"I_WBSELEMENTBYINTERNALKEY"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_EQUIPMENTSTOCKSEGMENT",
"I_MATERIAL",
"I_SUPPLIER"
],
"BASE":
[
"I_EQUIPMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/