C_RunOverheadWBSElement

@AbapCatalog.sqlViewName: 'COVHDWBSELEMENT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #INHERITED
@EndUserText.label: 'Overhead Calculation WBS Element'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Search.searchable: true
@VDM.viewType: #CONSUMPTION

@UI.headerInfo: {
  typeName: 'WBS Element'
  ,
  typeNamePlural: 'WBS Elements'
  ,
  title: { value: 'WBSElementExternalID' }
  ,
  description: {  value: 'WBSDescription' }
  }

@UI.presentationVariant: [{
  text: 'WBS Element',
  qualifier: 'VAR_WBS'
}]
define view C_RunOverheadWBSElement
  as select from I_WBSElementBasicData as _WBSElementBasicData
{
      @UI.hidden: true
  key _WBSElementBasicData.WBSElementInternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'WBSElement'
      @UI.lineItem: [{ position: 10 , importance: #MEDIUM }]
      @UI.textArrangement: #TEXT_SEPARATE
      WBSElementExternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.7
      }
      @UI.lineItem: { position: 20 }
      WBSDescription,

      @UI.hidden: true      
      cast( _WBSElementBasicData.ProjectInternalID as ps_s4_proj_pspnr preserving type ) as ProjectInternalID,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'Project'
      @UI.lineItem: { position: 30 }
      @ObjectModel.text.element: 'ProjectDescription'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @UI.textArrangement: #TEXT_LAST
      cast (_Project.ProjectExternalID as cats_cpr_extid ) as ProjectExternalID,
      _Project.ProjectDescription,

      @ObjectModel.text.association: '_CompanyCode'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @Search: {
        defaultSearchElement: true,
        ranking: #MEDIUM,
        fuzzinessThreshold: 0.9
      }
      @Consumption.semanticObject: 'CompanyCode'
      @Consumption.filter.mandatory: true
      @UI.lineItem: { position: 40 }
      @UI.textArrangement: #TEXT_LAST
      CompanyCode,

      @UI.hidden: true
      CostCenter,

      @UI.hidden: true
      ProfitCenter,

      @UI.hidden: true
      ControllingArea,

      @UI.hidden: true
      WBSElementObject,

      /* association */
      _CompanyCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_COMPANYCODE"
],
"BASE":
[
"I_WBSELEMENTBASICDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/