C_Q2CCustomerQuickView

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Customer'

@VDM: {
  viewType: #CONSUMPTION
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:
{ usageType: {
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER } }

@UI.headerInfo:{
  imageUrl:             'BusinessPartnerImageURL',
  title: {
     type:  #STANDARD,
     value: 'CustomerName'
   },
   description: {
     type:   #STANDARD,
     value:  'Customer'
   }
}

@ObjectModel.representativeKey: 'Customer'

define view entity C_Q2CCustomerQuickView
  as select from I_Customer as customer
{

      @UI.facet: [ {
          purpose:    #QUICK_VIEW,
          type:       #FIELDGROUP_REFERENCE,
          targetQualifier: 'CustomerQuickView',
          label: 'Standard Address'
        }
      ]

      @EndUserText.label : 'Customer'
      @ObjectModel.text.element:  [ 'CustomerName' ]
  key customer.Customer,
      @Consumption.hidden: true
      customer.AddressID,

      @EndUserText.label : 'Name'
      @Semantics.text:true
      @Semantics.name.fullName: true
      customer.CustomerName,

      @UI.hidden: true
      @Semantics.imageUrl: true
      cast (
      case
      when _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory  = '1'
      then 'sap-icon://customer'

      else  'sap-icon://building'

      end  as abap.sstring( 500 ) ) as BusinessPartnerImageURL,

      @UI: {
      fieldGroup:     [{ qualifier:'CustomerQuickView', position: 10}]}
      @Semantics.address.zipCode:true
      customer._AddressDefaultRepresentation.PostalCode,

      @UI: {
      fieldGroup:     [{ qualifier:'CustomerQuickView', position: 20}]}
      @Semantics.address.city:true
      customer._AddressDefaultRepresentation.CityName,

      @UI: {
      fieldGroup:     [{ qualifier:'CustomerQuickView', position: 30}]}
      @Semantics.address.country:true
      customer._AddressDefaultRepresentation.Country,

      @UI.hidden: true
      customer.OrganizationBPName1,

      @UI.hidden: true
      customer.OrganizationBPName2,

      //    DCL relevant fields

      @Consumption.hidden: true
      customer.CustomerAccountGroup,
      @Consumption.hidden: true
      customer.AuthorizationGroup,
      @Consumption.hidden: true
      @Semantics.booleanIndicator: true
      customer.IsBusinessPurposeCompleted,

      //Added for DPP Data Controller

      @Consumption.hidden:true
      customer.DataControllerSet,
      @Consumption.hidden:true
      customer.DataController1,
      @Consumption.hidden:true
      customer.DataController2,
      @Consumption.hidden:true
      customer.DataController3,
      @Consumption.hidden:true
      customer.DataController4,
      @Consumption.hidden:true
      customer.DataController5,
      @Consumption.hidden:true
      customer.DataController6,
      @Consumption.hidden:true
      customer.DataController7,
      @Consumption.hidden:true
      customer.DataController8,
      @Consumption.hidden:true
      customer.DataController9,
      @Consumption.hidden:true
      customer.DataController10
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CUSTOMER",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_ORGANIZATIONADDRESS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/