C_SalesDocOutputRequestItemTP

@EndUserText.label: 'Output Request Item for Sales Document'
@AccessControl: { authorizationCheck: #PRIVILEGED_ONLY,
                  privilegedAssociations: [ '_OutputRequest','_CreatedByUser', '_LastChangedByUser' ]}


@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #NONE,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
@ObjectModel: {
   modelingPattern:       #TRANSACTIONAL_QUERY,
   supportedCapabilities: [#TRANSACTIONAL_PROVIDER],
   usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED },
    query.implementedBy: 'ABAP:CL_SD_OUTPREQ_RAP_STICKY_QRY'
}

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@Feature: 'SW:Q2C_SLS_DOC_OUTPUT_CONTROL'

define view entity C_SalesDocOutputRequestItemTP
  as projection on R_OutputRequestItemTP as OutputRequestItem

  association [0..1] to I_User                       as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to C_PartnerFunctionUnconverted as _PartnerFunction   on $projection.RecipientRole = _PartnerFunction.PartnerFunction

{

  key     OutputRequestItem.OutputRequestItemUUID,
          OutputRequestItem.OutputControlApplObjectType,
          OutputRequestItem.OutputControlApplicationObject,
          OutputRequestItem.OutputRequestItem,
          OutputRequestItem.OutputRequestUUID,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_APOC_ITM_STD_MIME_TYPE'
  virtual MimeType                       : w3conttype,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_APOC_ITM_STD_BIN_DATA'
          @Semantics.largeObject.contentDispositionPreference: #INLINE
          @Semantics.largeObject.mimeType: 'MimeType'
  virtual OutputBinaryData               : abap.rawstring,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_APOC_ITM_STD_BIN_DATA_AVAIL'
  virtual OutputBinaryDataIsNotAvailable : boole_d,

          @ObjectModel.foreignKey.association: '_OutputRequestItemStatus'
          OutputRequestItem.OutputRequestItemStatus,

          @ObjectModel.foreignKey.association: '_DispatchTime'
          OutputRequestItem.DispatchTime,

          @ObjectModel.foreignKey.association: '_OutputDocumentType'
          OutputRequestItem.OutputDocumentType,

          @ObjectModel.foreignKey.association: '_OutputChannel'
          OutputRequestItem.OutputChannel,

          @ObjectModel.foreignKey.association: '_PartnerFunction'
          OutputRequestItem.RecipientRole,
          OutputRequestItem.Recipient,

          @ObjectModel.foreignKey.association: '_FormTemplateCountry'
          OutputRequestItem.FormTemplateCountry,
          @ObjectModel.foreignKey.association: '_FormTemplateLanguage'
          OutputRequestItem.FormTemplateLanguage,
          OutputRequestItem.FormTemplate,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
          @Consumption.hidden: true
  virtual IsChangeDocument_H             : rap_cp_odata_value_control,

          @OData.property.valueControl: 'IsChangeDocument_H'
          OutputRequestItem.IsChangeDocument,
          OutputRequestItem.CreationDateTime,
          @ObjectModel.foreignKey.association: '_CreatedByUser'
          OutputRequestItem.CreatedByUser,
          OutputRequestItem.LastChangeDateTime,
          @ObjectModel.foreignKey.association: '_LastChangedByUser'
          OutputRequestItem.LastChangedByUser,

          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _OutputRequest : redirected to parent C_SalesDocumentOutputRequestTP,

          /* Associations */
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._OutputRequestItemStatus,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._DispatchTime,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._OutputDocumentType,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._OutputChannel,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _PartnerFunction,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _CreatedByUser,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _LastChangedByUser,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._FormTemplateCountry,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          OutputRequestItem._FormTemplateLanguage


}
where
  OutputRequestItem.OutputControlApplObjectType = 'SALES_DOCUMENT'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_OUTPUTREQUESTITEMTP"
],
"ASSOCIATED":
[
"C_PARTNERFUNCTIONUNCONVERTED",
"C_SALESDOCUMENTOUTPUTREQUESTTP",
"I_COUNTRY",
"I_DISPATCHTIME",
"I_LANGUAGE",
"I_OUTPUTCHANNEL",
"I_OUTPUTCONTROLOUTPUTTYPE",
"I_OUTPUTREQUESTITEMSTATUS",
"I_USER",
"R_OUTPUTREQUESTTP"
],
"BASE":
[
"R_OUTPUTREQUESTITEMTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/