C_PurchaseOrderItemDEX

@AbapCatalog.sqlViewName: 'CMMPOITMDX'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl:{
                 authorizationCheck: #CHECK,
                 personalData.blocking: #BLOCKED_DATA_EXCLUDED
                }
@EndUserText.label: 'Data Extraction View for PO Item'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel :{ usageType.dataClass: #TRANSACTIONAL,
                usageType.sizeCategory: #L,
                usageType.serviceQuality: #D,
                supportedCapabilities: #EXTRACTION_DATA_SOURCE
                }

@VDM.viewType : #CONSUMPTION
@ObjectModel.representativeKey: [ 'PurchaseOrderItem' ]
@Metadata.ignorePropagatedAnnotations:true

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Analytics: {
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
            mapping:[
                {
                    table: 'ekpo', role: #MAIN,
                    viewElement: ['PurchaseOrder', 'PurchaseOrderItem'],
                    tableElement: ['ebeln', 'ebelp']
                },
                {
                    table: 'ekko', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['PurchaseOrder'],
                    tableElement: ['ebeln']}
            ]
        }
    }
    }

define view C_PurchaseOrderItemDEX
  as select from           I_PurchaseOrderItemAPI01 as item
    left outer to one join I_CompanyCode            as CompanyCode on item.CompanyCode = CompanyCode.CompanyCode
  //  association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode


{
      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key item.PurchaseOrder,

  key item.PurchaseOrderItem,

      // PO header fields

      item._PurchaseOrder.PurchaseOrderType        as PurchaseOrderType,

      item._PurchaseOrder.PurchasingGroup          as PurchasingGroup,

      item._PurchaseOrder.PurchasingOrganization   as PurchasingOrganization,

      item._PurchaseOrder.PurchasingDocumentOrigin as PurchasingDocumentOrigin,

      item._PurchaseOrder.Supplier                 as Supplier,

      item._PurchaseOrder.SupplyingSupplier        as SupplyingSupplier,

      item._PurchaseOrder.SupplyingPlant           as SupplyingPlant,

      @Semantics.currencyCode: true
      item._PurchaseOrder.DocumentCurrency         as DocumentCurrency,

      item._PurchaseOrder.ExchangeRate             as ExchangeRate,

      item._PurchaseOrder.InvoicingParty           as InvoicingParty,

      item._PurchaseOrder.PurchaseOrderDate        as PurchaseOrderDate,

      item._PurchaseOrder.ValidityStartDate        as ValidityStartDate,

      item._PurchaseOrder.ValidityEndDate          as ValidityEndDate,

      //PO item

      item.PurchasingDocumentDeletionCode          as PurchasingDocumentDeletionCode,

      item.MaterialGroup                           as MaterialGroup,

      item.Material                                as Material,

      item.ManufacturerMaterial                    as ManufacturerMaterial,

      item.PurchaseOrderCategory                   as PurchaseOrderCategory,

      item.PurchasingOrderReason                   as PurchasingOrderReason,

      item.PurchaseOrderItemText                   as PurchaseOrderItemText,

      item.PurchaseOrderItemCategory               as PurchaseOrderItemCategory,

      CompanyCode.CompanyCode                      as CompanyCode,

      item.Plant                                   as Plant,

      item.StorageLocation                         as StorageLocation,

      item.PurchaseContract                        as PurchaseContract,

      item.PurchaseContractItem                    as PurchaseContractItem,

      @Semantics.unitOfMeasure: true
      item.BaseUnit                                as BaseUnit,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      item.OrderQuantity                           as OrderQuantity,

      @Semantics.unitOfMeasure:true
      item.PurchaseOrderQuantityUnit               as PurchaseOrderQuantityUnit,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      item.NetPriceAmount                          as NetPriceAmount,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      item.NetAmount                               as NetAmount,

      @Semantics.currencyCode: true
      CompanyCode.Currency                         as LocalCurrency,

      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      item.NetPriceQuantity                        as NetPriceQuantity,

      @Semantics.unitOfMeasure: true
      item.OrderPriceUnit                          as OrderPriceUnit,

      item.RequisitionerName                       as RequisitionerName,

      item.RetailPromotion                         as RetailPromotion,

      item.IsCompletelyDelivered                   as IsCompletelyDelivered,
      
      item.IsReturnsItem                           as IsReturnsItem,

      item.IsFinallyInvoiced                       as IsFinallyInvoiced,

      item.InvoiceIsExpected                       as InvoiceIsExpected,

      item.OrderItemQtyToBaseQtyDnmntr             as OrderItemQtyToBaseQtyDnmntr,

      item.OrderItemQtyToBaseQtyNmrtr              as OrderItemQtyToBaseQtyNmrtr,

      item.InvoiceIsGoodsReceiptBased              as InvoiceIsGoodsReceiptBased,

      item.GoodsReceiptIsExpected                  as GoodsReceiptIsExpected,

      item.EvaldRcptSettlmtIsAllowed               as EvaldRcptSettlmtIsAllowed,

      item.AccountAssignmentCategory               as AccountAssignmentCategory,

      item.GoodsReceiptIsNonValuated               as GoodsReceiptIsNonValuated,

      item.MaterialType                            as MaterialType,

      item.OverdelivTolrtdLmtRatioInPct            as OverdelivTolrtdLmtRatioInPct,

      item.ServicePerformer                        as ServicePerformer,

      item.TaxCode                                 as TaxCode,

      item.UnderdelivTolrtdLmtRatioInPct           as UnderdelivTolrtdLmtRatioInPct,

      item.UnlimitedOverdeliveryIsAllowed          as UnlimitedOverdeliveryIsAllowed,

      //Association

      item._PurchaseOrder
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_PURCHASEORDERAPI01",
"I_PURCHASEORDERITEMAPI01"
],
"ASSOCIATED":
[
"I_PURCHASEORDERAPI01"
],
"BASE":
[
"I_PURCHASEORDERITEMAPI01"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/