C_ProductObjPgRetailPromotion

DDL: C_PRODUCTOBJPGRETAILPROMOTION SQL: CPRODOBJPGRTLPRM Type: view CONSUMPTION

Product Object Page - Retail Promotion

C_ProductObjPgRetailPromotion is a Consumption CDS View that provides data about "Product Object Page - Retail Promotion" in SAP S/4HANA. It reads from 1 data source (I_RetailPromotionByProduct) and exposes 21 fields with key fields Product, RetailPromotion. It has 1 association to related views.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
I_RetailPromotionByProduct I_RetailPromotionByProduct from

Associations (1)

CardinalityTargetAliasCondition
[1..1] C_ProductObjPg _ProductObjPg $projection.Product = _ProductObjPg.Product

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName CPRODOBJPGRTLPRM view
EndUserText.label Product Object Page - Retail Promotion view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

Fields (21)

KeyFieldSource TableSource FieldDescription
KEY Product Product
KEY RetailPromotion RetailPromotion
RetailPromotionName
RetailPromotionSalesFromDate _RetailPromotion RetailPromotionSalesFromDate Start
RetailPromotionSalesToDate _RetailPromotion RetailPromotionSalesToDate End
SalesPriceActivationStatus _RetailPromotion SalesPriceActivationStatus Sales Price Activation
SalesOrganization _RetailPromotion SalesOrganization
DistributionChannel _RetailPromotion DistributionChannel
PurchasingOrganization _RetailPromotion PurchasingOrganization
PurchasingGroup _RetailPromotion PurchasingGroup
RetailPromotionType _RetailPromotion RetailPromotionType
PromotionAnnouncementStatus _RetailPromotion PromotionAnnouncementStatus Promotion Announcement
_ProductObjPg _ProductObjPg
_RetailPromotion _RetailPromotion
_RtlPromnSalesPriceActvtnSts _RetailPromotion _RtlPromnSalesPriceActvtnSts
_RtlPromotionAnnouncementSts _RetailPromotion _RtlPromotionAnnouncementSts
_SalesOrganization _RetailPromotion _SalesOrganization
_DistributionChannel _RetailPromotion _DistributionChannel
_PurchasingOrganization _RetailPromotion _PurchasingOrganization
_PurchasingGroup _RetailPromotion _PurchasingGroup
_RetailPromotionType _RetailPromotion _RetailPromotionType 
@AbapCatalog.sqlViewName: 'CPRODOBJPGRTLPRM'
@EndUserText.label: 'Product Object Page - Retail Promotion'

@VDM.viewType: #CONSUMPTION
@AccessControl: {
    authorizationCheck: #CHECK
}
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey: ['Product', 'RetailPromotion'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
   }
}

@UI.presentationVariant.sortOrder: [{
    by: 'RetailPromotionSalesToDate',
    direction: #DESC
}, {
    by: 'RetailPromotionSalesFromDate',
    direction: #DESC
}]

define view C_ProductObjPgRetailPromotion
  as select from I_RetailPromotionByProduct
  association [1..1] to C_ProductObjPg as _ProductObjPg on $projection.Product = _ProductObjPg.Product
{
      @UI.hidden: true
  key Product,
      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_RetailPromotionStdVH',
                     element: 'RetailPromotion' }
        }]
      @Consumption.semanticObject: 'RetailPromotion'
      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['RetailPromotionName']
      @UI.lineItem: [{position: 10, importance: #HIGH}]
  key RetailPromotion,

      @UI.hidden: true
      _RetailPromotion._Text[1:Language=$session.system_language].RetailPromotionName,

      @EndUserText.label: 'Start'
      @UI.lineItem: [{position: 20, importance: #HIGH}]
      _RetailPromotion.RetailPromotionSalesFromDate,
      @EndUserText.label: 'End'
      @UI.lineItem: [{position: 30, importance: #MEDIUM}]
      _RetailPromotion.RetailPromotionSalesToDate,

      @EndUserText.label: 'Sales Price Activation'
      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 40, importance: #MEDIUM}]
      _RetailPromotion.SalesPriceActivationStatus,

      @UI.lineItem: [{position: 50, importance: #MEDIUM}]
      _RetailPromotion.SalesOrganization,

      @UI.lineItem: [{position: 60, importance: #MEDIUM}]
      _RetailPromotion.DistributionChannel,

      @UI.lineItem: [{position: 70, importance: #LOW}]
      _RetailPromotion.PurchasingOrganization,

      @UI.lineItem: [{position: 80, importance: #LOW}]
      _RetailPromotion.PurchasingGroup,

      @UI.lineItem: [{position: 90, importance: #MEDIUM}]
      _RetailPromotion.RetailPromotionType,

      @EndUserText.label: 'Promotion Announcement'
      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 100, importance: #LOW}]
      _RetailPromotion.PromotionAnnouncementStatus,

      _ProductObjPg,
      _RetailPromotion,
      _RetailPromotion._RtlPromnSalesPriceActvtnSts,
      _RetailPromotion._RtlPromotionAnnouncementSts,
      _RetailPromotion._SalesOrganization,
      _RetailPromotion._DistributionChannel,
      _RetailPromotion._PurchasingOrganization,
      _RetailPromotion._PurchasingGroup,
      _RetailPromotion._RetailPromotionType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RETAILPROMOTION",
"I_RETAILPROMOTIONBYPRODUCT",
"I_RETAILPROMOTIONT"
],
"ASSOCIATED":
[
"C_PRODUCTOBJPG",
"I_DISTRIBUTIONCHANNEL",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_RETAILPROMOTION",
"I_RETAILPROMOTIONTYPE",
"I_RTLPROMNSALESPRICEACTVTNSTS",
"I_RTLPROMOTIONANNOUNCEMENTSTS",
"I_SALESORGANIZATION"
],
"BASE":
[
"I_RETAILPROMOTION",
"I_RETAILPROMOTIONBYPRODUCT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More