C_RSHOpUnassignedWorkKPI

@AbapCatalog.sqlViewName: 'CRSHOPUNASWKPI'

@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Operations unassigned work KPI'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #REQUIRED

/*
CONTRACT**********************************************************************************************************************

Name:                       Operations Unassigned Work KPI
Specification:              This view is used to determine unassigned work in get_entityset of C_RSHOpUnassignedWork
Requires:                   Operations work available for next 2 weeks
Ensures:                    Unassigned work at operation level for current and next week
Owners:                     CVK
Contributors:               PRP
Unit Test required Y/N:     Yes
Additional comments         None

END OF CONTRACT***************************************************************************************************************
*/

define view C_RSHOpUnassignedWorkKPI
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum

  //  as select from P_RSHWCUtilization( P_StartDate : $parameters.P_StartDate, P_EndDate : $parameters.P_EndDate) as Operations

  as select from P_RSHWrkCtrUtilization(P_SAPClient : $session.client, P_StartDate : $parameters.P_StartDate, P_EndDate : $parameters.P_EndDate) as Operations
    inner join   I_CalendarDate                                                                                                                  as Calendardate on  Operations.CalendarDate   = Calendardate.CalendarDate
                                                                                                                                                                 and Calendardate.CalendarDate between $parameters.P_StartDate and $parameters.P_EndDate
  association [0..1] to C_RSHOrderPriorityVH           as _PriorityVH                 on  $projection.MaintPriority     = _PriorityVH.MaintPriority
                                                                                      and $projection.MaintPriorityType = _PriorityVH.MaintPriorityType
  association [0..1] to C_RSHOperationActivityTypeVH   as _ActivityTypeVH             on  $projection.MaintenanceActivityType = _ActivityTypeVH.MaintenanceActivityType
  association [0..1] to C_RSHOperationProcessStatusVH  as _ProcessingStatusVH         on  $projection.ProcessingStatus = _ProcessingStatusVH.ProcessingStatus
  association [0..1] to C_RSHMaintPriorityColorCodeTxt as _MaintPriorityColorCodeText on  $projection.MaintPriorityColorCode = _MaintPriorityColorCodeText.MaintPriorityColorCode

  association [0..1] to I_RSHOrder                     as _Order                      on  $projection.MaintenanceOrder = _Order.MaintenanceOrder

{

        // Below key is carried forward from the base class to avoid duplicate entries error during ATC

  key   Operations.MaintenanceOrder                                                                                as MaintenanceOrder,
  key   Operations.MaintenancePlan                                                                                 as MaintenancePlan,
  key   Operations.MaintenanceOrderOperation                                                                       as MaintenanceOrderOperation,
  key   Operations.MaintenanceOrderSubOperation                                                                    as MaintenanceOrderSubOperation,
  key   Calendardate.CalendarDate                                                                                  as CalendarDate,
  key   Operations.CapacityStartTime                                                                               as CapacityStartTime,
  key   Operations.AvailableCapacityShift                                                                          as AvailableCapacityShift,

  key   Operations.WorkCenter                                                                                      as WorkCenter,
  key   Operations.Plant                                                                                           as Plant,

        @ObjectModel.foreignKey.association: '_PriorityVH'
        @ObjectModel.text.element:  [ 'MaintPriorityDesc' ]
        Operations.MaintPriority                                                                                   as MaintPriority,
        Operations.MaintPriorityType                                                                               as MaintPriorityType,
        @ObjectModel.text.element:  [ 'MaintPriorityColorCodeText' ]
        Operations.MaintPriorityColorCode                                                                          as MaintPriorityColorCode,
        _MaintPriorityColorCodeText[ 1: Language = $session.system_language  ].MaintPriorityColorCodeText          as MaintPriorityColorCodeText,
        _PriorityVH.MaintPriorityDesc                                                                              as MaintPriorityDesc,

        Operations.OperationControlKey                                                                             as OperationControlKey,

        Operations.OrderType                                                                                       as MaintenanceOrderType,

        @ObjectModel.foreignKey.association: '_ActivityTypeVH'
        Operations.MaintenanceActivityType                                                                         as MaintenanceActivityType,
        _ActivityTypeVH._Text[ 1: Language = $session.system_language  ].MaintenanceActivityTypeName               as MaintenanceActivityTypeName,

        @ObjectModel.foreignKey.association: '_ProcessingStatusVH'
        Operations.ProcessingStatus                                                                                as ProcessingStatus,
        cast( _ProcessingStatusVH.ProcessingStatusText  as rsh_eam_processing_status_text preserving type)         as ProcessingStatusText,

        @DefaultAggregation: #SUM
        Operations.UsedCapacity                                                                                    as MaintOrdOperationsUnassgWork,

        _Order.MaintenanceRevision                                                                                 as MaintenanceRevision,
        _Order._LocationAccountAssignment.FunctionalLocation                                                       as FunctionalLocation,
        _Order._LocationAccountAssignment._FunctionalLocation._FunctionalLocationLabel.FunctionalLocationLabelName as FunctionalLocationLabelName,

        cast( case when _Order.Equipment = '' then
               _Order._LocationAccountAssignment._FunctionalLocation._FunctionalLocationLabel.FunctionalLocationLabelName
         else _Order.Equipment end as rsh_eams_ord_tec_obj )                                                       as TechnicalObjectLabel,

        cast( case when _Order.Equipment = '' and _Order._LocationAccountAssignment.FunctionalLocation  = '' then ''
           else case when _Order.Equipment = '' then 'EAMS_FL'
           else 'EAMS_EQUI' end end as rsh_eam_ord_tec_obj_type_value )                                            as TechObjIsEquipOrFuncnlLoc,

        cast( _Order._LocationAccountAssignment.ABCIndicator as rsh_eam_abc_ind preserving type )                  as ABCIndicator,

        // Associations - Value Helps - defined locally

        _PriorityVH,
        _ActivityTypeVH,
        _ProcessingStatusVH,

        //       For DCL Selects

        _Order.Equipment                                                                                           as Equipment,
        _Order.MaintObjectLocAcctAssgmtNmbr,
        _Order.MaintenancePlanningPlant,
        _Order.MaintenancePlannerGroup,
        _Order.MainWorkCenter,
        _Order.MainWorkCenterPlant,
        _Order._LocationAccountAssignment.PlantSection,
        _Order._LocationAccountAssignment.AssetLocation,
        _Order._LocationAccountAssignment.MaintenancePlant,

        _Order._Equipment,
        _Order._LocationAccountAssignment

}
where
      OperationPersonResponsible    = '00000000'
  and Operations.MaintenancePlan    is initial
  and _PriorityVH.MaintPriorityDesc is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_RSHMAINTPRIORITYCOLORCODETXT",
"C_RSHOPERATIONACTIVITYTYPEVH",
"C_RSHOPERATIONPROCESSSTATUSVH",
"C_RSHORDERPRIORITYVH",
"I_CALENDARDATE",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEACTIVITYTYPETEXT",
"I_RSHORDER"
],
"ASSOCIATED":
[
"C_RSHMAINTPRIORITYCOLORCODETXT",
"C_RSHOPERATIONACTIVITYTYPEVH",
"C_RSHOPERATIONPROCESSSTATUSVH",
"C_RSHORDERPRIORITYVH",
"I_EQUIPMENT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_RSHORDER"
],
"BASE":
[
"I_RSHORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/