C_SchedgAgrmtWorkflow

@AbapCatalog.sqlViewName: 'CSCHAGMRTWF'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Scheduling Agreement Workflow'
@VDM.viewType: #CONSUMPTION
@ObjectModel.createEnabled: false
@ObjectModel.updateEnabled: false
@ObjectModel.deleteEnabled: false
@ObjectModel.semanticKey: ['SchedulingAgreement']
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@UI: { headerInfo: {
        typeName:       'Scheduling Agreement Workflow',
        typeNamePlural: 'Scheduling Agreement Workflows',
        title:          {value: 'SchedulingAgreement'}
        },
        presentationVariant: [{ sortOrder: [{by: 'WrkflwTskCreationUTCDateTime', direction: 'DESC' } ] }]
}
@AbapCatalog.preserveKey:true 
@ClientHandling.algorithm: #SESSION_VARIABLE

define view C_SchedgAgrmtWorkflow
  as select from I_WorkflowTaskLeadingApplObj as Object inner join I_WorkflowTask as WFTask
    on Object.WorkflowTaskInternalID = WFTask.WorkflowTaskInternalID

  //--Association with Scheduling Agreement Header

  association [1..1] to C_Schedgagrmthdr         as _SchedgAgrmtHdr on _SchedgAgrmtHdr.SchedulingAgreement = $projection.SchedulingAgreement
  association [1..1] to I_WorkflowTaskStatusText  as _TaskStatus    on  _TaskStatus.WorkflowTaskStatus = $projection.WorkflowTaskStatus
                                                                    and _TaskStatus.Language = $session.system_language      
{
      @UI.facet: [{ label: 'General Information',
                      id : 'GeneralInfo',
                      purpose: #STANDARD,
                      type: #COLLECTION,
                      position: 10 },
                  {
                    label: 'Basic Data',
                    id: 'BasicData',
                    purpose: #STANDARD,
                    parentId: 'GeneralInfo',
                    type:#IDENTIFICATION_REFERENCE,
                    position: 10
                  }
                      ]

  key cast (substring(Object.TechnicalWrkflwObject,1,10)  as ebeln ) as SchedulingAgreement,
  key WFTask.WorkflowTaskInternalID,
      WFTask.WorkflowTaskStatus,
      @UI:{ lineItem: {position: 10}, identification: {position: 10} }
      @ObjectModel: { readOnly: true }
      @EndUserText.label: 'Workflow Status'
      _TaskStatus.WorkflowTaskStatusDesc,
      @UI:{ lineItem: {position: 20}, identification: {position: 20} }
      @ObjectModel: { readOnly: true }
      @EndUserText.label: 'Workflow Creation Date & Time'
      WFTask.WrkflwTskCreationUTCDateTime,
      @UI:{ lineItem: {position: 30}, identification: {position: 30} }
      @ObjectModel: { readOnly: true }
      @EndUserText.label: 'Workflow End Date & Time'
      WFTask.WrkflwTskCompletionUTCDateTime,      

      _SchedgAgrmtHdr,
      _TaskStatus
}
where
      WFTask.WorkflowTaskType          = 'F'//Parent task of the WF  

  and Object.TechnicalWrkflwObjectType = 'CL_MM_PUR_WF_OBJECT_SA' // SA Leading class

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKFLOWTASK",
"I_WORKFLOWTASKLEADINGAPPLOBJ",
"I_WORKFLOWTASKSTATUSTEXT"
],
"ASSOCIATED":
[
"C_SCHEDGAGRMTHDR",
"I_WORKFLOWTASKSTATUSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/