C_PurchaseOrderSpend

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions: true
@AbapCatalog.sqlViewName: 'CMMPURORDSPND' 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED 
@EndUserText.label: 'Purchase Order Spend'
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PROVIDER  ]
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
define view C_PurchaseOrderSpend 

  with parameters
  
    P_DisplayCurrency           : displaycurrency,
       
    P_StartDate: bedat,
    
    P_EndDate: bedat   
    
  as select from    P_PurOrdItemAcctAssgmt( P_DisplayCurrency: $parameters.P_DisplayCurrency,
                                            P_StartDate : $parameters.P_StartDate,
                                            P_EndDate : $parameters.P_EndDate ) as P_PurOrdItmAcctAssgmt

  left outer join I_PurchasingCategoryMatlGroup                                                               as PurchasingCategoryMatlGroup on P_PurOrdItmAcctAssgmt.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup

  association [1..1] to P_Purordmaintaincustproj   as _WBSElement                 on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [1..1] to I_Material                 as _MaterialText               on $projection.Material = _MaterialText.Material
  association [1..1] to I_MaterialGroup            as _MaterialGroup              on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [1..1] to I_PurchasingDocumentStatus as _PurchasingDocumentStatus   on $projection.PurchasingDocumentStatus = _PurchasingDocumentStatus.PurchasingDocumentStatus
  association [1..1] to I_Country                  as _Country                    on $projection.SupplierCountry = _Country.Country
 
{
      /* Keys */
  key cast(P_PurOrdItmAcctAssgmt.PurchaseOrder as vdm_purchaseorder)                                                           as PurchaseOrder,
  key cast(PurchaseOrderItem as vdm_purchaseorderitem)                                                   as PurchaseOrderItem,
  key AccountAssignmentNumber,
      
      PurgCatUUID,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
       @ObjectModel.foreignKey.association: '_Country'
      SupplierCountry,           
      
      /* Order Date */
      
      PurchaseOrderDate,
      @Semantics.calendar.year: true
      CalendarYear,
      CalendarQuarter,
      CalendarMonth,
      CalendarWeek,
      YearQuarter,

      /* Header */
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_PurchasingDocumentStatus'
      PurchasingDocumentStatus,
      
      /* Item Data */
      @ObjectModel.foreignKey.association: '_MaterialText'
      Material,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      P_PurOrdItmAcctAssgmt.MaterialGroup,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
            
      ProductType                                                                        as ProductTypeCode,

      @VDM.lifecycle.status:#DEPRECATED
      @VDM.lifecycle.successor:'ProductTypeCode'
      cast ( ProductType as producttype)                                                 as ProductType,
      
      ServicePerformer,
      
      PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory                                 as PurchasingCategory,
      _PurchasingCategory.PurgCatName                                                                    as PurgCatName,
      
      WBSElementInternalID,
      WBSElement,
      WBSDescription,
      _WBSElement.CustomerProjectName,
      _WBSElement.CustProjWorkPackageName,
      
      CostCenter,
      @Semantics.currencyCode: true
      cast( :P_DisplayCurrency as displaycurrency )                                                      as DisplayCurrency,

      /* Order Amount*/
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      @DefaultAggregation: #SUM                             //3000972

      PurOrdNetAmountInDisplayCrcy ,
      
      _Plant,
      _PurchasingGroup,
      _PurchasingOrganization,
      _PurchasingDocumentStatus,
      _Supplier,
      _MaterialGroup,
      _MaterialText,
      _Country
      
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"P_PURORDITEMACCTASSGMT",
"P_PURORDMAINTAINCUSTPROJ"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASINGDOCUMENTSTATUS",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"P_PURORDMAINTAINCUSTPROJ"
],
"BASE":
[
"P_PURORDITEMACCTASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/