C_RFDYSalesOrder

@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CRFDYSO'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations:  [ '_RFDYSalesOrderItem', '_SoldToParty', '_ShipToParty' ]
@ObjectModel.usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
}
@EndUserText.label: 'Release for Delivery Sales Order'
define view C_RFDYSalesOrder
  as select from I_SalesOrder
  association [1..*] to C_RFDYSalesOrderItem      as _RFDYSalesOrderItem       on $projection.SalesOrder = _RFDYSalesOrderItem.SalesOrder
  association [0..1] to I_Customer                as _ShipToParty              on $projection.ShipToParty = _ShipToParty.Customer
  association [0..*] to I_SalesDocumentTypeText   as _SalesOrderTypeText       on $projection.SalesOrderType = _SalesOrderTypeText.SalesDocumentType
  association [0..*] to I_SalesOrganizationText   as _SalesOrganizationText    on $projection.SalesOrganization = _SalesOrganizationText.SalesOrganization
  association [0..*] to I_DistributionChannelText as _DistributionChannelText  on $projection.DistributionChannel = _DistributionChannelText.DistributionChannel
  association [0..*] to I_DivisionText            as _OrganizationDivisionText on $projection.OrganizationDivision = _OrganizationDivisionText.Division
  association [0..*] to I_ShippingConditionText   as _ShippingConditionText    on $projection.ShippingCondition = _ShippingConditionText.ShippingCondition

  //  association [1..1] to C_RFDYSalesOrderConfirmation as _RFDYSalesOrderConfirmation on $projection.RFDYRequirementUUID = _RFDYSalesOrderConfirmation.RFDYRequirementUUID

{
  key SalesOrder,

      @ObjectModel.text.association: '_SalesOrderTypeText'
      SalesOrderType,

      // Sales Area

      @ObjectModel.text.association: '_SalesOrganizationText'
      SalesOrganization,
      @ObjectModel.text.association: '_DistributionChannelText'
      DistributionChannel,
      @ObjectModel.text.association: '_OrganizationDivisionText'
      OrganizationDivision,

      SalesOrderDate,

      @Consumption.valueHelpDefinition: null
      @ObjectModel.text.association: '_SoldToParty'
      SoldToParty,
      @ObjectModel.readOnly: true
      @ObjectModel.text.association: '_ShipToParty'
      _Partner[PartnerFunction='WE'].Customer as ShipToParty,


      PurchaseOrderByCustomer,
      @ObjectModel.text.association: '_ShippingConditionText'
      ShippingCondition,

      _RFDYSalesOrderItem,

      _SalesOrderType,
      _SalesOrderTypeText,
      _SalesOrganization,
      _SalesOrganizationText,
      _DistributionChannel,
      _DistributionChannelText,
      _OrganizationDivision,
      _OrganizationDivisionText,
      _SoldToParty,
      _ShipToParty,
      _ShippingCondition,
      _ShippingConditionText

      //      _RFDYSalesOrderConfirmation

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDER",
"I_SALESORDERPARTNER"
],
"ASSOCIATED":
[
"C_RFDYSALESORDERITEM",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISION",
"I_DIVISIONTEXT",
"I_SALESDOCUMENTTYPETEXT",
"I_SALESORDERTYPE",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONTEXT",
"I_SHIPPINGCONDITION",
"I_SHIPPINGCONDITIONTEXT"
],
"BASE":
[
"I_SALESORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/