C_RecipeFmlaWthExplosionRecipe

@AbapCatalog.sqlViewName: 'CRCPFRMWEXPLRCP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED

@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Recipe Formula With Explosion Recipes'
@Metadata.ignorePropagatedAnnotations: true
define view C_RecipeFmlaWthExplosionRecipe
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate        : sydate,
    P_ExplosionScope : /plmi/rca_expl_scope
  as select from I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as FromFormula
    inner join   I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate)  as ToFormula on  FromFormula.SpecificationInternalID      = ToFormula.SpecificationInternalID
                                                                                                 and ToFormula.RcpFmlaItemExplosionRecipeUUID = FromFormula.RecipeUUID
                                                                                                 and FromFormula.RcpFmlaItemType              = 'PO'
                                                                                                 and ToFormula.RcpFmlaItemType                = 'IN'

  association [0..1] to I_RecipeExplosionScopeCompType as _ToRecipeExplScopeCompType     on  _ToRecipeExplScopeCompType.RcpFmlaItemComponentType = ToFormula.RcpFmlaItemComponentType
                                                                                         and _ToRecipeExplScopeCompType.ExplosionScope           = $parameters.P_ExplosionScope
  association [0..1] to I_RecipeExplosionScopeCompType as _FromRecipeExplScopeCompType   on  _FromRecipeExplScopeCompType.RcpFmlaItemComponentType = FromFormula.RcpFmlaItemComponentType
                                                                                         and _FromRecipeExplScopeCompType.ExplosionScope           = $parameters.P_ExplosionScope
  association [1..1] to I_RecipeStreamQtyForKeyDate    as _ToRecipeStreamQtyForKeyDate   on  _ToRecipeStreamQtyForKeyDate.RcpFmlaItemUUID = ToFormula.RcpFmlaItemUUID
                                                                                         and _ToRecipeStreamQtyForKeyDate.ExplosionScope  = $parameters.P_ExplosionScope
  association [1..1] to I_RecipeStreamQtyForKeyDate    as _FromRecipeStreamQtyForKeyDate on  _FromRecipeStreamQtyForKeyDate.RcpFmlaItemUUID = FromFormula.RcpFmlaItemUUID
                                                                                         and _FromRecipeStreamQtyForKeyDate.ExplosionScope  = $parameters.P_ExplosionScope

{
  key FromFormula.RecipeUUID                                                                           as FromRecipeUUID,
  key ToFormula.RecipeUUID                                                                             as ToRecipeUUID,
  key FromFormula.SpecificationInternalID                                                              as FromSpecificationInternalID,
  key ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipePrimaryOutputInternalID    as ToSpecificationInternalID,

      ToFormula.RcpFmlaItemUUID                                                                        as ToRcpFmlaItemUUID,


      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipePurpose                  as FromRecipePurpose,
      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeStatus                   as FromRecipeStatus,
      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeType                     as FromRecipeType,
      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeAuthorizationGroup       as FromRecipeAuthorizationGroup,
      FromFormula.RcpFmlaItemQuantityInKilogram                                                        as FromRcpFmlaItemQuantityInKg,
      _FromRecipeStreamQtyForKeyDate( P_KeyDate : $parameters.P_KeyDate).RcpFmlaItemStreamQuantityInKg as FromRcpFmlaItemStreamQtyInKg,

      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeAuthorizationGroup         as ToRecipeAuthorizationGroup,
      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipePurpose                    as ToRecipePurpose,
      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeStatus                     as ToRecipeStatus,
      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeType                       as ToRecipeType,
      ToFormula.RcpFmlaItemQuantityInKilogram                                                          as ToRcpFmlaItemQuantityInKg,
      _ToRecipeStreamQtyForKeyDate( P_KeyDate : $parameters.P_KeyDate).RcpFmlaItemStreamQuantityInKg   as ToRcpFmlaItemStreamQtyInKg,

      _FromRecipeExplScopeCompType.ExplosionIsToBeStopped                                              as ExplosionIsToBeStopped,

      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeValidityStartDate        as FromRecipeValidityStartDate,
      FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeValidityEndDate          as FromRecipeValidityEndDate,

      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeValidityStartDate          as ToRecipeValidityStartDate,
      ToFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeValidityEndDate            as ToRecipeValidityEndDate,

      FromFormula.RcpFmlaUUID                                                                          as FromRcpFmlaUUID,
      ToFormula.RcpFmlaUUID                                                                            as ToRcpFmlaUUID,

      FromFormula._RecipeForKeyDate                                                                    as _FromRecipeForKeyDate,
      ToFormula._RecipeForKeyDate                                                                      as _ToRecipeForKeyDate
}


where
  // filter for deleted+archives recipes

       FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeIsDeleted  <> 'X'
  and  FromFormula._RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate ).RecipeIsArchived <> 'X'

  //  component type of the input item and PO should not have explosion stop on it

  //  from side explosion stop check is moved to ABAP

  and(
       _ToRecipeExplScopeCompType.ExplosionIsToBeStopped                                  =  ''
    or _ToRecipeExplScopeCompType.ExplosionIsToBeStopped                                  is null
  )
  and  ToFormula.RcpFmlaItemExplosionRecipeUUID                                           <> hextobin(
    '00000000000000000000000000000000'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECIPEEXPLOSIONSCOPECOMPTYPE",
"I_RECIPEFORKEYDATE",
"I_RECIPEFORMULAITEMFORKEYDATE",
"I_RECIPESTREAMQTYFORKEYDATE"
],
"ASSOCIATED":
[
"I_RECIPEEXPLOSIONSCOPECOMPTYPE",
"I_RECIPEFORKEYDATE",
"I_RECIPESTREAMQTYFORKEYDATE"
],
"BASE":
[
"I_RECIPEFORMULAITEMFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/