C_QltyTskProcProcsrNotes

@AbapCatalog.sqlViewName: 'CQLTYTSKPROCPN'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Quality Task Processor Notes'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    dataCategory: #TEXT,
    representativeKey: 'QualityTaskInternalId',
    usageType: {
        dataClass: #MIXED,
        sizeCategory: #L,
        serviceQuality: #C },
// Begin Draft 2.0

    compositionRoot: false,
    transactionalProcessingDelegated: true,
    draftEnabled:  true,
    createEnabled: false,
    updateEnabled: true,
    deleteEnabled: false    
}

define view C_QltyTskProcProcsrNotes as select from I_QualityTaskLongTextTP 

    association [1..1] to C_QualityTaskProcess as _QualityTaskProcess on $projection.QualityTaskInternalId = _QualityTaskProcess.QualityTaskInternalId

{
//=== Key Fields

        @UI.hidden: true 
        @ObjectModel: { foreignKey.association: '_QualityTaskProcess' }
        key QualityTaskInternalId, 
        @UI.hidden: true 
        key Language, 
        @UI.hidden: true 
        key ItemCounter,
        
//=== Common Fields

        @UI.hidden: true 
        LongTextID, 
        
        @UI.multiLineText: true
        @EndUserText: { label: 'Processor Notes', quickInfo: 'Processor Notes' }        
        //casting is not possible for source type STRING -> define the label via annotation

        QualityTaskLongText as QualityTaskProcessorNotes,

        @ObjectModel: {  
            readOnly: true,
            virtualElement: true,
            virtualElementCalculatedBy: 'ABAP:cl_qm_task_proc_calc_exit'
       }
       cast ( ' ' as vdm_qltytaskprocsrnotespreview ) as QualityTaskProcsrNotesPreview,

//=== Administrative Fields        

        @UI.hidden: true 
        LongTextCreatedByUser, 
        @UI.hidden: true 
        LongTextCreatedAt, 
        @UI.hidden: true 
        LongTextLastChangedByUser, 
        @UI.hidden: true        
        LongTextLastChangedAt, 
        
//=== Expose associations

        _Language, 
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _QualityTaskProcess     
           
}   where ItemCounter = 1 and LongTextID = 'LTPN'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_QUALITYTASKLONGTEXTTP"
],
"ASSOCIATED":
[
"C_QUALITYTASKPROCESS",
"I_LANGUAGE"
],
"BASE":
[
"I_QUALITYTASKLONGTEXTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/