C_ReworkBOOVersionDefectCode

@AbapCatalog.sqlViewName: 'CBOOVDEF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:
{
    serviceQuality: #C,
    sizeCategory:   #L,
    dataClass:      #MIXED
}
@EndUserText.label: 'Rework Version BOO Defect Code Assgnmnt'
--@Search.searchable: true
define view C_ReworkBOOVersionDefectCode
  as select from           I_ProductionRoutingVersion   as ProductionRoutingVersion
    left outer to one join I_InspSubsetFieldCombination as InspSubsetFieldCombination on  InspSubsetFieldCombination.InspSubsetFieldCombination = ProductionRoutingVersion.InspSubsetFieldCombination
                                                                                      and InspSubsetFieldCombination.InspectionSubsetType       = '4' --Inspection Point for Serialized Material
    left outer join        I_BillOfOpVersionDefectCode  as BillOfOpVersionDefectCode  on  BillOfOpVersionDefectCode.BillOfOperationsType    = ProductionRoutingVersion.BillOfOperationsType
                                                                                      and BillOfOpVersionDefectCode.BillOfOperationsGroup   = ProductionRoutingVersion.BillOfOperationsGroup
                                                                                      and BillOfOpVersionDefectCode.BillOfOperationsVariant = ProductionRoutingVersion.BillOfOperationsVariant
                                                                                      and BillOfOpVersionDefectCode.BillOfOperationsVersion = ProductionRoutingVersion.BillOfOperationsVersion

  association [1..*] to C_MfgReworkRoutingOperation   as _MfgReworkRoutingOperation   on  $projection.BillOfOperationsType    = _MfgReworkRoutingOperation.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _MfgReworkRoutingOperation.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVersion = _MfgReworkRoutingOperation.BillOfOperationsVersion
  association [0..*] to I_DefectCodeText              as _DefectCodeText              on  $projection.DefectCodeGroup = _DefectCodeText.DefectCodeGroup
                                                                                      and $projection.DefectCode      = _DefectCodeText.DefectCode
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [1..1] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType    = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperationsChangeState.BillOfOperationsVariant
                                                                                      and $projection.BillOfOperationsVersion = _BillOfOperationsChangeState.BillOfOperationsVersion
{
  key ProductionRoutingVersion.BillOfOperationsType,
  key ProductionRoutingVersion.BillOfOperationsGroup,
  key ProductionRoutingVersion.BillOfOperationsVariant,
  key ProductionRoutingVersion.BillOfOperationsVersion,
  key cast(coalesce(BillOfOpVersionDefectCode.DefectCodeGroup, '') as vdm_qfegrp) as DefectCodeGroup,
      @ObjectModel.text.association: '_DefectCodeText'
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_DefectCodeStdVH',
                     element: 'DefectCode' }
        }]
  key cast(coalesce(BillOfOpVersionDefectCode.DefectCode, '') as vdm_qfecod)      as DefectCode,
      BillOfOpVersionDefectCode._DefectCodeGroup._Text[1: Language=$session.system_language].DefectCodeGroupText,
      ProductionRoutingVersion.BillOfOperationsDesc,
      cast(case BillOfOpVersionDefectCode.BillOfOperationsType
        when ProductionRoutingVersion.BillOfOperationsType then 'X'
        else ''
      end as mpe_rtg_defcode_assigned preserving type )                           as DefectCodeIsAssignedToBOO,
      cast(case
        when InspSubsetFieldCombination.InspectionSubsetType is null then ''
        else 'X'
      end as mpe_oan_sfi_conf_rqd preserving type)                                as OpActyConfIsSFIBased,

      // associations

      _DefectCodeText,
      ProductionRoutingVersion._BillOfOperationsType,
      ProductionRoutingVersion._BillOfOperationsGroup,
      ProductionRoutingVersion._BillOfOperations,
      _MfgReworkRoutingOperation,
      _BillOfOperationsChangeState

}
where
      ProductionRoutingVersion.RoutingIsReworkRouting = 'X'
  and ProductionRoutingVersion.IsLatestBOOVersion     = 'X';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPVERSIONDEFECTCODE",
"I_DEFECTCODEGROUP",
"I_DEFECTCODEGROUPTEXT",
"I_INSPSUBSETFIELDCOMBINATION",
"I_PRODUCTIONROUTINGVERSION"
],
"ASSOCIATED":
[
"C_MFGREWORKROUTINGOPERATION",
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_DEFECTCODETEXT"
],
"BASE":
[
"I_PRODUCTIONROUTINGVERSION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/