C_RevnRecgnJournalEntryItem

@AbapCatalog.sqlViewName: 'CIRRJRNENTRITEM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.semanticKey: ['SourceLedger', 'CompanyCode', 'FiscalYear', 'AccountingDocument', 'LedgerGLLineItem', 'Ledger' ]

@EndUserText.label: 'Accnt. Items for Inspect Revn. Recg.'

@VDM.viewType: #CONSUMPTION

@UI.presentationVariant: [
    // Default Presentation variant

    { 
      text:      '',
      qualifier: '',
      groupBy: '',
      selectionFieldsQualifier: '',
      sortOrder: [
        { by: 'AccountingDocument', direction: #ASC },
        { by: 'LedgerGLLineItem', direction: #ASC }      
      ]
    }
]

define view C_RevnRecgnJournalEntryItem 
  as select from P_RevnRecgnJournalEntryItem( P_Language: $session.system_language )

  association [0..1] to I_RevnRecgnLineItmPostgTypeTxt as _RevnRecgnLineItmPostgTypeTxt
    on $projection.RevnRecgnGLLineItmPostgType = _RevnRecgnLineItmPostgTypeTxt.RevnRecgnGLLineItmPostgType
    and _RevnRecgnLineItmPostgTypeTxt.Language = $session.system_language

{ 
  key Ledger, 
  
  key SourceLedger,
  
  @ObjectModel.text.element: ['CompanyCodeName']
  @UI.textArrangement: #TEXT_LAST
  @Consumption.semanticObject: 'CompanyCode' 
  key CompanyCode,
  
  @UI.lineItem: [{ position: 30 }]
  key FiscalYear,
  
  @Consumption.semanticObject: 'AccountingDocument'
  @UI.lineItem: [{ position: 10 }]
  key AccountingDocument, 
  
  @UI.lineItem: [{ position: 20 }]
  key LedgerGLLineItem, 
  
  ReferenceDocument, 
  BusinessTransactionType, 
  FiscalPeriod,
  @Semantics.fiscal.yearPeriod: true
  FiscalYearPeriod,
  @ObjectModel.text.element: ['GLAccountName']
  @UI.textArrangement: #TEXT_LAST
  @Consumption.semanticObject: 'GLAccount' 
  @UI.lineItem: [{ position: 40 }]
  GLAccount, 
  GLAccountType, 
  DebitCreditCode, 
  ChartOfAccounts, 
  Project,
  @UI.hidden: true
  ProjectInternalID,
  WBSElement,
  @UI.hidden: true
  WBSElementInternalID,
  SalesOrder, 
  SalesOrderItem,
  @ObjectModel.text.element: ['RevnRecgnLineItmPostgTypeName']
  @UI.textArrangement: #TEXT_ONLY
  @UI.lineItem: [{ position: 50 }]
  RevnRecgnGLLineItmPostgType,

  @UI.hidden: true
  _RevnRecgnLineItmPostgTypeTxt.RevnRecgnLineItmPostgTypeName,

  @UI.hidden: true
  BalanceTransactionCurrency,

  @UI.hidden: true 
  TransactionCurrency, 

  @UI.hidden: true 
  CompanyCodeCurrency,

  @UI.hidden: true
  GlobalCurrency,
  
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'H' then -AmountInCompanyCodeCurrency
    else 0
  end as fis_aci_hsl_cr preserving type ) as CreditAmountInCoCodeCrcy ,

  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'S' then AmountInCompanyCodeCurrency
    else 0
  end as fis_aci_hsl_dr preserving type ) as DebitAmountInCoCodeCrcy,

  @Semantics.amount.currencyCode: 'GlobalCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'H' then -AmountInGlobalCurrency
    else 0
  end as fis_aci_ksl_cr preserving type ) as CreditAmountInGlobalCrcy,

  @Semantics.amount.currencyCode: 'GlobalCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'S' then AmountInGlobalCurrency
    else 0
  end as fis_aci_ksl_dr preserving type ) as DebitAmountInGlobalCrcy,

  @Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'H' then -AmountInBalanceTransacCrcy
    else 0
  end as fis_aci_tsl_cr preserving type ) as CreditAmountInBalanceTransCrcy,

  @Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'S' then AmountInBalanceTransacCrcy
    else 0
  end as fis_aci_tsl_dr preserving type ) as DebitAmountInBalanceTransCrcy,

  @Semantics.amount.currencyCode: 'TransactionCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'H' then -AmountInTransactionCurrency
    else 0
  end as fis_aci_wsl_cr preserving type ) as CreditAmountInTransCrcy,

  @Semantics.amount.currencyCode: 'TransactionCurrency'
  @DefaultAggregation: #SUM
  cast ( case
    when DebitCreditCode = 'S' then AmountInTransactionCurrency
    else 0
  end as fis_aci_wsl_dr preserving type ) as DebitAmountInTransCrcy,
  
  @ObjectModel.text.element: ['ProfitCenterName']
  @UI.textArrangement: #TEXT_LAST
  @Consumption.semanticObject: 'ProfitCenter' 
  ProfitCenter,
  
  @ObjectModel.text.element: ['CostCenterName']
  @UI.textArrangement: #TEXT_LAST
  @Consumption.semanticObject: 'CostCenter'
  CostCenter, 
  OriginProfitCenter, 
  AccountingDocCreatedByUser, 
  AccountingDocumentType, 
  DocumentDate, 
  PostingDate, 
  CreationDateTime, 
  AccountingDocumentCategory, 
  GLAccountName,
  ProfitCenterName,
  CostCenterName,
  CostCtrActivityType,
  CompanyCodeName,
  
  
  /* Associations */   
  @Consumption.hidden: true
  _GLAccountLineItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REVNRECGNLINEITMPOSTGTYPETXT",
"P_REVNRECGNJOURNALENTRYITEM"
],
"ASSOCIATED":
[
"I_GLACCOUNTLINEITEM",
"I_REVNRECGNLINEITMPOSTGTYPETXT"
],
"BASE":
[
"P_REVNRECGNJOURNALENTRYITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/