C_PurOrderItemHistoryValues2

@EndUserText.label: 'Purchase Order Item History Values 2'
@AbapCatalog.sqlViewName: 'CMMPUOITMHISV2'
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@Metadata.allowExtensions:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory:  #L
define view C_PurOrderItemHistoryValues2

  with parameters
    @Consumption.hidden : true
    @Environment.systemField : #SYSTEM_DATE
    P_StartDate       : bedat,
    P_EndDate         : bedat,
    P_DisplayCurrency : displaycurrency


  as select from    P_PurchaseOrderItemHistory1( P_StartDate: $parameters.P_StartDate, P_EndDate: $parameters.P_EndDate, P_DisplayCurrency : $parameters.P_DisplayCurrency)

    left outer join I_CalendarDate                as Calendar                    on P_PurchaseOrderItemHistory1.PurchaseOrderDate = Calendar.CalendarDate

    left outer join I_PurchasingCategoryMatlGroup as PurchasingCategoryMatlGroup on P_PurchaseOrderItemHistory1.MaterialGroup = PurchasingCategoryMatlGroup.MaterialGroup

  association [1..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [1..1] to I_PurchasingGroup        as _PurchasingGroup        on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

  association [1..1] to I_Supplier               as _Supplier               on $projection.Supplier = _Supplier.Supplier

  association [1..1] to I_Plant                  as _Plant                  on $projection.Plant = _Plant.Plant

  association [1..1] to I_Country                as _Country                on $projection.SupplierCountry = _Country.Country

  association [1..1] to I_Material               as _Material               on $projection.Material = _Material.Material
  
  association [1..1] to I_MaterialGroup          as _MaterialGroup          on $projection.MaterialGroup = _MaterialGroup.MaterialGroup


{
      /* Keys */
  key PurchaseOrder,
  key PurchaseOrderItem,
      //  key MaterialDocument,

      //  key MaterialDocumentItem,

      //  key MaterialDocumentYear,

      //  key AccountAssignmentNumber,



      /*Supplier*/
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption.labelElement: 'SupplierName'
      Supplier,

      @ObjectModel.foreignKey.association: '_Country'
      @Consumption.labelElement: 'CountryName'
      _Supplier.Country as SupplierCountry,

      /* Org Data*/
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      @Consumption.labelElement: 'PurchasingOrganizationName'
      PurchasingOrganization,

      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      @Consumption.labelElement: 'PurchasingGroupName'
      PurchasingGroup,

      CompanyCode,

      /* Purchasing Category*/
      PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory                 as PurchasingCategory,
      PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName,

      /* Dates */
      PurchaseOrderDate,
      Calendar.CalendarYear,
      Calendar.CalendarQuarter,
      Calendar.CalendarMonth,
      Calendar.CalendarWeek,

      /* Item Data */
      @ObjectModel.foreignKey.association: '_Material'
      Material,
      @ObjectModel.foreignKey.association:'_MaterialGroup'
      P_PurchaseOrderItemHistory1.MaterialGroup,

      @ObjectModel.foreignKey.association: '_Plant'
      @Consumption.labelElement: 'PlantName'
      Plant,

      @DefaultAggregation: #SUM
      DeliveryTime,

      @Semantics.currencyCode: true
      cast( $parameters.P_DisplayCurrency as displaycurrency )                           as DisplayCurrency,

      @Semantics.unitOfMeasure: true
      PurchaseOrderQuantityUnit,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      GoodsReceiptQty,

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      @DefaultAggregation: #SUM
      case when NonDeductibleInputTaxAmount = 0
            then GoodsReceiptAmountInDspCrcy
           else EffectiveAmount
      end as GoodsReceiptAmountInDspCrcy,                   //3200657


      @DefaultAggregation: #SUM
      DeliveryItem,

      @DefaultAggregation: #SUM
      cast( DeliveryTime * GoodsReceiptQty as abap.dec(15,2))                            as WeightedDeliveryTime,
      
      @DefaultAggregation: #SUM
      division(GoodsReceiptQty, WeightedReceiptQuantity, 3 ) as WeightedReceiptQuantity, //Temporary Solution


      _Material,
      _MaterialGroup                                          as _MaterialGroup,
      _Supplier,
      _Country,
      _Plant,
      _PurchasingOrganization,
      _PurchasingGroup

}
where
  GoodsReceiptQty > 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"I_SUPPLIER",
"P_PURCHASEORDERITEMHISTORY1"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/