C_SFOAssldNonTrcblComponent

@Metadata.allowExtensions: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}

@VDM.viewType: #CONSUMPTION

@UI.headerInfo.typeName: 'Non-Traceable Component'
@UI.headerInfo.typeNamePlural: 'Non-Traceable Components'
@UI.headerInfo.title.label: 'Non-Traceable Component'
@UI.presentationVariant:[
  {
   sortOrder:[{by: 'MaterialName', direction: #ASC}],
   requestAtLeast: ['EffectivityParameterVariant','Assembly']
  }]
@UI.textArrangement:#TEXT_LAST
@UI.lineItem:[{criticality: 'ComponentAssemblyCriticality'}]

@EndUserText.label: 'SFO assembled non traceable component'
define view entity C_SFOAssldNonTrcblComponent
  as select from P_SFONonTrcblComponentAssembly as ass
  association [0..1] to I_Plant                     as _Plant                       on  $projection.Plant = _Plant.Plant
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance          on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance as _OperationActivityInstance   on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  ----Extension Association
  association [0..1] to E_BillOfMaterialItemTP      as _BillOfMaterialItemExtension on  $projection.BillOfMaterialCategory     = _BillOfMaterialItemExtension.BillOfMaterialCategory
                                                                                    and $projection.BillOfMaterialInternalID   = _BillOfMaterialItemExtension.BillOfMaterial
                                                                                    and $projection.BOMItem                    = _BillOfMaterialItemExtension.BillOfMaterialItemNodeNumber
                                                                                    and $projection.BOMItemInternalChangeCount = _BillOfMaterialItemExtension.BOMItemInternalChangeCount

{
      @UI.hidden:true
  key ass.Reservation                                                                        as Reservation,
      @UI.hidden:true
  key ass.ReservationItem                                                                    as ReservationItem,
      @UI.hidden:true
  key ass.RecordType                                                                         as RecordType,
      @UI.hidden:true
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance' } } ]
  key ass.OpActyNtwkInstance                                                                 as OpActyNtwkInstance,
      @UI.hidden:true
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyInstceStdVH', element: 'OpActyNtwkElement' } } ]
  key ass.OpActyNtwkElement                                                                  as OpActyNtwkElement,
      @UI:{
       lineItem:[{position:40}]}       -- defines default columns of the table on ObjectList
      ass.Batch                                                                              as Batch,
      @UI:{
       lineItem:[{position:10}]}       -- defines default columns of the table on ObjectList
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @ObjectModel.text.element:['MaterialName']
      ass.Material                                                                           as Material,
      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_Plant'
      ass.Plant                                                                              as Plant,

      ass.BillOfMaterialItemNumber                                                           as BillOfMaterialItemNumber,
      @UI.hidden: true
      ass.BillOfMaterialCategory                                                             as BillOfMaterialCategory,
      @UI.hidden: true
      ass.BillOfMaterialInternalID                                                           as BillOfMaterialInternalID,
      @UI.hidden: true
      ass.BOMItem                                                                            as BOMItem,
      @UI.hidden: true
      ass.BOMItemInternalChangeCount                                                         as BOMItemInternalChangeCount,
      @UI.hidden: true
      ass.BillOfMaterialVariant                                                              as BillOfMaterialVariant,
      @UI.hidden: true
      ass.BillOfMaterialVersion                                                              as BillOfMaterialVersion,
      @UI.hidden: true
      ass.InheritedNodeNumberForBOMItem                                                      as InheritedNodeNumberForBOMItem,
      @UI.hidden: true
      ass.InheritedNodeNumberVersionBOM                                                      as InheritedNodeNumberVersionBOM,
      @UI.hidden: true
      ass.Assembly                                                                           as Assembly,

      cast(coalesce(ass._MfgBOMItemWithPhantomHier.MfgBOMItemIsPhantomChild, '')
        as mpe_bom_phantom_child preserving type)                                            as MfgBOMItemIsPhantomChild,

      @UI.hidden: true
      ass._Material._Text[1: Language=$session.system_language].MaterialName                 as MaterialName,

      --Quantities
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @UI:{
       lineItem:[{position:60}]}       -- defines default columns of the table on ObjectList
      ass.RequiredQuantity                                                                   as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      ass.RequiredQuantityInBaseUnit                                                         as RequiredQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @UI:{
       lineItem:[{position:50}]}       -- defines default columns of the table on ObjectList
      ass.MaterialComponentQuantity                                                          as MaterialComponentQuantity,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      ass.ResvnItmWithdrawnQtyInBaseUnit                                                     as ResvnItmWithdrawnQtyInBaseUnit,
      @UI.hidden:true
      ass.MaterialBaseUnit                                                                   as MaterialBaseUnit,
      @UI.hidden:true
      ass.EntryUnit                                                                          as EntryUnit,
      @UI.hidden:true
      ass.OrderInternalID                                                                    as OrderInternalID,
      @UI.hidden:true
      ass.OrderOperationInternalID                                                           as OrderOperationInternalID,

      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_BATCHBYSUPPLIER_VE'
      }
      cast('               ' as lichn preserving type )                                      as BatchBySupplier,

      -- Variable-Size Item Fields
      @UI.hidden: true
      ass.MaterialCompIsVariableSized                                                        as MaterialCompIsVariableSized,
      @UI.hidden: true
      ass.FormulaKey                                                                         as FormulaKey,
      @UI.hidden: true
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      ass.VariableSizeDimension1                                                             as VariableSizeDimension1,
      @UI.hidden: true
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      ass.VariableSizeDimension2                                                             as VariableSizeDimension2,
      @UI.hidden: true
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      ass.VariableSizeDimension3                                                             as VariableSizeDimension3,
      @UI.hidden: true
      ass.VariableSizeDimensionUnit                                                          as VariableSizeDimensionUnit,
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_VSI_FRMTD_FORMULA_VE'
      }
      cast('' as mpe_vsi_formatted_formula)                                                  as VarblSizeCompFrmtdFormulaVal,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      ass.VariableSizeComponentQuantity                                                      as VariableSizeComponentQuantity,
      @UI.hidden: true
      ass.VariableSizeComponentUnit                                                          as VariableSizeComponentUnit,

      cast(ass.ManufacturingOrder as aufnr preserving type)                                  as ManufacturingOrder,

      --Operation Fields
      @ObjectModel.text.element:['MfgOrderOperationText']
      ass.ManufacturingOrderOperation                                                        as ManufacturingOrderOperation,

      @UI.hidden: true
      @Semantics.text: true
      ass.MfgOrderOperationText                                                              as MfgOrderOperationText,

      -- OA Details Fields
      @ObjectModel.text.element:['OperationActivityName']
      cast(ass.OpActyNtwkElementExternalID  as mpe_oa_number_ext preserving type)            as OpActyNtwkElementExternalID,

      @UI.hidden: true
      @Semantics.text: true
      ass._OperationActivityText[1: Language=$session.system_language].OperationActivityName as OperationActivityName,

      @UI.hidden: true
      case
                when ass.Reservation = '0000000000' then 1
                else 0
                end                                                                          as ComponentAssemblyCriticality,

      @UI.hidden: true
      ass.MatlCompAssembleControl,
      @UI:{
       lineItem:[{position:20}]} -- defines default columns of the table on ObjectList
      cast(ass._MatlCompAssembleControl._Text[1: Language=$session.system_language].MatlCompAssembleControlName
        as mpe_assembly_type_name preserving type )                                          as MatlCompAssembleControlName,

      @ObjectModel.text.element:['BillOfMaterialItemCategoryDesc']
      ass.BOMItemCategory,
      @UI.hidden: true
      ass._BOMItemCategory._ItemCategoryT[1: Language=$session.system_language].BillOfMaterialItemCategoryDesc,

      @UI.hidden: true
      ass.EffectivityParameterVariant                                                        as EffectivityParameterVariant,

      ass._Batch,
      ass._Material,
      _Plant,
      _OpActyNtwkInstance,
      _OperationActivityInstance
      //      _Genealogy

}
where
      ass.MaterialComponentQuantity > 0
  and ass.DebitCreditCode           = 'H'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITEMCATEGORYTEXT",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MATLCOMPASSEMBLECONTROL",
"I_MATLCOMPASSEMBLECONTROLTEXT",
"I_MFGBOMITEMWITHPHANTOMHIER",
"I_OPERATIONACTIVITYTEXT",
"P_SFONONTRCBLCOMPONENTASSEMBLY"
],
"ASSOCIATED":
[
"I_BATCH",
"I_MATERIAL",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_PLANT"
],
"BASE":
[
"P_SFONONTRCBLCOMPONENTASSEMBLY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/