C_ProjSchedOperationGraph

@AbapCatalog.sqlViewName: 'COPERATIONGROVW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Operation Graph Overview'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions:true }

define view C_ProjSchedOperationGraph
  as select from I_NetworkActivityByInternalKey as NetworkActivity
  association [1..1] to I_NetworkActivityDatesQuantity as _NetworkActivityDatesQuantity on  $projection.OrderInternalBillOfOperations = _NetworkActivityDatesQuantity.ProjectNetworkInternalID
                                                                                        and $projection.NetworkActivityInternalID     = _NetworkActivityDatesQuantity.NetworkActivityInternalID

  association [0..1] to I_ProjSchedMaintOrderData      as _MaintenanceOrder             on  $projection.OrderInternalBillOfOperations = _MaintenanceOrder.OrderInternalBillOfOperations

  association [0..1] to C_ProjectShedMaintOrderGraph   as _WorkOrderGraphOverview       on  $projection.MaintenanceOrder = _WorkOrderGraphOverview.MaintenanceOrder
  association [0..1] to I_StatusObjectStatusBasic      as _ActivityConfirmed            on  $projection.NetworkActivityObject = _ActivityConfirmed.StatusObject
                                                                                        and _ActivityConfirmed.StatusCode     = 'I0009'
  association [0..1] to I_StatusObjectStatusBasic      as _ActivityPartiallyConfirmed   on  $projection.NetworkActivityObject      = _ActivityPartiallyConfirmed.StatusObject
                                                                                        and _ActivityPartiallyConfirmed.StatusCode = 'I0010'
  association [0..1] to I_OperationControlProfileText  as _OperationControlProfileText  on  $projection.OperationControlKey       = _OperationControlProfileText.OperationControlProfile
                                                                                        and _OperationControlProfileText.Language = $session.system_language
  association [0..1] to I_Plant                        as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_MaterialText                 as _AssemblyText                 on  $projection.Assembly   = _AssemblyText.Material
                                                                                        and _AssemblyText.Language = $session.system_language
  association [0..1] to I_EquipmentText                as _EquipmentText                on  $projection.Equipment   = _EquipmentText.Equipment
                                                                                        and _EquipmentText.Language = $session.system_language
  association [0..1] to I_FunctionalLocationLabel      as _FunctionalLocationLabel      on  $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
  association [0..1] to I_FunctionalLocationText       as _FunctionalLocationText       on  $projection.FunctionalLocation   = _FunctionalLocationText.FunctionalLocation
                                                                                        and _FunctionalLocationText.Language = $session.system_language
  association [0..*] to I_EAMProcessPhaseText          as _EAMProcessPhaseText          on  $projection.MaintOrdProcessPhaseCode = _EAMProcessPhaseText.EAMProcessPhaseCode
  association [0..*] to I_EAMProcessSubPhaseText       as _EAMProcessSubPhaseText       on  $projection.MaintOrdProcessSubPhaseCode = _EAMProcessSubPhaseText.EAMProcessSubPhaseCode

  association [0..*] to C_ProjectNetworkRelationship   as _Successor                    on  _Successor.PredecessorProjNtwkIntID = $projection.OrderInternalBillOfOperations
                                                                                        and _Successor.PredecessorNtwkActyIntID = $projection.NetworkActivityInternalID
  association [0..*] to C_ProjectNetworkRelationship   as _Predecessor                  on  _Predecessor.SuccessorProjNtwkIntID = $projection.OrderInternalBillOfOperations
                                                                                        and _Predecessor.SuccessorNtwkActyIntID = $projection.NetworkActivityInternalID
{
  key cast (NetworkActivity.ProjectNetworkInternalID as co_aufpl preserving type)                                                as OrderInternalBillOfOperations,

  key NetworkActivity.NetworkActivityInternalID                                                                                  as NetworkActivityInternalID,


      @ObjectModel.text.element: ['OrderDescription']
      @EndUserText.label: 'Order'
      _MaintenanceOrder.MaintenanceOrder                                                                                         as MaintenanceOrder,
      @ObjectModel.text.element: ['OperationDescription']
      @EndUserText.label: 'Operation'
      NetworkActivity.NetworkActivity                                                                                            as MaintenanceOrderOperation,
      @ObjectModel.text.element: ['WBSDescription']
      @EndUserText.label: 'WBS Element ID'
      _MaintenanceOrder._WBSElementData.WBSElementExternalID                                                                     as WBSElementExternalID,
      @Semantics.text: true
      @EndUserText.label: 'Operation Description'
      NetworkActivity.NetworkActivityDescription                                                                                 as OperationDescription,
      @Semantics.text: true
      @EndUserText.label: 'Order Name'
      _MaintenanceOrder.OrderDescription                                                                                         as OrderDescription,
      @Semantics.text: true
      @EndUserText.label: 'WBS Element Name'
      _MaintenanceOrder._WBSElementData.WBSDescription                                                                           as WBSDescription,
      @EndUserText.label: 'Order Type'
      @ObjectModel.text.element: ['MaintenanceOrderTypeName']
      _MaintenanceOrder.OrderType                                                                                                as OrderType,
      @EndUserText.label: 'Order Type Name'
      @Semantics.text: true
      _MaintenanceOrder._OrderType._Text[1:Language = $session.system_language].OrderTypeName                                    as MaintenanceOrderTypeName,
      @EndUserText.label: 'Fully Confirmed'
      cast( ( case when _ActivityConfirmed.StatusIsInactive = ' '
          then 'X'
          else ' '
          end ) as boole_d )                                                                                                     as ObjectIsConfirmed,
      @EndUserText.label: 'Partially Confirmed'
      cast( ( case when _ActivityPartiallyConfirmed.StatusIsInactive = ' '
          then 'X'
          else ' '
          end  ) as boole_d )                                                                                                    as ObjectIsPartiallyConfirmed,
      @EndUserText.label: 'Control Key'
      @ObjectModel.text.element: ['OperationControlProfileName']
      NetworkActivity.NetworkActivityControlProfile                                                                              as OperationControlKey,
      @Semantics.text: true
      cast ( _OperationControlProfileText.OperationControlProfileName as ps_s4_pph_steutxt )                                     as OperationControlProfileName,
      @EndUserText.label: 'Work Center'
      NetworkActivity._WorkCenter.WorkCenter                                                                                     as OperationWorkCenter,
      NetworkActivity._WorkCenter._Text[1:Language=$session.system_language].WorkCenterText                                      as WorkCenterText,
      @EndUserText.label: 'Plant'
      NetworkActivity.Plant                                                                                                      as Plant,
      _Plant.PlantName                                                                                                           as PlantName,
      @EndUserText.label: 'Assembly'
      @ObjectModel.text.element: ['AssemblyName']
      NetworkActivity.Assembly                                                                                                   as Assembly,
      @Semantics.text: true
      _AssemblyText.MaterialName                                                                                                 as AssemblyName,
      @EndUserText.label: 'Functional Location'
      NetworkActivity.FunctionalLocation                                                                                         as FunctionalLocation,
      @ObjectModel.text.element: ['FunctionalLocationName']
      _FunctionalLocationLabel.FunctionalLocationLabelName                                                                       as FunctionalLocationLabelName,
      @EndUserText.label: 'Functional Location'
      @Semantics.text: true
      _FunctionalLocationText.FunctionalLocationName                                                                             as FunctionalLocationName,
      @EndUserText.label: 'Equipment'
      @ObjectModel.text.element: ['EquipmentName']
      NetworkActivity.Equipment                                                                                                  as Equipment,
      @Semantics.text: true
      _EquipmentText.EquipmentName                                                                                               as EquipmentName,
      @EndUserText.label: 'Flagged for Deletion'
      NetworkActivity.IsMarkedForDeletion                                                                                        as IsMarkedForDeletion,
      @UI.hidden: true
      NetworkActivity.NetworkActivityObject                                                                                      as NetworkActivityObject,
      //Dates and work

      @EndUserText.label: 'Earliest Start Date'
      _NetworkActivityDatesQuantity.SchedldBasicEarliestStartDate                                                                as SchedldBasicEarliestStartDate,
      @EndUserText.label: 'Earliest Finish Date'
      _NetworkActivityDatesQuantity.SchedldBasicEarliestEndDate                                                                  as SchedldBasicEarliestEndDate,
      @EndUserText.label: 'Latest Start Date'
      _NetworkActivityDatesQuantity.SchedldBasicLatestStartDate                                                                  as SchedldBasicLatestStartDate,
      @EndUserText.label: 'Latest Finish Date'
      _NetworkActivityDatesQuantity.ScheduledBasicLatestEndDate                                                                  as ScheduledBasicLatestEndDate,
      @EndUserText.label: 'Duration'
      @Semantics.quantity.unitOfMeasure: 'StandardDurationUnit'
      _NetworkActivityDatesQuantity.StandardDuration                                                                             as StandardDuration,
      @Semantics.unitOfMeasure: true
      _NetworkActivityDatesQuantity.StandardDurationUnit                                                                         as StandardDurationUnit,
      @EndUserText.label: 'Actual Exec. Start Date'
      _NetworkActivityDatesQuantity.ActualStartDate                                                                              as ActualStartDate,
      @EndUserText.label: 'Actual Exec. Finish Date'
      _NetworkActivityDatesQuantity.ActualEndDate                                                                                as ActualEndDate,
      @EndUserText.label: 'Forecast Finish'
      _NetworkActivityDatesQuantity.ActyConfFcstdEndDate                                                                         as ActyConfFcstdEndDate,
      @EndUserText.label: 'Start Restriction'
      @ObjectModel.text.element: 'ActyBscStartDateConstraintText'
      _NetworkActivityDatesQuantity.ActyBscStartDateConstraintType                                                               as ActyBscStartDateConstraintType,
      @EndUserText.label: 'Start Restriction Text'
      @Semantics.text: true
      _NetworkActivityDatesQuantity._BscStartConstraintTypeText[1:Language = $session.system_language].StartConstraintTypeText   as ActyBscStartDateConstraintText,
      @EndUserText.label: 'End Restriction'
      @ObjectModel.text.element: 'ActyBscEndDateConstraintText'
      _NetworkActivityDatesQuantity.ActyBscEndDateConstraintType                                                                 as ActyBscEndDateConstraintType,
      @EndUserText.label: 'End Restriction Text'
      @Semantics.text: true
      _NetworkActivityDatesQuantity._BscFinishConstraintTypeText[1:Language = $session.system_language].FinishConstraintTypeText as ActyBscEndDateConstraintText,
      @EndUserText.label: 'Start Restriction Date'
      _NetworkActivityDatesQuantity.ConstraintDateForBscStartDate                                                                as ConstraintDateForBscStartDate,
      @EndUserText.label: 'End Restriction Date'
      _NetworkActivityDatesQuantity.ConstraintDateForBscEndDate                                                                  as ConstraintDateForBscEndDate,
      @EndUserText.label: 'Total Float'
      _NetworkActivityDatesQuantity.TotalFloatForBasicDates                                                                      as TotalFloatForBasicDates,
      @EndUserText.label: 'Free Float'
      _NetworkActivityDatesQuantity.BasicDatesFreeFloat                                                                          as BasicDatesFreeFloat,
      @EndUserText.label: 'Planned Work'
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      _NetworkActivityDatesQuantity.PlannedWorkQuantity                                                                          as PlannedWorkQuantity,
      @EndUserText.label: 'Actual Work'
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      _NetworkActivityDatesQuantity.ActualWorkQuantity                                                                           as ActualWorkQuantity,
      @EndUserText.label: 'Forecast Work'
      @Semantics.quantity.unitOfMeasure: 'NtwkActivityWorkQuantityUnit'
      _NetworkActivityDatesQuantity.ForecastedWorkQty                                                                            as ForecastedWorkQty,
      @Semantics.unitOfMeasure: true
      _NetworkActivityDatesQuantity.NtwkActivityWorkQuantityUnit                                                                 as NtwkActivityWorkQuantityUnit,
      cast( ''  as vsnmr_v )                                                                                                     as Version,
      //New 12.10.2021

      @EndUserText.label: 'Process Phase'
      @ObjectModel.text.element: ['EAMProcessPhaseCodeDesc']
      NetworkActivity.MaintOrdProcessPhaseCode,
      @EndUserText.label: 'Process Phase Description'
      @Semantics.text: true
      _EAMProcessPhaseText[1:Language = $session.system_language].EAMProcessPhaseCodeDesc                                        as EAMProcessPhaseCodeDesc,
      @EndUserText.label: 'Process Subphase'
      @ObjectModel.text.element: ['EAMProcessSubPhaseCodeDesc']
      NetworkActivity.MaintOrdProcessSubPhaseCode,
      @EndUserText.label: 'Process Subphase Description'
      @Semantics.text: true
      _EAMProcessSubPhaseText[1:Language = $session.system_language].EAMProcessSubPhaseCodeDesc                                  as EAMProcessSubPhaseCodeDesc,
      //End

      //Status

      @EndUserText.label: 'System Status'
      @ObjectModel: { virtualElement: true,
                      virtualElementCalculatedBy: 'ABAP:CL_PS_PROJ_OBJECT_STATUS_CALC' }
      cast ( '' as vdm_j_system_status_concat_t )                                                                                as ConcatenatedActiveSystStsName,
      @EndUserText.label: 'User Status'
      @ObjectModel: { virtualElement: true,
                      virtualElementCalculatedBy: 'ABAP:CL_PS_PROJ_OBJECT_STATUS_CALC' }
      cast ( '' as vdm_j_user_status_concat_t )                                                                                  as ConcatenatedActiveUserStsName,
      //Associations

      _NetworkActivityDatesQuantity,
      _MaintenanceOrder,
      _WorkOrderGraphOverview,
      _ActivityConfirmed,
      _ActivityPartiallyConfirmed,
      _EAMProcessPhaseText,
      _EAMProcessSubPhaseText,
      _Successor,
      _Predecessor
}
where
      NetworkActivity.NetworkActivityObject like 'OV%'
  and _MaintenanceOrder.MaintenanceOrder    is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EAMPROCESSPHASETEXT",
"I_EAMPROCESSSUBPHASETEXT",
"I_EQUIPMENTTEXT",
"I_FINISHCONSTRAINTTYPETEXT",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_MATERIALTEXT",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_OPERATIONCONTROLPROFILETEXT",
"I_ORDERTYPE",
"I_ORDERTYPETEXT",
"I_PLANT",
"I_PROJSCHEDMAINTORDERDATA",
"I_STARTCONSTRAINTTYPETEXT",
"I_STATUSOBJECTSTATUSBASIC",
"I_WBSELEMENTDATA_2",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"C_PROJECTNETWORKRELATIONSHIP",
"C_PROJECTSHEDMAINTORDERGRAPH",
"I_EAMPROCESSPHASETEXT",
"I_EAMPROCESSSUBPHASETEXT",
"I_EQUIPMENTTEXT",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_MATERIALTEXT",
"I_NETWORKACTIVITYDATESQUANTITY",
"I_OPERATIONCONTROLPROFILETEXT",
"I_PLANT",
"I_PROJSCHEDMAINTORDERDATA",
"I_STATUSOBJECTSTATUSBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/