C_ResourceObjPgTodayOp

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Todays Operations for Resources'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@UI.headerInfo.typeName: 'Today''s Operation'
@UI.headerInfo.typeNamePlural: 'Today''s Operations'

define view entity C_ResourceObjPgTodayOp
  as select from I_TodaysOperations
{

      @UI.hidden
  key OrderInternalBillOfOperations,
      @UI.hidden
  key OrderIntBillOfOperationsItem,

      @UI.hidden
  key WorkCenterInternalID,

      @Consumption.semanticObject: 'ProcessOrder'
      @UI.lineItem:[{ position:10 }]
      @EndUserText.label: 'Process Order'
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'ProcessOrder'}]
      @ObjectModel.foreignKey.association: '_MfgOrder'
      @Consumption.valueHelpDefinition: [{entity:{name:'I_MfgOrderStdVH' , element: 'ManufacturingOrder'}}]
      ManufacturingOrder,

      @ObjectModel.text.element: [ 'MfgOrderOperationText']
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderOperation' } } ]
      @UI.lineItem:[{position:20 }]
      ManufacturingOrderOperation,
      @UI.hidden
      ManufacturingOrderCategory,
      @UI.hidden: true
      MfgOrderOperationText,
      @Consumption.semanticObject: 'Material'
      @UI.lineItem: [ { position: 30, label: 'Material'}]    
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'Material'}]          
      @EndUserText.label: 'Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      Material,
      @UI.lineItem: [{position:35}]
      @EndUserText:{label:'Material Description',quickInfo: 'Material Description'}
      _Material._Text[1:Language=$session.system_language].MaterialName,
      @UI.lineItem: [{position:40}]
      @EndUserText:{label:'Operation Is Released ',quickInfo: 'Operation Is Released '}
      OperationIsReleased,
      @UI.lineItem: [{position:50}]
      @EndUserText.label: 'Planned Start Date'
      OpErlstSchedldExecStrtDte,
      @EndUserText.label: 'Planned Start Time'
      @UI.lineItem: [{position:60}]
      OpErlstSchedldExecStrtTme,
      @EndUserText.label: 'Planned End Date'
      @UI.lineItem: [{position:70}]
      OpErlstSchedldExecEndDte,
      @EndUserText.label: 'Planned End Time'
      @UI.lineItem: [{position:80}]
      OpErlstSchedldExecEndTme,
      @UI.lineItem: [{position:90}]
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpPlannedTotalQuantity,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
      OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @EndUserText.label: 'Confirmed Quantity'
      OpTotalConfirmedYieldQty,
      @EndUserText.label: 'Planned Duration'
      ErlstSchedldExecDurnInWorkdays,
      @EndUserText.label: 'Actual Duration'
      OpActualExecutionDays,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      @Consumption.valueHelpDefinition: [{entity:{name:'I_MfgOrderSequenceStdVH' , element: 'ManufacturingOrderSequence'}}]
      ManufacturingOrderSequence,
      @EndUserText:{label:'Phase',quickInfo: 'Phase'}
      MfgOrderOperationIsPhase,

      _Material,
      _MfgOrderSequence,
      _MfgOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_TODAYSOPERATIONS"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDERSEQUENCE"
],
"BASE":
[
"I_TODAYSOPERATIONS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/