C_ReturnsReferenceInvoiceVH

@VDM.viewType: #CONSUMPTION
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Customer Return Reference Invoice'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
dataCategory: #VALUE_HELP,
representativeKey:'BillingDocument',
usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
}
@Search.searchable: true
@Consumption.ranked: true
@UI.presentationVariant: [{
  sortOrder: [{
    by: 'BillingDocument',
    direction: #DESC
  }]
}]
define view entity C_ReturnsReferenceInvoiceVH   as select from I_BillingDocument as BillingDocument

  association [0..*] to I_OverallBillingStatusText as _OverallBillingStatusText on $projection.OverallBillingStatus = _OverallBillingStatusText.OverallBillingStatus

{
      @UI: {
      lineItem: [{ position: 10,  importance: #HIGH }],
      selectionField: [{ position: 10 }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
  key cast(BillingDocument.BillingDocument as vdm_invoice preserving type) as BillingDocument,

      @UI.textArrangement: #TEXT_FIRST
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'D_SlsDocSoldToPartyCVH',
        element: 'Customer' } }]
      }
      @ObjectModel.text.element: ['SoldToPartyName']
      BillingDocument.SoldToParty,
      @Semantics.text: true
      @UI.hidden: true
      cast (BillingDocument._SoldToParty.CustomerName as ad_namtext)         as SoldToPartyName,

      @UI: {
      lineItem: [{ position: 20,  importance: #HIGH }],
      selectionField: [{ position: 20 }],
      textArrangement: #TEXT_FIRST
      }
      @Consumption.valueHelpDefinition:[{
        entity: { name: 'C_CustomerSalesAreaVH',
                  element: 'Customer' },
        label: 'Payer'
      }]
      @ObjectModel.text.element: ['PayerPartyName']
      BillingDocument.PayerParty,

      @Semantics.text: true
      @UI.hidden: true
      BillingDocument._PayerParty.CustomerName as PayerPartyName,


      @UI: {
      selectionField: [{ position: 30 }],
      lineItem: [{ position: 30,  importance: #HIGH }]
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #MEDIUM
      }
      BillingDocument.PurchaseOrderByCustomer,
      @UI: {
        lineItem: [{ position: 40,  importance: #HIGH }],
        selectionField: [{ position: 40 }]
      }
      @Consumption.filter: {
        selectionType: #INTERVAL
      }
      BillingDocument.BillingDocumentDate,
      @UI: {
      lineItem: [{ position: 50,  importance: #HIGH }],
      selectionField: [{ position: 50 }],
      textArrangement: #TEXT_ONLY
      }
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_OverallBillingStatus',
          element: 'OverallBillingStatus'
        }
      }]
      @ObjectModel.text.element: ['OverallBillingStatusDesc']
      cast(BillingDocument.OverallBillingStatus as billing_document_status preserving type ) as OverallBillingStatus,


      @UI.hidden: true
      @Semantics.text: true
      _OverallBillingStatusText[1: Language=$session.system_language].OverallBillingStatusDesc,

      @Consumption.hidden:true
      BillingDocument.BillingDocumentType,
      @Consumption.hidden:true
      BillingDocument.SalesOrganization,
      @Consumption.hidden:true
      BillingDocument.DistributionChannel,
      @Consumption.hidden:true
      BillingDocument.Division

}
where
      BillingDocument.SDDocumentCategory     = 'M'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENT",
"I_CUSTOMER",
"I_OVERALLBILLINGSTATUSTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/