C_RFM_MngSlsDocHdrIncompltn

@AbapCatalog.sqlViewName: 'CRFMSDHINC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.updateEnabled: true
@EndUserText.label: 'Header Details for Mass Incompletion'
@VDM.viewType: #CONSUMPTION
define view C_RFM_MngSlsDocHdrIncompltn
  as select from I_SDDocumentIncompletionLog as Incompletion
    inner join   I_RFM_IncompletionTableTxt  as _IncompletionTableTxt on _IncompletionTableTxt.SDDocumentTable = Incompletion.SDDocumentTable
    inner join   I_RFM_IncompletionTxt       as _IncompletionTxt      on _IncompletionTxt.SlsDocIncompletionCode = Incompletion.SDDocumentTableField
    inner join I_SalesDocumentBasic as SalesDocument
   on Incompletion.SDDocument = SalesDocument.SalesDocument
{
      @EndUserText.label: 'Sales Document'
      @ObjectModel.readOnly: true
  key SDDocument                     as SalesOrder,
  key SDDocumentItem,
  key ScheduleLine,
  key cast(PartnerFunction as parvw) as SlsDistrictDeviatedPartFunc,
  key SDDocumentTextID,
      @ObjectModel.text.element: ['SlsDocIncompletionTableName']
      @UI.textArrangement: #TEXT_FIRST
      @ObjectModel.readOnly: true
  key Incompletion.SDDocumentTable,
      @ObjectModel.text.element: ['SlsDocIncompletionFieldName']
      @UI.textArrangement: #TEXT_FIRST
      @ObjectModel.readOnly: true
  key SDDocumentTableField,
      @Semantics.text:true
      _IncompletionTableTxt.SlsDocIncompletionTableName,
      @Semantics.text:true
      _IncompletionTxt.SlsDocIncompletionFieldName,
      @Consumption.valueHelpDefinition: [{entity.name:      'C_SlsOrdIncompltnFieldVH',
                                          entity.element:   'SalesOrderFieldValue',
                                          additionalBinding: [{ element:      'SDDocumentTable',
                                                                localElement: 'SDDocumentTable',
                                                                usage:        #FILTER },
                                                                { element:      'SDDocumentTableField',
                                                                localElement: 'SDDocumentTableField',
                                                                usage:        #FILTER } ]
                                                                }]
      @Consumption.filter : { selectionType : #SINGLE, multipleSelections : false }
      @EndUserText.label: 'Field Value'
      cast('' as char50)             as SalesOrderFieldValue,
      SalesDocumentType,
      SalesOrganization,
      DistributionChannel,
      OrganizationDivision
}
where
       SDDocumentItem               = '000000'
  and(
       Incompletion.SDDocumentTable = 'VBKD'
    or Incompletion.SDDocumentTable = 'VBAK'
    or Incompletion.SDDocumentTable = 'VEDA'
    or Incompletion.SDDocumentTable = 'VBAP'
    or Incompletion.SDDocumentTable = 'VBKA'
    or Incompletion.SDDocumentTable = 'VBEP'
    or Incompletion.SDDocumentTable = 'VBPA'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RFM_INCOMPLETIONTABLETXT",
"I_RFM_INCOMPLETIONTXT",
"I_SALESDOCUMENTBASIC",
"I_SDDOCUMENTINCOMPLETIONLOG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/