C_ReturnsReferenceSalesOrderVH

@VDM.viewType: #CONSUMPTION

@ObjectModel: {
  dataCategory:#VALUE_HELP,
  representativeKey: 'SalesOrder',
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #L
  }
}

@Search.searchable: true
@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #MANDATORY

@UI.presentationVariant: [{
  sortOrder: [{
    by: 'SalesOrder',
    direction: #DESC
  }]
}]
@EndUserText.label: 'Return Reference Sales Order'
define view entity C_ReturnsReferenceSalesOrderVH

  as select from I_SalesOrder as SalesOrder

  association [0..*] to I_OverallSDProcessStatusText   as _OverallSDProcessStatusText   on $projection.OverallSDProcessStatus      = _OverallSDProcessStatusText.OverallSDProcessStatus

{
      @UI: {
        lineItem: [{ position: 10,  importance: #HIGH }],
        selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key SalesOrder.SalesOrder,

      @UI: {
        lineItem: [{ position: 20,  importance: #HIGH }],
        selectionField: [{ position: 20 }],
        textArrangement: #TEXT_FIRST
      }

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'D_SlsDocSoldToPartyCVH',
        element: 'Customer' } }]
      }
      @ObjectModel.text.element: ['SoldToPartyName']
      SalesOrder.SoldToParty,

      @Semantics.text: true
      @UI.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_SLSORD_UI_PARTNER_UTIL'
      cast('' as ad_namtext )                                                        as SoldToPartyName,

      @UI: {
        selectionField: [{ position: 30 }],
        lineItem: [{ position: 30,  importance: #HIGH }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      SalesOrder.PurchaseOrderByCustomer,

      @UI: {
        lineItem: [{ position: 40,  importance: #HIGH }],
        selectionField: [{ position: 40 }]
      }
      @Consumption.filter: {
        selectionType: #INTERVAL
      }
      SalesOrder.SalesOrderDate,

      @UI: {
        lineItem: [{ position: 50,  importance: #HIGH }],
        selectionField: [{ position: 50 }],
        textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallSDProcessStatus',
          element: 'OverallSDProcessStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallSDProcessStatusDesc']
      SalesOrder.OverallSDProcessStatus,

      @UI.hidden: true
      @Semantics.text: true
      _OverallSDProcessStatusText[1: Language=$session.system_language].OverallSDProcessStatusDesc,

      //Properties for DCL

      @UI.hidden: true
      SalesOrder.SalesOrderType,
      @UI.hidden: true
      SalesOrder.SalesOrganization,
      @UI.hidden: true
      SalesOrder.DistributionChannel,
      @UI.hidden: true
      SalesOrder.OrganizationDivision
}
 where
     SalesDocApprovalStatus        <> 'A' and  // In Approval

     SalesDocApprovalStatus        <> 'C' and  // Rejected

     SalesDocApprovalStatus        <> 'D'      // To Be Reworked

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_OVERALLSDPROCESSSTATUSTEXT",
"I_SALESORDER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/