C_ProductObjPgAllocationTable

DDL: C_PRODUCTOBJPGALLOCATIONTABLE SQL: CPRODOBJPGALCTBL Type: view CONSUMPTION

Product Object Page - Allocation Table

C_ProductObjPgAllocationTable is a Consumption CDS View that provides data about "Product Object Page - Allocation Table" in SAP S/4HANA. It reads from 1 data source (I_AllocationTableByProduct) and exposes 11 fields with key fields Product, AllocationTable. It has 1 association to related views.

1 data source(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
I_AllocationTableByProduct I_AllocationTableByProduct from

Associations (1)

CardinalityTargetAliasCondition
[1..1] C_ProductObjPg _ProductObjPg $projection.Product = _ProductObjPg.Product

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CPRODOBJPGALCTBL view
EndUserText.label Product Object Page - Allocation Table view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
Consumption.semanticObject AllocationTable view
UI.presentationVariant.sortOrder.by DeliveryDate view
UI.presentationVariant.sortOrder.direction #DESC view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY Product Product
KEY AllocationTable AllocationTable
AllocationTableDescription _AllocationTable AllocationTableDescription
AllocTableActivityStatus _AllocationTable AllocTableActivityStatus
MaintenanceStatus _AllocationTable MaintenanceStatus
DeliveryDate
AllocationTableType _AllocationTable AllocationTableType
_ProductObjPg _ProductObjPg
_AllocTableActivityStatus _AllocationTable _AllocTableActivityStatus
_AllocTableMaintenanceStatus _AllocationTable _AllocTableMaintenanceStatus
_AllocationTableType _AllocationTable _AllocationTableType 
@AbapCatalog.sqlViewName: 'CPRODOBJPGALCTBL'
@EndUserText.label: 'Product Object Page - Allocation Table'

@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    semanticKey: ['Product', 'AllocationTable'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
   }
}

@Consumption.semanticObject: 'AllocationTable'

@UI.presentationVariant.sortOrder: {
    by: 'DeliveryDate',
    direction: #DESC
}

define view C_ProductObjPgAllocationTable
  as select from I_AllocationTableByProduct
  association [1..1] to C_ProductObjPg as _ProductObjPg on $projection.Product = _ProductObjPg.Product
{
      @UI.hidden: true
  key Product,

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_AllocationTableStdVH',
                     element: 'AllocationTable' }
        }]
      @Consumption.semanticObject: 'AllocationTable'
      @ObjectModel.text.element: 'AllocationTableDescription'
      @UI.textArrangement: #TEXT_LAST
      @UI.lineItem: [{position: 10, importance: #HIGH}]
  key AllocationTable,

      @UI.hidden: true
      _AllocationTable.AllocationTableDescription,

      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 20, importance: #MEDIUM}]
      _AllocationTable.AllocTableActivityStatus,

      @UI.textArrangement: #TEXT_ONLY
      @UI.lineItem: [{position: 30, importance: #MEDIUM}]
      _AllocationTable.MaintenanceStatus,

      @EndUserText: {
          label: 'Default Delivery Date',
          quickInfo: 'Default Delivery Date'
      }
      @UI.lineItem: [{position: 40, importance: #HIGH}]
      _AllocationTable._DefaultDeliveryPhase.DeliveryDate,

      @UI.lineItem: [{position: 50, importance: #MEDIUM}]
      _AllocationTable.AllocationTableType,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ProductObjPg,
      _AllocationTable._AllocTableActivityStatus,
      _AllocationTable._AllocTableMaintenanceStatus,
      _AllocationTable._AllocationTableType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCATIONTABLE",
"I_ALLOCATIONTABLEBYPRODUCT",
"I_ALLOCATIONTABLEDELIVERYPHASE"
],
"ASSOCIATED":
[
"C_PRODUCTOBJPG",
"I_ALLOCATIONTABLETYPE",
"I_ALLOCTABLEACTIVITYSTATUS",
"I_ALLOCTABLEMAINTENANCESTATUS"
],
"BASE":
[
"I_ALLOCATIONTABLE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More