C_RSHOperationValidation

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CRSHOPRVAL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:  #CHECK
@ObjectModel.representativeKey: 'MaintenanceOrderOperation'
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Message for operation list'
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
/*
CONTRACT**********************************************************************************************************************

Name:                       Validation for order operation change
Specification:              This view provides the below messages for each of the operations.
                            1. Operation with status in process
                            2. Operation with cross order relationship
                            Filtering of message is handled in C_RSHOperations
Requires:                   NA
Ensures:                    All messages validation of message class RSH_EAM_ORDER are returned with Text
Owners:                     YS
Contributors:               YS, NF
Unit Test required Y/N:     N
Additional comments         No
END OF CONTRACT***************************************************************************************************************
*/

define view C_RSHOperationValidation
  as select from I_MaintOrderOperAndSubOper
  association [0..*] to I_RSHOrderMessages      as _Message                      on  _Message.SystemMessageNumber = '001'
                                                                                 or  _Message.SystemMessageNumber = '002'

  association [1..1] to I_RSHMessageType        as _MessageType                  on  _MessageType.SystemMessageType = 'I'

  association [0..1] to I_MaintenanceOrderStdVH as _MaintenanceOrder             on  _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
  association [0..1] to I_MaintOrdOpStdVH       as _MaintenanceOrderOperation    on  $projection.MaintenanceOrder          = _MaintenanceOrderOperation.MaintenanceOrder
                                                                                 and $projection.MaintenanceOrderOperation = _MaintenanceOrderOperation.MaintenanceOrderOperation
  association [0..1] to I_MaintOrdSubOpStdVH    as _MaintenanceOrderSubOperation on  $projection.MaintenanceOrder             = _MaintenanceOrderSubOperation.MaintenanceOrder
                                                                                 and $projection.MaintenanceOrderOperation    = _MaintenanceOrderSubOperation.MaintenanceOrderOperation
                                                                                 and $projection.MaintenanceOrderSubOperation = _MaintenanceOrderSubOperation.MaintenanceOrderSubOperation
  association [0..1] to I_RSHOrderMessageVH     as _MessageVH                    on  $projection.systemmessagenumber = _MessageVH.SystemMessageNumber
{
           @Consumption.semanticObject: 'MaintenanceOrder'
           @ObjectModel.foreignKey.association: '_MaintenanceOrder'
           @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaintenanceOrderStdVH', element: 'MaintenanceOrder' } } ]
  key      MaintenanceOrder,
           @ObjectModel.foreignKey.association: '_MaintenanceOrderOperation'
           @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaintOrdOpStdVH', element: 'MaintenanceOrderOperation' } } ]
  key      MaintenanceOrderOperation,
           @ObjectModel.foreignKey.association: '_MaintenanceOrderSubOperation'
           @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaintOrdSubOpStdVH', element: 'MaintenanceOrderSubOperation' } } ]
  key      MaintenanceOrderSubOperation,
           @ObjectModel.foreignKey.association: '_MessageVH'
  key      _Message.SystemMessageNumber,

           //        HasError,

           _MessageType.SystemMessageType,
           _MessageType.SystemMessageTypeCriticality,
           @Semantics.text: true
           _MessageType.SystemMessageTypeName,

           @Semantics.text: true
           _Message.SystemMessageText,

           I_MaintOrderOperAndSubOper.Plant                                                                                                                                                                                                                                                                                                                                                                                                        as         Plant,
           I_MaintOrderOperAndSubOper._MaintenanceOrder.MaintenanceOrderType                                                                                                                                                                                                                                                                                                                                                                       as         OrderType,
           I_MaintOrderOperAndSubOper._MaintenanceOrder.MaintenancePlannerGroup                                                                                                                                                                                                                                                                                                                                                                    as         MaintenancePlannerGroup,

           // Select for DCL

           @UI.hidden: true
           _MaintenanceOrder.Equipment,
           _MaintenanceOrder.MaintObjectLocAcctAssgmtNmbr,
           _MaintenanceOrder.MaintenanceOrderType,
           _MaintenanceOrder.MaintenancePlanningPlant,
           _MaintenanceOrderOperation.OperationPersonResponsible,
           
           _MaintenanceOrder,
           _MaintenanceOrder._LocationAccountAssignment,
           _MaintenanceOrder._Equipment,
           _MaintenanceOrderOperation,
           _MaintenanceOrderOperation._PersonResponsible,
           _MaintenanceOrderSubOperation,
           _Message,
           _MessageVH
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDER",
"I_MAINTENANCEORDERSTDVH",
"I_MAINTORDEROPERANDSUBOPER",
"I_MAINTORDOPSTDVH",
"I_RSHMESSAGETYPE",
"I_RSHORDERMESSAGES"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEORDERSTDVH",
"I_MAINTORDOPSTDVH",
"I_MAINTORDSUBOPSTDVH",
"I_PERSONWORKAGREEMENT_1",
"I_RSHMESSAGETYPE",
"I_RSHORDERMESSAGES",
"I_RSHORDERMESSAGEVH"
],
"BASE":
[
"I_MAINTENANCEORDERSTDVH",
"I_MAINTORDOPSTDVH"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/