C_RAMnlRevnSprdgByPeriodTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'RA Manual Spreading By Period'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #MIXED
}

@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

define view entity C_RAMnlRevnSprdgByPeriodTP
  as select from P_RAMnlRevnSprdgByPeriodTP as _SprdgByPeriodTP

  association        to parent C_RAPerfOblgnManualSpreadingTP as _PerformanceObligation on  $projection.RevenueAccountingContract = _PerformanceObligation.RevenueAccountingContract
                                                                                        and $projection.PerformanceObligation     = _PerformanceObligation.PerformanceObligation

  association [1..1] to C_RAContrManualSpreadingTP            as _Contract              on  $projection.RevenueAccountingContract = _Contract.RevenueAccountingContract

{
  key _SprdgByPeriodTP.RevenueAccountingContract,
  key _SprdgByPeriodTP.PerformanceObligation,
  key _SprdgByPeriodTP.FiscalYear,
  key _SprdgByPeriodTP.FiscalPeriod,

      @Semantics.fiscal.yearPeriod: true
      cast(  concat(FiscalYear,FiscalPeriod) as fis_tojahrper_c_no_conv)                      as FiscalYearPeriodCompoundText,


      CompanyCode,

      AccountingPrinciple,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      @EndUserText: { label: 'Previous Manual Spreading '}
      cast ( FulfilledAmountInSlsDocCrcy as farr_mnlsprdg_prev_mnl_sprdg preserving type)     as FulfilledAmountInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast ( DeltaRecognizedAmtInSlsDocCrcy + RecgdCatchUpAmtInSlsDocCrcy
      as farr_mnlsprdg_recgbl_revenue )                                                       as DeltaRecognizedAmtInSlsDocCrcy,
      
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      @EndUserText: { label: 'Revenue Catch-up '}
      RecgdCatchUpAmtInSlsDocCrcy,

      @ObjectModel.editableFieldFor: 'DeltaRecognizedAmtInSlsDocCrcy'
      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      @EndUserText: { label: 'New Recognizable Revenue '}
      cast ( DeltaRecognizedAmtInSlsDocCrcy + RecgdCatchUpAmtInSlsDocCrcy 
      as farr_mnlsprdg_new_recgbl_rev ) as DeltaRecgdAmtInSlsDocCrcyFoEd,

      case when SalesDocumentCurrency = _PerformanceObligation.SalesDocumentCurrency
        then
          SalesDocumentCurrency
        else
          _PerformanceObligation.SalesDocumentCurrency
        end                                                                                   as SalesDocumentCurrency,

      @Semantics.quantity.unitOfMeasure: 'FulfilledQuantityUnit'
      @EndUserText: { label: 'Fulfilled Quantity '}
      cast(ReportedFulfilledQuantity as farr_cds_quantity)                                    as ReportedFulfilledQuantity,

      case when FulfilledQuantityUnit = _PerformanceObligation.PerfOblgnEffectiveQuantityUnit
      then
        FulfilledQuantityUnit
      else
         _PerformanceObligation.PerfOblgnEffectiveQuantityUnit
      end                                                                                     as FulfilledQuantityUnit,


      cast (
      case
       when NotEditableSplit = 'X' or NotEditablePeriod = 'X'
         then
            ' '
         else
           'X'
       end         as farr_revninfyperdiseditable               )                             as RevnInFYPerdIsEditable,

      _PerformanceObligation,
      _Contract

}
where
      _PerformanceObligation.PerfOblgnIsSoftDeleted   =  ''
  and _PerformanceObligation.PerfOblgnFulfillmentType =  'T'
  and _PerformanceObligation.RAPerfOblgnCategory      <> 'C'
  and _PerformanceObligation.RAPerfOblgnDistinctType  =  'D'
//  and _Contract.RAContractIsCreatedByContrMgr        =  'X'

//  and _Contract.RAContractHasAssetsImpairment <> 'X'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_RAPERFOBLGNMANUALSPREADINGTP",
"P_RAMNLREVNSPRDGBYPERIODTP"
],
"ASSOCIATED":
[
"C_RACONTRMANUALSPREADINGTP",
"C_RAPERFOBLGNMANUALSPREADINGTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/