C_RO_SAFTHeader

@AbapCatalog.sqlViewName: 'CROSAFTHEADER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Header Master Data for RO SAFT'

define view C_RO_SAFTHeader
  with parameters
    P_VATRegistration : stceg,
    P_CompanyCodeName : char200,
    P_IsTestRun       : allgtest
  as select from    I_CompanyCode         as CompanyCode
    join            I_SAFTProductVersion  as Version on  Version.ObjectName is not initial
                                                     and EmbeddedSwVersionDescription is initial
  
{
  key CompanyCode.CompanyCode                                          as CompanyCode,
  Version.EmbeddedSwVersionStatusDesc                                  as EmbeddedSwVersionStatusDesc,
  Version.ObjectName                                                   as ObjectName,
  Version.Version                                                      as Version,
  case
    when CompanyCode.VATRegistration = '' then
      cast( $parameters.P_VATRegistration as stceg )
    else
      CompanyCode.VATRegistration
  end                                                                  as VATRegistration,
  case
    when CompanyCode.VATRegistration <> '' then
      concat('00', substring(CompanyCode.VATRegistration, 3, 18 ) )
    else 
      cast( concat('00', $parameters.P_VATRegistration ) as stceg )
  end                                                                  as ReportingVATRegistration,
  $parameters.P_CompanyCodeName                                        as CompanyCodeName,
  CompanyCode._Address.StreetName                                      as StreetName,
  CompanyCode._Address.HouseNumber                                     as HouseNumber,                               
  CompanyCode._Address.CityName                                        as CityName,
  CompanyCode._Address.Country                                         as Country,
  CompanyCode._Address._DefaultPhoneNumber.PhoneNumber                 as PhoneNumber,
  case $parameters.P_IsTestRun 
    when 'X' then
      cast( '' as fis_cpdat )
    else
      cast( $session.system_date as fis_cpdat )                                   
  end                                                                  as CreationDate
  
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESS",
"I_ADDRESSPHONENUMBER",
"I_COMPANYCODE",
"I_SAFTPRODUCTVERSION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/