C_ProjectBillingCustomerCard

@AbapCatalog: {
    sqlViewName: 'CPROJCUSTOMERCRD',
    compiler.compareFilter: true
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Project Billing - Customer Contact Card'

@ObjectModel.usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #L
}
@Search.searchable: true
@VDM: {
    viewType: #CONSUMPTION,
    private: false
}
@AbapCatalog.preserveKey:true
@Metadata.allowExtensions: true

@ObjectModel: {
     semanticKey: ['Customer'],
     representativeKey: 'Customer'
}


define view C_ProjectBillingCustomerCard
  as select from I_Customer as Customer
{
      @Semantics.contact.type: #ORGANIZATION
      @Search: {defaultSearchElement: true,fuzzinessThreshold: 0.85,ranking: #HIGH}
      @ObjectModel.text.element:  [ 'CustomerName' ]
  key Customer.Customer,


      @Semantics.name.fullName: true
      @Semantics.text: true
      Customer.CustomerName,

      @Semantics.text: true
      concat(concat_with_space(concat_with_space( concat_with_space( Customer._AddressRepresentation.HouseNumber, Customer.StreetName,1), Customer.CityName,1 ) ,Customer.Country,1), Customer.PostalCode) as CustAddressNumber,

      @UI.hidden: true
      Customer.AuthorizationGroup,

      @UI.hidden: true
      Customer.CustomerAccountGroup,


      -- ADDRESS

      @Semantics.address.street: true
      @Semantics.text: true
      Customer.StreetName,

      @Semantics.address.number: true
      Customer._AddressRepresentation.HouseNumber,

      @Semantics.address.city: true
      @Semantics.text: true
      @UI.fieldGroup: [{ position:'40', qualifier: 'CustomerFieldGroup'}]
      Customer.CityName,

      @Semantics.address.zipCode: true
      Customer.PostalCode,

      @Semantics.address.country:true
      Customer.Country,

      -- END ADDRESS


      @Semantics.telephone.type:  [ #WORK ]
      @Consumption.filter.hidden: true
      //@UI.fieldGroup: [{ position:'20', qualifier: 'CustomerFieldGroup'}]

      Customer._AddressRepresentation._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber                                                                                                          as PhoneNumber,


      @Semantics.telephone.type:  [ #CELL ]
      @Consumption.filter.hidden: true
      Customer._AddressRepresentation._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber                                                                                                          as MobilePhoneNumber,


      @EndUserText.label: 'Email'
      @Semantics.eMail: {
        type:  #WORK,
        address: true
      }
      @Consumption.filter.hidden: true
      //@UI.fieldGroup: [{ position:'30', qualifier: 'CustomerFieldGroup'}]

      Customer._AddressRepresentation._CurrentDfltEmailAddress.EmailAddress                                                                                                                                as EmailAddress,

      //Adding 10 fields for DCP 10+1 development

      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController1,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController2,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController3,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController4,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController5,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController6,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController7,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController8,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController9,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataController10,
      @UI.hidden: true
      @Consumption.hidden: true
      Customer.DataControllerSet


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESS_2",
"I_CUSTOMER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/