C_SalesQuotationTypeValueHelp

DDL: C_SALESQUOTATIONTYPEVALUEHELP Type: view CONSUMPTION

Sales Quotation specific document types

C_SalesQuotationTypeValueHelp is a Consumption CDS View that provides data about "Sales Quotation specific document types" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentType) and exposes 3 fields with key field SalesDocumentType.

1 data source(s) 3 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentType _SalesDocumentType from

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName CSALESQTTYPEVH view
AbapCatalog.compiler.compareFilter true view
ClientDependent true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Sales Quotation specific document types view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName Quotation Type view
UI.headerInfo.typeNamePlural Quotation Types view
ObjectModel.representativeKey SalesDocumentType view
Search.searchable true view
Consumption.ranked true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view

Fields (3)

KeyFieldSource TableSource FieldDescription
KEY SalesDocumentType SalesDocumentType Sales Quotation Type
SalesDocumentTypeLangDepdnt
SalesDocumentTypeName 

@AbapCatalog: {
   sqlViewName: 'CSALESQTTYPEVH',
   compiler.compareFilter: true
}

@ClientDependent: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Sales Quotation specific document types'

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S

@VDM: {
  viewType: #CONSUMPTION
}

@UI.headerInfo:{ 
  typeName:       'Quotation Type',
  typeNamePlural: 'Quotation Types'
}
@ObjectModel.representativeKey: 'SalesDocumentType'
@Search.searchable: true

@Consumption: {
  ranked: true,
  valueHelpDefault.fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
}
define view C_SalesQuotationTypeValueHelp as select from I_SalesDocumentType as _SalesDocumentType
{   
    @EndUserText.label : 'Sales Quotation Type'  
    @Search: {
      defaultSearchElement: true,
      ranking: #HIGH
    }
    @UI.lineItem: [{ position: 10, importance: #HIGH }]
    @ObjectModel.text.element: ['SalesDocumentTypeName']
    key SalesDocumentType,

    @UI.hidden: true
    @Search: {
      defaultSearchElement: true,
      ranking: #HIGH
    }
    @UI.textArrangement: #TEXT_SEPARATE
    _SalesDocumentType._SalesDocumentTypeLangDepdnt[1:Language=$session.system_language].SalesDocumentTypeLangDepdnt,

    @Search: {
      defaultSearchElement: true,
      ranking: #LOW,
      fuzzinessThreshold: 0.9
    }
    @UI.lineItem: [{ position: 20, importance: #HIGH }]
    @Semantics.text: true
    _SalesDocumentType._Text[1:Language=$session.system_language].SalesDocumentTypeName
}
where SDDocumentCategory = 'B'                 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTTYPE",
"I_SALESDOCUMENTTYPELANGDEPDNT",
"I_SALESDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More