C_RO_SAFTProductC

@AbapCatalog.sqlViewName: 'CROSAFTPRODTYPEC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName:#LOCAL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Product Type for RO SAFT - Cube'
@Metadata.allowExtensions: true
define view C_RO_SAFTProductC
  with parameters
    P_FromPostingDate            : figen_rep_date_from,
    P_ToPostingDate              : figen_rep_date_to,
    P_AlternativeGLAccountIsUsed : saft_ro_alt_gl_account_flag

  as select distinct from  I_RO_SAFTProduct ( P_FromPostingDate: $parameters.P_FromPostingDate,
                           P_ToPostingDate  : $parameters.P_ToPostingDate )                                                     as Product
    inner join             P_RO_SAFTJournalEntryItemExc(P_AlternativeGLAccountIsUsed: $parameters.P_AlternativeGLAccountIsUsed) as JournalEntry on  JournalEntry.Product = Product.Product
                                                                                                                                                and JournalEntry.Plant   = Product.Plant
    inner join             I_StRpJournalEntryHeaderLog                                                                          as Log          on  Log.AccountingDocument = JournalEntry.AccountingDocument
                                                                                                                                                and Log.CompanyCode        = JournalEntry.CompanyCode
                                                                                                                                                and Log.FiscalYear         = JournalEntry.FiscalYear
    left outer to one join I_RO_SAFTUnitOfMeasureMap                                                                            as UomAltUnit   on Product.AlternativeUnit = UomAltUnit.SourceUnitOfMeasure
{
  key Log.StatryRptCategory,
  key Log.StatryRptgEntity,
  key Log.StatryRptRunID,
  key Product.Product,
      Product.MaterialType,
      Product.ProductGroup,
      Product.ProductName,
      case
        when Product.CommodityCodeText is not initial
          then left(replace(Product.CommodityCodeText, '.', ''), 8)
        when Product.CommodityCodeText is initial and Product.RO_SAFTGoodsService = '02'
          then '99999999'
        else '0'
      end                                  as CommodityCodeText,


      // Product.CommodityCodeText,

      Product.ProductStandardID,
      Product.ValuationClass,

      //Base Unit

      Product.BaseUnit,
      Product.SourceUnitOfMeasureFactor,

      // Alternative Unit

      Product.AlternativeUnit,
      UomAltUnit.SourceUnitOfMeasureFactor as TargetUnitOfMeasure,

      Product.ConversionFactor,
      Product.RO_SAFTGoodsService,

      'X'                                  as ItemIsReportingRelevant

      //    case $session.system_language

      //      when '4' then '4'

      //      else '-'

      //    end as Language

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RO_SAFTPRODUCT",
"I_RO_SAFTUNITOFMEASUREMAP",
"I_STRPJOURNALENTRYHEADERLOG",
"P_RO_SAFTJOURNALENTRYITEMEXC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/