C_SalesDocumentSchedLineDEX

@AbapCatalog.sqlViewName: 'CSDSDOCSCHEDLNDX'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl:{
    authorizationCheck: #CHECK,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Data Extraction for Sales Document Schedule Lines'
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities:  [ #EXTRACTION_DATA_SOURCE ]


@Analytics: { 
     internalName: #LOCAL,
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
            mapping:[              
                {
                    table: 'vbep', role: #MAIN,
                    viewElement: ['SalesDocument', 'SalesDocumentItem','ScheduleLine'],
                    tableElement: ['vbeln', 'posnr','etenr']
                },                                              
                {
                    table: 'vbap', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['SalesDocument', 'SalesDocumentItem'],
                    tableElement: ['vbeln', 'posnr']
                },
                {
                    table: 'vbak', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['SalesDocument'],
                    tableElement: ['vbeln']},
                {
                    table: 't001', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['BillingCompanyCode'],
                    tableElement: ['bukrs']},
                {
                    table: 'tvko', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['SalesOrganization'],
                    tableElement: ['vkorg']
                }
                                                
            ]
        }
    }
 }


define view C_SalesDocumentSchedLineDEX 


as select from I_SalesDocumentScheduleLine          as ScheduleLine
                                                                                      
       inner join I_SalesDocumentItem               as SalesDocumentItem       on ScheduleLine.SalesDocument = SalesDocumentItem.SalesDocument
                                                                               and ScheduleLine.SalesDocumentItem = SalesDocumentItem.SalesDocumentItem

       inner join I_SalesDocument                   as SalesDocument           on ScheduleLine.SalesDocument = SalesDocument.SalesDocument
       
                                                                                                                                                      
left outer to one join I_CompanyCode                as CompanyCode             on  SalesDocument.BillingCompanyCode = CompanyCode.CompanyCode

//Extensibility 

association [0..1] to E_SalesDocumentItemBasic      as  _ExtensionItem         on  $projection.SalesDocument     = _ExtensionItem.SalesDocument
                                                                               and $projection.SalesDocumentItem = _ExtensionItem.SalesDocumentItem
                                                                              
association [0..1] to E_SalesDocumentBasic          as  _ExtensionHeader       on  $projection.SalesDocument     = _ExtensionHeader.SalesDocument 

{
    // Key

    @ObjectModel.foreignKey.association: '_SalesDocument'
    key ScheduleLine.SalesDocument,
    key ScheduleLine.SalesDocumentItem,
    key ScheduleLine.ScheduleLine,
    
    
    //Admin 

    SalesDocumentItem.CreationDate,
    SalesDocumentItem.CreationTime,
    SalesDocumentItem.LastChangeDate,
    
    
    
    //Category

    SalesDocument.SDDocumentCategory,
    SalesDocument.SalesDocumentType,
    SalesDocumentItem.SalesDocumentItemCategory,
    ScheduleLine.ScheduleLineCategory,

    
    
    //Organization

    SalesDocument.SalesOrganization,
    SalesDocument.DistributionChannel,
    SalesDocumentItem.Division,         
    SalesDocument.SalesGroup,
    SalesDocument.SalesOffice,
    

    //Pricing

    SalesDocument.PricingDate,
    @Semantics.unitOfMeasure: true
    SalesDocumentItem.NetPriceQuantityUnit,
    @Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
    SalesDocumentItem.NetPriceQuantity,
    @Semantics.amount.currencyCode: 'TransactionCurrency'
    SalesDocumentItem.NetPriceAmount,
    SalesDocument.PriceDetnExchangeRate,
    

   //Product

    SalesDocumentItem.Material,
    SalesDocumentItem.MaterialGroup,
    SalesDocumentItem.ProductGroup,
    SalesDocumentItem.Product,
    SalesDocumentItem.ProductHierarchyNode,
    ScheduleLine.ProductAvailabilityDate,
    SalesDocumentItem.InternationalArticleNumber,
    SalesDocumentItem.OriginallyRequestedMaterial,
    SalesDocumentItem.MaterialSubstitutionReason,
    SalesDocumentItem.Batch,
    SalesDocumentItem.AdditionalMaterialGroup1,
    SalesDocumentItem.AdditionalMaterialGroup2,
    SalesDocumentItem.AdditionalMaterialGroup3,
    SalesDocumentItem.AdditionalMaterialGroup4,
    SalesDocumentItem.AdditionalMaterialGroup5,
    
    
    //Sales

    SalesDocument.SoldToParty,
    SalesDocument.AdditionalCustomerGroup1,
    SalesDocument.AdditionalCustomerGroup2,
    SalesDocument.AdditionalCustomerGroup3,
    SalesDocument.AdditionalCustomerGroup4,
    SalesDocument.AdditionalCustomerGroup5,  
    SalesDocument.CustomerGroup,
    SalesDocument.SDDocumentReason,
    ScheduleLine.IsConfirmedDelivSchedLine,
    ScheduleLine.IsRequestedDelivSchedLine,
    @Semantics.unitOfMeasure: true
    SalesDocumentItem.TargetQuantityUnit,
    @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
    ScheduleLine.CorrectedQtyInOrderQtyUnit,
    @Semantics.unitOfMeasure: true
    ScheduleLine.OrderQuantityUnit,
    @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'    
    ScheduleLine.ConfdOrderQtyByMatlAvailCheck,
    @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
    ScheduleLine.ScheduleLineOrderQuantity,
    SalesDocumentItem.TargetToBaseQuantityDnmntr,
    SalesDocumentItem.TargetToBaseQuantityNmrtr,
    SalesDocumentItem.OrderToBaseQuantityDnmntr,
    SalesDocumentItem.OrderToBaseQuantityNmrtr,
    @Semantics.unitOfMeasure: true
    SalesDocumentItem.BaseUnit,
    @Semantics.unitOfMeasure: true
    SalesDocumentItem.ItemVolumeUnit,
    SalesDocumentItem.SalesDocumentRjcnReason,
    @Semantics.unitOfMeasure: true
    SalesDocumentItem.ItemWeightUnit,
    SalesDocument.SalesDistrict,
    ScheduleLine.DeliveryDate,
    SalesDocument.RequestedDeliveryDate,
    SalesDocument.ServicesRenderedDate,
    @Semantics.currencyCode: true
    SalesDocument.StatisticsCurrency,
    
    
    SalesDocumentItem.ShipToParty           as  ShipToParty,
    SalesDocumentItem.PayerParty            as  PayerParty,
    SalesDocumentItem.BillToParty           as  BillToParty,
    
    
    //Shipping

    SalesDocumentItem.Route,
    SalesDocumentItem.Plant,
    SalesDocumentItem.StorageLocation,
    SalesDocumentItem.ShippingPoint,
    SalesDocument.IncotermsClassification,
    SalesDocument.IncotermsTransferLocation,
    SalesDocument.IncotermsVersion,
    SalesDocument.DeliveryBlockReason,
    ScheduleLine.ConfdSchedLineReqdDelivDate,
    ScheduleLine.ConfirmedDeliveryDate,
    @Semantics.quantity.unitOfMeasure: 'BaseUnit'
    ScheduleLine.MRPRequiredQuantityInBaseUnit,
    ScheduleLine.DelivBlockReasonForSchedLine,
    ScheduleLine.LoadingDate,
    ScheduleLine.TransportationPlanningDate,
    ScheduleLine.GoodsIssueDate,
    
    
    //Quotation

    SalesDocumentItem.ItemOrderProbabilityInPercent,
    SalesDocument.BindingPeriodValidityStartDate,
    SalesDocument.BindingPeriodValidityEndDate,

    
    
    //Billing

    SalesDocument.BillingCompanyCode,
    SalesDocument.BillingDocumentDate,
    SalesDocumentItem.ItemBillingBlockReason,
    
    
    //Accounting   

    SalesDocument.ExchangeRateType,
    SalesDocument.ExchangeRateDate,
    CompanyCode.FiscalYearVariant,
    @Semantics.currencyCode: true
    SalesDocumentItem.TransactionCurrency,
    SalesDocument.CustomerAccountAssignmentGroup,
 
    
    //Reference

    SalesDocumentItem.ReferenceSDDocumentCategory,
    
    
    
    //Status

    SalesDocumentItem.SDDocumentRejectionStatus,
    SalesDocumentItem.ItemDeliveryIncompletionStatus,
    SalesDocumentItem.ItemGeneralIncompletionStatus,
    SalesDocumentItem.ItemBillingIncompletionStatus,
    SalesDocumentItem.PricingIncompletionStatus,
    
    

    
    //Association

    _SalesDocument
    
    
} 
where
        SalesDocument.SDDocumentCategory = 'A' // Inquiry

    or  SalesDocument.SDDocumentCategory = 'B' // Quotation

    or  SalesDocument.SDDocumentCategory = 'C' // Order

    or  SalesDocument.SDDocumentCategory = 'G' // Contract

    or  SalesDocument.SDDocumentCategory = 'H' // Returns

    or  SalesDocument.SDDocumentCategory = 'I' // Order w/o charge

    or  SalesDocument.SDDocumentCategory = 'K' // Credit Memo Request

    or  SalesDocument.SDDocumentCategory = 'L' // Debit Memo Request

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESDOCUMENTSCHEDULELINE"
],
"ASSOCIATED":
[
"E_SALESDOCUMENTBASIC",
"E_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENT"
],
"BASE":
[
"I_SALESDOCUMENTSCHEDULELINE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/