@AccessControl.authorizationCheck: #CHECK
//@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {
dataClass: #MASTER,
serviceQuality: #C,
sizeCategory: #L
}
@EndUserText.label: 'RE Contract Condition'
@Metadata.allowExtensions: true
//@Search.searchable: true
define view entity C_REContractConditionTP
as projection on R_REContrConditionTP
association [0..*] to C_REContractConditionCalc as _REContractConditionCalc on $projection.REConditionUUID = _REContractConditionCalc.REConditionUUID
association [0..*] to C_REContractConditionDistr as _REContractConditionDistr on $projection.REConditionUUID = _REContractConditionDistr.REConditionUUID
{
@UI.hidden: true
key REConditionUUID,
@UI.hidden: true
key InternalRealEstateNumber,
@UI.hidden: true
REStatusObjectCalculation,
@Consumption.valueHelpDefinition: [{ entity : {name: 'C_REContractObjAssgmtVH', element: 'REIdentification'},
additionalBinding: [{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER }] }]
@ObjectModel.text.element: ['REStatusObjectIDCalculation'] // needed for drop down in smart table
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECA_VDM_OBJECT_CALC_EXIT'
REStatusObjectIDCalculation,
@UI.hidden: true
REStatusObjectTypeCalculation,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_REConditionTypeForContrVH', element: 'REConditionType'},
additionalBinding: [
{ element: 'REConditionGroup', localElement: 'REConditionGroup', usage: #FILTER },
{ element: 'REContractType', localElement: 'REContractType', usage: #FILTER },
{ element: 'REConditionTypeName', localElement: 'REConditionTypeName', usage: #RESULT}
] } ]
@ObjectModel.text.element: ['REConditionTypeName']
REConditionType,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_REConditionPurposeExtStdVH', element: 'REExtConditionPurpose' },
additionalBinding: [{ element: 'REExtConditionPurpose_Text', localElement: 'RECndnPurposeExtName', usage: #RESULT }] }]
@ObjectModel.text.element: ['RECndnPurposeExtName']
REExtConditionPurpose,
@UI.hidden: true
ValidityStartEndDateValue,
ValidityStartDate,
@UI.hidden: true
REStatusObjectDistribution,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECA_VDM_OBJECT_CALC_EXIT'
REStatusObjectIDDistribution,
@ObjectModel.text.element: ['REObjectTypeDistributionName']
REObjectTypeDistribution,
@ObjectModel.text.element: ['REObjectTypePostingName']
REObjectTypePosting,
ValidityEndDate,
CreatedByUser,
CreationDateTime,
RESourceOfCreation,
LastChangedByUser,
LastChangeDateTime,
RESourceOfChange,
REIsOneTimeCondition,
REConditionIsStatistical,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber'},
additionalBinding: [{ element: 'RETermType', localConstant: '1100', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'REPostingTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['REPostingTermName']
REPostingTerm,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber'},
additionalBinding: [ { element: 'RETermType', localConstant: '1110', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'RERhythmTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['RERhythmTermName']
RERhythmTerm,
REAdjustmentNumber,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_RETermForContractVH', element: 'RETermNumber' },
additionalBinding: [{ element: 'RETermType', localConstant: '1120', usage: #FILTER },
{ element: 'InternalRealEstateNumber', localElement: 'InternalRealEstateNumber', usage: #FILTER },
{ element: 'RETermName', localElement: 'REOrglAssgmtTermName', usage: #RESULT }] }]
@ObjectModel.text.element: ['REOrglAssgmtTermName']
REOrglAssignmentTerm,
RESalesTerm,
REPeakSalesTerm,
RESrvcChrgSettlementPostingTrm,
REWithholdingTaxTerm,
@Consumption.valueHelpDefinition: [{
entity : {name: 'I_RECndnCalcRuleExtStdVH', element: 'RECalculationRule' } ,
additionalBinding: [{ element: 'RECalculationRule_Text', localElement: 'REConditionAttributeName', usage: #RESULT } ] } ]
@ObjectModel.text.element: ['REConditionAttributeName']
RECalculationRule,
REUnitPrice,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_CurrencyStdVH', element: 'Currency' },
additionalBinding: [{ element: 'Currency_Text', localElement: 'CurrencyName', usage: #RESULT }] } ]
@ObjectModel.text.element: ['CurrencyName']
REConditionCurrency,
@UI.hidden: true
RECalculationRuleParam1,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_REMeasurementTypeStdVH', element: 'REMeasurementType' } } ]
@ObjectModel.editableFieldFor: 'RECalculationRuleParam1'
REMeasurementTypeForEdit,
@UI.hidden: true
RECalculationRuleParam2,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
@ObjectModel.editableFieldFor: 'RECalculationRuleParam2'
REMeasurementUnitForEdit,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_RECndnDistrRuleExtStdVH', element: 'REDistributionRule' },
additionalBinding: [{ element: 'REDistributionRule_Text', localElement: 'REDistributionRuleName', usage: #RESULT }] } ]
@ObjectModel.text.element: ['REDistributionRuleName']
REDistributionRule,
@EndUserText.label: 'Distribution Formula Parameter 1'
@UI.hidden: true
REDistributionRuleParam1,
@EndUserText.label: 'Distribution Formula Parameter 2'
@UI.hidden: true
REDistributionRuleParam2,
@ObjectModel.text.element: ['REReasonForChgName']
// @Search.defaultSearchElement: true
// @Search.fuzzinessThreshold : 0.7
REReasonForChange,
REStsObjectParamCalculation,
REStsObjectParamDistribution,
RECashFlowPostingFromDate,
REConditionExceptionalDueDate,
@ObjectModel.text.element: ['REEntryValidityText']
@Consumption.valueHelpDefinition: [{ entity: {name: 'I_REEntryValidity', element: 'REEntryValidity' } }]
REEntryValidity,
@UI.hidden: true
REEntryValidityCriticality,
@UI.hidden: true
_REContract._REContractType.REConditionGroup as REConditionGroup,
@UI.hidden: true
_REContract.REContractType as REContractType,
@UI.hidden: true
_REContract.CompanyCode as CompanyCode,
@UI.hidden: true
_REContract.RealEstateContract as RealEstateContract,
@UI.hidden: true
REPostingTermType,
@UI.hidden: true
REOrglAssgmtTermType,
@UI.hidden: true
RERhythmTermType,
@UI.hidden: true
_REContrCndnSelPostingTerm.RETermName as REPostingTermName,
@UI.hidden: true
_REContrCndnSelRhythmTerm.RETermName as RERhythmTermName,
@UI.hidden: true
_REContrCndnSelOrglAssgmtTerm.RETermName as REOrglAssgmtTermName,
@UI.hidden: true
_REContrCndnSelPostingTerm.RETermName as REPostingTermPlaceholderName,
@UI.hidden: true
_REContrCndnSelRhythmTerm.RETermName as RERhythmTermPlaceholderName,
@UI.hidden: true
_REContrCndnSelOrglAssgmtTerm.RETermName as REOrglAssTermPlaceholderName,
@UI.hidden: true
_REConditionTypeText.REConditionTypeName as REConditionTypeName : localized,
@UI.hidden: true
_RECndnPurposeExtText.RECndnPurposeExtName as RECndnPurposeExtName : localized,
@UI.hidden: true
_REObjectTypeDistribution._Text.REObjectTypeDistributionName as REObjectTypeDistributionName : localized,
@UI.hidden: true
_REObjectTypePosting._Text.REObjectTypePostingName as REObjectTypePostingName : localized,
@UI.hidden: true
_RECndnCalculationRuleExtText.REConditionAttributeName as REConditionAttributeName : localized,
@UI.hidden: true
_CurrencyText.CurrencyName as CurrencyName : localized,
@UI.hidden: true
_RECndnDistrRuleExtText.REDistributionRuleName as REDistributionRuleName : localized,
@UI.hidden: true
_RECndnChangeReasonText.REReasonForChgName as REReasonForChgName : localized,
@UI.hidden: true
_REEntryValidity._Text.REEntryValidityText as REEntryValidityText : localized,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual IsDraftEntity : recabool,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual RECndnParamMsmtTypeIsHidden : recabool,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual RECndnParamMsmtUnitIsHidden : recabool,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual RECndnDistrRuleExtIsHidden : recabool,
@UI.hidden: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual RECndnExcptnDueDateIsHidden : recabool,
@UI.hidden: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RECN_CONDITION_CALC_EXIT'
virtual NoteUUID : /bobf/conf_key,
_Currency,
_CreatedByUser,
_ChangedByUser,
_REConditionType,
_REConditionPurposeExt,
_REObjectTypeDistribution,
_REObjectTypePosting,
_RECndnCalculationRuleExt,
_RECndnDistributionRuleExt,
_REConditionChangeReason,
_REContractConditionCalc,
_REContractConditionDistr,
_REContract : redirected to parent C_REContractTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENCYTEXT",
"I_RECNDNCALCULATIONRULEEXTTEXT",
"I_RECNDNCHANGEREASONTEXT",
"I_RECNDNDISTRRULEEXTTEXT",
"I_RECNDNPURPOSEEXTTEXT",
"I_RECONDITIONTYPETEXT",
"I_RECONTRACTTYPE",
"I_REENTRYVALIDITY",
"I_REENTRYVALIDITYTEXT",
"I_REOBJECTTYPEDISTRIBUTION",
"I_REOBJECTTYPEDISTRIBUTIONTEXT",
"I_REOBJECTTYPEPOSTING",
"I_REOBJECTTYPEPOSTINGTEXT",
"I_RETERM",
"R_RECONTRACTTP",
"R_RECONTRCONDITIONTP"
],
"ASSOCIATED":
[
"C_RECONTRACTCONDITIONCALC",
"C_RECONTRACTCONDITIONDISTR",
"C_RECONTRACTTP",
"I_CURRENCY",
"I_RECNDNCALCULATIONRULEEXT",
"I_RECNDNDISTRIBUTIONRULEEXT",
"I_RECONDITIONCHANGEREASON",
"I_RECONDITIONPURPOSEEXT",
"I_RECONDITIONTYPE",
"I_REOBJECTTYPEDISTRIBUTION",
"I_REOBJECTTYPEPOSTING",
"I_USER",
"R_RECONTRACTTP"
],
"BASE":
[
"R_RECONTRCONDITIONTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/