C_RetsReferenceSalesOrderItem

DDL: C_RETSREFERENCESALESORDERITEM Type: view_entity CONSUMPTION

Returns Reference Sales Order Item

C_RetsReferenceSalesOrderItem is a Consumption CDS View that provides data about "Returns Reference Sales Order Item" in SAP S/4HANA. It reads from 2 data sources (C_ReturnsReferenceSalesOrder, I_SalesDocumentItemBasic) and exposes 19 fields with key fields ReferenceDocument, ReferenceSDDocumentItem. It has 1 association to related views.

2 data source(s) 19 fields

Data Sources (2)

SourceAliasJoin Type
C_ReturnsReferenceSalesOrder ReferenceDocument inner
I_SalesDocumentItemBasic SalesDocumentItemBasic from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_SalesDocumentRjcnReasonText _RjcnReasonText $projection.SalesDocumentRjcnReason = _RjcnReasonText.SalesDocumentRjcnReason

Annotations (11)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.modelingPattern #NONE view
Search.searchable true view
EndUserText.label Returns Reference Sales Order Item view

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY ReferenceDocument I_SalesDocumentItemBasic SalesDocument
KEY ReferenceSDDocumentItem
SDDocumentCategory C_ReturnsReferenceSalesOrder SDDocumentCategory
Product I_SalesDocumentItemBasic Product
ProductName
ReturnableQuantity
OrderQuantityUnit I_SalesDocumentItemBasic OrderQuantityUnit
OrderQuantity I_SalesDocumentItemBasic OrderQuantity
NetAmount I_SalesDocumentItemBasic NetAmount
ReturnQuantity
ReturnQuantityUnit I_SalesDocumentItemBasic OrderQuantityUnit
TransactionCurrency I_SalesDocumentItemBasic TransactionCurrency
HigherLevelItem I_SalesDocumentItemBasic HigherLevelItem
SalesDocumentRjcnReason I_SalesDocumentItemBasic SalesDocumentRjcnReason
SalesDocumentRjcnReasonName
SalesDocumentType C_ReturnsReferenceSalesOrder SalesDocumentType
OrganizationDivision C_ReturnsReferenceSalesOrder OrganizationDivision
SalesOrganization C_ReturnsReferenceSalesOrder SalesOrganization
DistributionChannel C_ReturnsReferenceSalesOrder DistributionChannel 
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED
}
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@ObjectModel: {
  updateEnabled,
  usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XL
  },
  supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern: #NONE
}
@Search.searchable: true
@EndUserText.label: 'Returns Reference Sales Order Item'
define view entity C_RetsReferenceSalesOrderItem 
  as select from I_SalesDocumentItemBasic as SalesDocumentItemBasic
    inner join C_ReturnsReferenceSalesOrder  as ReferenceDocument               on SalesDocumentItemBasic.SalesDocument     = ReferenceDocument.SalesOrder
    association [0..*] to I_SalesDocumentRjcnReasonText as _RjcnReasonText      on $projection.SalesDocumentRjcnReason      = _RjcnReasonText.SalesDocumentRjcnReason
{ 
      @Search.defaultSearchElement: true
  key SalesDocumentItemBasic.SalesDocument as ReferenceDocument,

  key cast(SalesDocumentItemBasic.SalesDocumentItem as reference_doc_item) as ReferenceSDDocumentItem, 

      ReferenceDocument.SDDocumentCategory,

      @ObjectModel.text.element: ['ProductName']
      SalesDocumentItemBasic.Product,
     
      @Semantics.text: true
      SalesDocumentItemBasic._ProductText[1: Language=$session.system_language].ProductName,
      
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_CUSTRETURN_V4_UI_UTIL'
      cast(0 as returnable_quantity)            as ReturnableQuantity,

      SalesDocumentItemBasic.OrderQuantityUnit,
      
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      SalesDocumentItemBasic.OrderQuantity,
      
     
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SalesDocumentItemBasic.NetAmount,

      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_CUSTRETURN_V4_UI_UTIL'
      @Semantics.valueRange.minimum: '0'
      @Semantics.quantity.unitOfMeasure: 'ReturnQuantityUnit'     
      cast(0 as return_quantity)                as ReturnQuantity,
      
      SalesDocumentItemBasic.OrderQuantityUnit                         as ReturnQuantityUnit,
      
      SalesDocumentItemBasic.TransactionCurrency,
                
      SalesDocumentItemBasic.HigherLevelItem,
        
      @ObjectModel.text.element:  [ 'SalesDocumentRjcnReasonName' ]
      SalesDocumentItemBasic.SalesDocumentRjcnReason,

      @Semantics.text: true
      _RjcnReasonText[1: Language=$session.system_language].SalesDocumentRjcnReasonName,
        
      // ACL

      @UI.hidden: true
      ReferenceDocument.SalesDocumentType,
      @Consumption.hidden:true
      ReferenceDocument.OrganizationDivision,
      @Consumption.hidden:true
      ReferenceDocument.SalesOrganization,
      @Consumption.hidden:true
      ReferenceDocument.DistributionChannel
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_RETURNSREFERENCESALESORDER",
"I_PRODUCTTEXT",
"I_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENTRJCNREASONTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More