C_ProdSubstnExclsnTP

@AccessControl: {
 authorizationCheck: #CHECK ,
  privilegedAssociations: [
    '_CreatedByUser',
    '_LastChangedByUser'
  ]
}
@EndUserText.label: 'Manage Exclusions - Products'
@ObjectModel: {
  representativeKey: 'MDSubstnUUID',
  semanticKey: [ 'Product'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M
  }
}
@Search.searchable: true
@VDM: {
  usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ],
  viewType: #CONSUMPTION
}
@Metadata.allowExtensions: true
define root view entity C_ProdSubstnExclsnTP
  provider contract transactional_query
  as projection on R_ProdSubstnExclsnTP
{
  key MDSubstnUUID,
      MDSubstnObjectType,

      @ObjectModel.text.element: ['ProductDescription']
      @Consumption: {
      semanticObject: 'Material',
       valueHelpDefinition: [{ entity: { name: 'I_ProductStdVH', element: 'Product' } }]
      }
      Product,
      _Product._Text.ProductName  as ProductDescription : localized,
      @ObjectModel.text.association: null
      _Product.Product            as Material,
      MDSubstnContextObjectType,

      @ObjectModel.text.element: ['PlantName']
      @Consumption: {
       valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
      }
      Plant,
      _Plant.PlantName,
      _Plant.Plant                as PlntFilterAnlytlMod,
      MDSubstnContextObjectType2,

      @ObjectModel.text.element: ['MDSubstnGroupDescription']
      @Consumption: {
       semanticObject: 'ProductSubstitutionGroup',
       valueHelpDefinition: [{ entity: { name: 'C_ProdSubstnGrpVH', element: 'MDSubstnGroup' },
                               additionalBinding: [{ localElement: 'MDSubstnVersionValue', element: 'MDSubstnVersionValue' }] }]
      }
      MDSubstnGroup,
      _Group._GroupText.MDSubstnGroupDescription        : localized,
      MDSubstnVersionValue,
      @Semantics.timeZoneReference: 'TimeZoneID'
      MDSubstnValidityStartDateTime,      
      MDSubstnValidityStartDate,
      MDSubstnValidityStartTime,
      @Semantics.timeZoneReference: 'TimeZoneID'
      MDSubstnValidityEndDateTime,
      MDSubstnValidityEndDate,
      MDSubstnValidityEndTime,

//      @ObjectModel.text.element: ['TimeZoneText']

      @Consumption: {
//        valueHelpDefinition: [{ entity: { name: 'I_TimeZone', element: 'TimeZoneID' } }]

        valueHelpDefinition: [{ entity: { name: 'C_MDSubstnTmznDfltIANACodeVH', element: 'TimeZoneIANACode' } }]
      }
      @Semantics.timeZone: true
      TimeZoneID,
      _TimeZone._TimeZoneText.TimeZoneText              : localized,

      @Consumption: {
            semanticObject: 'ProductSubstitutionReason',
            valueHelpDefinition: [{ entity: { name: 'C_ProdSubstnRsnVH', element: 'MDSubstnReason' } }]
          }
      @ObjectModel.text.element: ['MDSubstnReasonDescription']
      MDSubstnReason,
      _Reason._Text.MDSubstnReasonDescription           : localized,

      @ObjectModel.text.element: ['MDSubstnStatusDescription']
      @Consumption: {
       valueHelpDefinition: [{ entity: { name: 'I_MDSubstnSts', element: 'MDSubstnStatus' } }]
      }
      MDSubstnStatus,
      MDSubstnStatusCriticality,
      _Status._Text.MDSubstnStatusDescription           : localized,

      @Feature: 'SW:PROD_SUBSTN_ENABLE_ESPP'
      @Consumption.filter.selectionType: #SINGLE
      MDSubstnIsRlvtForATPProd,

      @Feature: 'SW:PROD_SUBSTN_ENABLE_ESPP'
      @Consumption.filter.selectionType: #SINGLE
      MDSubstnIsRelevantForESPP,

      @ObjectModel.text.element: ['CreatedByUserFullName']
      CreatedByUser,

      _CreatedByUser.FullName     as CreatedByUserFullName,
      CreationDateTime,

      @ObjectModel.text.element: ['LastChangedByUserFullName']
      LastChangedByUser,

      _LastChangedByUser.FullName as LastChangedByUserFullName,
      LastChangeDateTime,

      /* Associations */
      @Consumption.filter.hidden: true
      _MDObjectType,
      @Consumption.filter.hidden: true
      _ContextObjectTypeCode,
      @Consumption.filter.hidden: true
      _Product,
      @Consumption.filter.hidden: true
      _Plant,
      @Consumption.filter.hidden: true
      _ContextObjectTypeCode2,
      @Consumption.filter.hidden: true
      _Group,
      @Consumption.filter.hidden: true
      _TimeZone,
      @Consumption.filter.hidden: true
      _Reason,
      @Consumption.filter.hidden: true
      _Status,
      @Consumption.filter.hidden: true
      _CreatedByUser,
      @Consumption.filter.hidden: true
      _LastChangedByUser

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDSUBSTNGRP",
"I_MDSUBSTNGRPTEXT",
"I_MDSUBSTNRSN",
"I_MDSUBSTNRSNTEXT",
"I_MDSUBSTNSTS",
"I_MDSUBSTNSTSTEXT",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTTEXT",
"I_TIMEZONE",
"I_TIMEZONETEXT",
"I_USERCONTACTCARD",
"R_PRODSUBSTNEXCLSNTP"
],
"ASSOCIATED":
[
"I_MDSUBSTNGRP",
"I_MDSUBSTNRSN",
"I_MDSUBSTNSTS",
"I_PLANT",
"I_PRODUCT",
"I_SAPOBJECTTYPE",
"I_TIMEZONE",
"I_USERCONTACTCARD"
],
"BASE":
[
"R_PRODSUBSTNEXCLSNTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/