@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Contract Conditions'
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {
dataClass: #MASTER,
serviceQuality: #C,
sizeCategory: #L
}
@Metadata.allowExtensions: true
define view entity C_REValnMngConditionTP
as projection on R_REContrConditionTP
{
key REConditionUUID,
@UI.hidden: true
key InternalRealEstateNumber,
@UI.hidden: true
REStatusObjectCalculation,
@Consumption.semanticObject: #(SemanticObject)
@Consumption.semanticObjectMapping : {
element: 'REStatusObjectIDCalculation',
additionalBinding: [{ element: 'REContract', localElement: 'RealEstateContract' }] }
@Consumption.valueHelpDefinition: [{ entity : {name: 'C_REContractObjAssgmtVH', element: 'REIdentification'},
additionalBinding: [{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER }] }]
@ObjectModel.text.element: ['REStatusObjectIDCalculation'] // needed for drop down in smart table
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_F6170_VALMCD_CALC_EXIT'
virtual REStatusObjectIDCalculation : recaident,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_F6170_VALMCD_CALC_EXIT'
virtual SemanticObject : char40,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_REConditionTypeForContrVH', element: 'REConditionType'},
additionalBinding: [
{ element: 'REConditionGroup', localElement: 'REConditionGroup', usage: #FILTER },
{ element: 'REContractType', localElement: 'REContractType', usage: #FILTER },
{ element: 'REConditionTypeName', localElement: 'REConditionTypeName', usage: #RESULT}
] } ]
@ObjectModel.text.element: ['REConditionTypeName']
// @Search.defaultSearchElement: true
// @Search.ranking: #HIGH
// @Search.fuzzinessThreshold : 0.7
REConditionType,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_REConditionPurposeExtStdVH', element: 'REExtConditionPurpose' },
additionalBinding: [{ element: 'REExtConditionPurpose_Text', localElement: 'RECndnPurposeExtName', usage: #RESULT }] }]
@ObjectModel.text.element: ['RECndnPurposeExtName']
REExtConditionPurpose,
@UI.hidden: true
ValidityStartEndDateValue,
ValidityStartDate,
/*
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_REContractObjAssgmtVH',
element: 'REStatusObjectTarget' },
label: 'Calculation Object Value Help',
additionalBinding: [
{ element: 'InternalRealEstateNumber',
localElement: 'InternalRealEstateNumber',
usage: #FILTER }
] } ]
@ObjectModel.text.element: ['REIdentificationDist']
*/
@UI.hidden: true
REStatusObjectDistribution,
// @ObjectModel.text.element: ['REStatusObjectDistribution']
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_F6170_VALMCD_CALC_EXIT'
virtual REStatusObjectIDDistribution : recaident,
@ObjectModel.text.element: ['REObjectTypeDistributionName']
REObjectTypeDistribution,
@ObjectModel.text.element: ['REObjectTypePostingName']
REObjectTypePosting,
ValidityEndDate,
CreatedByUser,
CreationDateTime,
RESourceOfCreation,
LastChangedByUser,
LastChangeDateTime,
RESourceOfChange,
REIsOneTimeCondition,
REConditionIsStatistical,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber'},
additionalBinding: [{ element: 'RETermType', localConstant: '1100', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'REPostingTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['REPostingTermName']
REPostingTerm,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber'},
additionalBinding: [ { element: 'RETermType', localConstant: '1110', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'RERhythmTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['RERhythmTermName']
RERhythmTerm,
REAdjustmentNumber,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber' },
additionalBinding: [{ element: 'RETermType', localConstant: '1120', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'REOrglAssgmtTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['REOrglAssgmtTermName']
REOrglAssignmentTerm,
RESalesTerm,
REPeakSalesTerm,
RESrvcChrgSettlementPostingTrm,
REWithholdingTaxTerm,
@Consumption.valueHelpDefinition: [{
entity : {name: 'I_RECndnCalcRuleExtStdVH', element: 'RECalculationRule' } ,
additionalBinding: [{ element: 'RECalculationRule_Text', localElement: 'REConditionAttributeName', usage: #RESULT } ] } ]
@ObjectModel.text.element: ['REConditionAttributeName']
RECalculationRule,
REUnitPrice,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CurrencyStdVH', element: 'Currency' },
additionalBinding: [{ element: 'Currency_Text', localElement: 'CurrencyName', usage: #RESULT }] } ]
@ObjectModel.text.element: ['CurrencyName']
REConditionCurrency,
@UI.hidden: true
RECalculationRuleParam1,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_REMeasurementTypeStdVH', element: 'REMeasurementType' } } ]
@ObjectModel.editableFieldFor: 'RECalculationRuleParam1'
REMeasurementTypeForEdit,
@UI.hidden: true
RECalculationRuleParam2,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
@ObjectModel.editableFieldFor: 'RECalculationRuleParam2'
REMeasurementUnitForEdit,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_RECndnDistrRuleExtStdVH', element: 'REDistributionRule' },
additionalBinding: [{ element: 'REDistributionRule_Text', localElement: 'REDistributionRuleName', usage: #RESULT }] } ]
@ObjectModel.text.element: ['REDistributionRuleName']
REDistributionRule,
@EndUserText.label: 'Distribution Formula Parameter 1'
@UI.hidden: true
REDistributionRuleParam1,
@EndUserText.label: 'Distribution Formula Parameter 2'
@UI.hidden: true
REDistributionRuleParam2,
@ObjectModel.text.element: ['REReasonForChgName']
// @Search.defaultSearchElement: true
// @Search.fuzzinessThreshold : 0.7
REReasonForChange,
REStsObjectParamCalculation,
REStsObjectParamDistribution,
RECashFlowPostingFromDate,
@ObjectModel.text.element: ['REEntryValidityText']
@Consumption.valueHelpDefinition: [{ entity: {name: 'I_REEntryValidity', element: 'REEntryValidity' } }]
REEntryValidity,
@UI.hidden: true
REEntryValidityCriticality,
/* NOT IN USE anymore since switchig to Identification entry
@UI.hidden: true
_REConditionAddl.REIdentificationCalc,
@UI.hidden: true
_REConditionAddl.REIdentificationDist,
*/
@UI.hidden: true
_REContract._REContractType.REConditionGroup as REConditionGroup,
@UI.hidden: true
_REContract.REContractType as REContractType,
@UI.hidden: true
_REContract.CompanyCode as CompanyCode,
@UI.hidden: true
_REContract.RealEstateContract as RealEstateContract,
@UI.hidden: true
REPostingTermType,
@UI.hidden: true
_REContrCndnSelPostingTerm.RETermName as REPostingTermName,
@UI.hidden: true
RERhythmTermType,
@UI.hidden: true
_REContrCndnSelRhythmTerm.RETermName as RERhythmTermName,
@UI.hidden: true
REOrglAssgmtTermType,
@UI.hidden: true
_REContrCndnSelOrglAssgmtTerm.RETermName as REOrglAssgmtTermName,
// @Search.defaultSearchElement: true
// @Search.ranking: #HIGH
// @Search.fuzzinessThreshold : 0.7
@UI.hidden: true
_REConditionTypeText.REConditionTypeName as REConditionTypeName : localized,
@UI.hidden: true
_RECndnPurposeExtText.RECndnPurposeExtName as RECndnPurposeExtName : localized,
@UI.hidden: true
_REObjectTypeDistribution._Text.REObjectTypeDistributionName as REObjectTypeDistributionName : localized,
@UI.hidden: true
_REObjectTypePosting._Text.REObjectTypePostingName as REObjectTypePostingName : localized,
@UI.hidden: true
_RECndnCalculationRuleExtText.REConditionAttributeName as REConditionAttributeName : localized,
@UI.hidden: true
_CurrencyText.CurrencyName as CurrencyName : localized,
@UI.hidden: true
_RECndnDistrRuleExtText.REDistributionRuleName as REDistributionRuleName : localized,
// @Search.defaultSearchElement: true
// @Search.ranking: #HIGH
// @Search.fuzzinessThreshold : 0.7
@UI.hidden: true
_RECndnChangeReasonText.REReasonForChgName as REReasonForChgName : localized,
@UI.hidden: true
_REEntryValidity._Text.REEntryValidityText as REEntryValidityText : localized,
_REContract : redirected to parent C_REValuationManageTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENCYTEXT",
"I_RECNDNCALCULATIONRULEEXTTEXT",
"I_RECNDNCHANGEREASONTEXT",
"I_RECNDNDISTRRULEEXTTEXT",
"I_RECNDNPURPOSEEXTTEXT",
"I_RECONDITIONTYPETEXT",
"I_RECONTRACTTYPE",
"I_REENTRYVALIDITY",
"I_REENTRYVALIDITYTEXT",
"I_REOBJECTTYPEDISTRIBUTION",
"I_REOBJECTTYPEDISTRIBUTIONTEXT",
"I_REOBJECTTYPEPOSTING",
"I_REOBJECTTYPEPOSTINGTEXT",
"I_RETERM",
"R_RECONTRACTTP",
"R_RECONTRCONDITIONTP"
],
"ASSOCIATED":
[
"C_REVALUATIONMANAGETP",
"R_RECONTRACTTP"
],
"BASE":
[
"R_RECONTRCONDITIONTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/