C_SalesContrForCreateWithRefVH

@VDM: {
  viewType: #CONSUMPTION
}

@ObjectModel: {
  dataCategory:#VALUE_HELP,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #M
  }
}

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK

@UI.presentationVariant: [{
  sortOrder: [{ 
    by: 'SalesContract',
    direction: #DESC 
  }]
}]

@EndUserText.label: 'Sales Contract for Create Wth Reference'
define view entity C_SalesContrForCreateWithRefVH  
  as select from I_SalesContract as SalesContract
  
  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus      = _OverallSDProcessStatusText.OverallSDProcessStatus
  association [0..*] to I_OverallSDDocReferenceStatusT as _OverallSDDocReferenceStatusT on $projection.OverallSDDocReferenceStatus = _OverallSDDocReferenceStatusT.OverallSDDocReferenceStatus
  
{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH 
      }
  key SalesContract.SalesContract,
  
      @UI: {
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_SoldToValueHelp',
          element: 'Customer'
        }
      }]
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesContract.SoldToParty,

      @Semantics.text: true
      @EndUserText.label : 'Sold-to Party Name'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSCONTR_UI_PARTNER_UTIL'
      cast('' as ad_namtext )                                                        as SoldToPartyName,
             
      @UI: {
        selectionField: [{ position: 30 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM 
      }
      SalesContract.PurchaseOrderByCustomer,
      
      @UI: {
        selectionField: [{ position: 40 }]
      }
      SalesContract.SalesContractValidityStartDate,
      
      @UI: {
        selectionField: [{ position: 50 }]
      }
      SalesContract.SalesContractValidityEndDate,
      
      @UI: {
        selectionField: [{ position: 60 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDProcessStatusText'
      SalesContract.OverallSDProcessStatus,
      
      @UI: {
        selectionField: [{ position: 70 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDDocReferenceStatus',
          element: 'OverallSDDocReferenceStatus'
        }
      }]
      @ObjectModel.text.association: '_OverallSDDocReferenceStatusT'
      SalesContract.OverallSDDocReferenceStatus,
    
      //Properties for DCL

      @UI.hidden: true
      SalesContract.SalesContractType,
      @UI.hidden: true
      SalesContract.SalesOrganization,
      @UI.hidden: true
      SalesContract.DistributionChannel,
      @UI.hidden: true
      SalesContract.OrganizationDivision,
      
      //Associations

      @Consumption.filter.hidden: true
      _OverallSDProcessStatusText,
      @Consumption.filter.hidden: true
      _OverallSDDocReferenceStatusT
} 
 where 
   SalesDocApprovalStatus        <> 'A' and  // In Approval

   SalesDocApprovalStatus        <> 'C' and  // Rejected

   SalesDocApprovalStatus        <> 'D'      // To Be Reworked

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESCONTRACT"
],
"ASSOCIATED":
[
"I_OVERALLSDDOCREFERENCESTATUST",
"I_OVERALLSDPROCESSSTATUSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/