C_RO_SAFTPurInvoiceItemC

@AbapCatalog.sqlViewName: 'CROSAFTPURINVIC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@Consumption.dbHints: ['PREAGGR_BEFORE_JOIN']
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName:#LOCAL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Purchase invoice item for RO SAFT - Cube'
@Metadata.allowExtensions:true
define view C_RO_SAFTPurInvoiceItemC
  with parameters

    P_AlternativeGLAccountIsUsed : saft_ro_alt_gl_account_flag

  as select distinct from  P_RO_SAFTPurInvItem (P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed)       as Item
    inner join             P_RO_SAFTOplAcctgDocItmExc(P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed) as Bseg               on  Bseg.AccountingDocument   = Item.AccountingDocument
                                                                                                                                                    and Bseg.CompanyCode          = Item.CompanyCode
                                                                                                                                                    and Bseg.FiscalYear           = Item.FiscalYear
                                                                                                                                                    and Bseg.FinancialAccountType = 'K'

    left outer to one join I_RO_SAFTSpecialGLIndicator                                                                        as SpecialGLIndicator on  Bseg.CompanyCode          = SpecialGLIndicator.CompanyCode
                                                                                                                                                    and Bseg.FinancialAccountType = SpecialGLIndicator.AccountType
                                                                                                                                                    and Bseg.SpecialGLCode        = SpecialGLIndicator.SpecialGLCode

{
  key Item.StatryRptCategory,
  key Item.StatryRptgEntity,
  key Item.StatryRptRunID,
  key Item.CompanyCode,
  key Item.FiscalYear,
  key Item.AccountingDocument,
  key Item.AccountingDocumentItem,
      Item.AccountingDocumentType,
      Item.Product,
      Item.BaseUnit,
      Item.TransactionTypeDetermination,
      Item.PostingDate,
      @Semantics.currencyCode:true
      Item.CompanyCodeCurrency,
      @Semantics.currencyCode:true
      Item.TransactionCurrency,
      Item.IsNegativePosting,
      Item.RO_SAFTGoodsService,
      Item.ProductDescription,
      Item.SourceUnitOfMeasureFactor,

      Item.DebitCreditCode,

      Item.ConversionFactor,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Item.AmountInTransactionCurrency,

      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      Item.AmountInCompanyCodeCurrency,

      @Aggregation.default: #MAX
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      Item.UnitPriceAmountInReportingCrcy,

      Item.TaxReportingDate,

      Item.DocumentItemText, // Description


      @Aggregation.default: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Item.Quantity,         // Quantity


      @Aggregation.default: #MAX
      Item.RO_SAFTExchangeRate,

      RO_SAFTStandardAccount

}
where
  SpecialGLIndicator.SpecialGLCode is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RO_SAFTSPECIALGLINDICATOR",
"P_RO_SAFTOPLACCTGDOCITMEXC",
"P_RO_SAFTPURINVITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/