C_ProductObjPgPurchaseOrder

@AbapCatalog.sqlViewName: 'CPRODOBJPGPRCHOR'
@EndUserText.label: 'Product Object Page - Purchase Order'

@VDM.viewType: #CONSUMPTION
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey: ['Product', 'PurchaseOrder'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
   }
}
@Consumption.semanticObject: 'PurchaseOrder'

@UI.presentationVariant.sortOrder: {
    by: 'PurchaseOrderDate',
    direction: #DESC
}

define view C_ProductObjPgPurchaseOrder
  as select from I_PurchaseOrderByProduct
  association [1..1] to C_ProductObjPg       as _ProductObjPg     on $projection.Product = _ProductObjPg.Product
  association [0..1] to E_PurchasingDocument as _PurchaseOrderExt on $projection.PurchaseOrder = _PurchaseOrderExt.PurchasingDocument
{
      @UI.hidden: true
  key Product,
      @Consumption.semanticObject: 'PurchaseOrder'
      @UI.lineItem: [{position: 10, importance: #HIGH}]
  key PurchaseOrder,

      @Consumption.semanticObject: 'Supplier'
      @ObjectModel.text.element: ['SupplierName']
      @UI.lineItem: [{position: 20, importance: #MEDIUM}]
      @Consumption: { valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier'} }] }
      _PurchaseOrder.Supplier,

      @UI.hidden: true
      _PurchaseOrder._Supplier.SupplierName,

      @ObjectModel.text.element: 'SupplyingPlantName'
      @EndUserText.quickInfo: 'Supplying Plant'
      @UI.lineItem: [{position: 30, importance: #MEDIUM}]
      _PurchaseOrder.SupplyingPlant,
      @UI.hidden: true
      _PurchaseOrder._SupplyingPlant.PlantName                                                                 as SupplyingPlantName,

      @EndUserText.label: 'Purchasing Organization'
      @UI.lineItem: [{position: 40, importance: #MEDIUM}]
      _PurchaseOrder.PurchasingOrganization,

      @ObjectModel.text.element: 'PurchaseOrderTypeName'
      @EndUserText: {
          label: 'Document Type',
          quickInfo: 'Purchasing Document Type'
      }
      @UI.lineItem: [{position: 50, importance: #MEDIUM}]
      _PurchaseOrder.PurchaseOrderType,
      @UI.hidden: true
      _PurchaseOrder._PurchaseOrderType._Text[1: Language=$session.system_language].PurchasingDocumentTypeName as PurchaseOrderTypeName,

      @EndUserText.label: 'Order Date'
      @UI.lineItem: [{position: 60, importance: #HIGH}]
      _PurchaseOrder.PurchaseOrderDate,

      @EndUserText.quickInfo: 'Document Currency'
      @UI.lineItem: [{position: 70, importance: #MEDIUM}]
      _PurchaseOrder.DocumentCurrency,

      @Consumption.hidden: true
      _PurchaseOrder.PurchasingGroup,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ProductObjPg,
      _PurchaseOrder,
      _Product,
      _PurchaseOrder._Supplier,
      _PurchaseOrder._PurchasingOrganization,
      _PurchaseOrder._DocumentCurrency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"I_PURCHASEORDER",
"I_PURCHASEORDERBYPRODUCT",
"I_PURCHASINGDOCUMENTTYPE",
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"C_PRODUCTOBJPG",
"E_PURCHASINGDOCUMENT",
"I_CURRENCY",
"I_MATERIAL",
"I_PURCHASEORDER",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[
"I_PURCHASEORDER",
"I_PURCHASEORDERBYPRODUCT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/