C_ProcessOrderObjPgOpr

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manufacturing Order Opr : Object Page'

@VDM.viewType: #CONSUMPTION

@ObjectModel.representativeKey: 'OrderIntBillOfOperationsItem'
@ObjectModel.semanticKey: ['ManufacturingOrder' , 'ManufacturingOrderSequence' , 'ManufacturingOrderOperation' , 'ManufacturingOrderSubOperation']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@UI.presentationVariant: [{sortOrder: [{by: 'ManufacturingOrderOperation', direction: #ASC}]}, {requestAtLeast: [ 'ProductionResourceInternalID' ]}]
@UI.headerInfo.typeName: 'Operation'
@UI.headerInfo.typeNamePlural: 'Operations'
define view entity C_ProcessOrderObjPgOpr
  as select from I_MfgOrderOperationDurn as ManufacturingOrderOperation
    inner join   I_OrderItem             as OrderItem on  OrderItem.OrderID   = ManufacturingOrderOperation.ManufacturingOrder
                                                      and OrderItem.OrderItem = '0001'                                               
{
       // Technical Key

       @UI.hidden: true
       @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key  ManufacturingOrderOperation.OrderInternalBillOfOperations,
       @UI.hidden: true
  key  ManufacturingOrderOperation.OrderIntBillOfOperationsItem,
       @UI.hidden: true
       // Semantical Key

       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
       ManufacturingOrderOperation.ManufacturingOrder,
       @UI.lineItem: [{position:10}]
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderOperation' } } ]
       cast(ManufacturingOrderOperation.ManufacturingOrderOperation as ck_vornr)                                                       as  ManufacturingOrderOperation,
       //ltrim(ManufacturingOrderOperation,'0')                                                      as  ManufacturingOrderOperation,

       @UI.lineItem: [{position:20}]
       @EndUserText.label:'Phase'
       ManufacturingOrderOperation.MfgOrderOperationIsPhase,
       @UI.hidden: true
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
       ManufacturingOrderOperation.ManufacturingOrderSequence, // Sequence,

       @UI.lineItem: [{position:30}]
       ManufacturingOrderOperation.MfgOrderOperationText, // OperationShortText

       @EndUserText.label:'Suboperation'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderSubOperation' } } ]
       cast(ManufacturingOrderOperation.ManufacturingOrderSubOperation as vornr)                                                       as  ManufacturingOrderSubOperation, // Operation,

       @ObjectModel.foreignKey.association: '_MfgOrderType'
       @UI.hidden
       ManufacturingOrderOperation.ManufacturingOrderType,
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
       ManufacturingOrderOperation.BusinessProcessEntryUnit,
       // Order header data

       @ObjectModel.foreignKey.association: '_MfgOrderCategory'
       @UI.hidden
       ManufacturingOrderOperation.ManufacturingOrderCategory,
       @UI.lineItem: [{position:40}]
       @ObjectModel.foreignKey.association: '_Material'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
       OrderItem.Material,
       @UI.lineItem: [{position:45}]
       cast(OrderItem._Material._Text[1:Language = $session.system_language ].MaterialName as maktx) as MaterialDescription, //MaterialDescription

       @EndUserText.label:'Resource Type Code'
       @ObjectModel.text.element: ['WorkCenterText']
       ManufacturingOrderOperation.WorkCenterTypeCode                                                                                  as  ProductionResourceType,
       @UI.hidden: true
       ManufacturingOrderOperation._WorkCenter._Text[1: Language=$session.system_language].WorkCenterText                              as  WorkCenterText,
       @Consumption.semanticObject: 'Resource'
       @UI.lineItem: [{ position: 50}]
       @EndUserText.label:'Resource'
       @UI.identification: [{type: #WITH_INTENT_BASED_NAVIGATION,dataAction: 'display'}]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_WorkCenterVH', element: 'WorkCenter'} }] 
       ManufacturingOrderOperation.WorkCenter,                     // WorkCenter,


       @Semantics.calendarItem.dtStart: true
       @UI.lineItem: [{position:60}]
       @EndUserText.label:'Earliest Execution Start Date'
       ManufacturingOrderOperation.OpErlstSchedldExecStrtDte,      // PlannedStartDate

       @UI.lineItem: [{position:70}]
       @EndUserText.label:'Earliest Execution Start Time'
       ManufacturingOrderOperation.OpErlstSchedldExecStrtTme,      // PlannedStartTime

       @Semantics.calendarItem.dtStart: true
       @UI.lineItem: [{position:80}]
       @EndUserText.label:'Earliest Execution End Date'
       ManufacturingOrderOperation.OpErlstSchedldExecEndDte,       // PlannedEndDate

       @UI.lineItem: [{position:90}]
       @EndUserText.label:'Earliest Execution End Time'
       ManufacturingOrderOperation.OpErlstSchedldExecEndTme,       // PlannedEndTime

       @Semantics.calendarItem.dtStart: true
       @EndUserText.label:'Actual Execution Start Date'
       ManufacturingOrderOperation.OpActualExecutionStartDate,     // StartDate,

       @EndUserText.label:'Actual Execution Start Time'
       ManufacturingOrderOperation.OpActualExecutionStartTime,     // StartTime,

       @Semantics.calendarItem.dtEnd: true
       @EndUserText.label:'Actual Execution End Date'
       ManufacturingOrderOperation.OpActualExecutionEndDate,       // EndDate,

       @EndUserText.label:'Actual Execution End Time'
       ManufacturingOrderOperation.OpActualExecutionEndTime,       // EndTime,

       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
       ManufacturingOrderOperation.OperationUnit,                  // OperationUnit,

       @Semantics.quantity.unitOfMeasure: 'OperationUnit'
       //@DefaultAggregation: #NONE

       ManufacturingOrderOperation.OpPlannedTotalQuantity,         // OperationQuantity,

       @Semantics.calendarItem.duration: true
       @EndUserText.label:'Scheduled Execution Duration'
       ManufacturingOrderOperation.ErlstSchedldExecDurnInWorkdays, // PlannedDuration,

       @Semantics.calendarItem.duration: true
       @EndUserText.label:'Actual Execution Duration'
       ManufacturingOrderOperation.OpActualExecutionDays                                                                               as  OpActualExecutionDays, // ActualDuration,

       ManufacturingOrderOperation.OpTotalConfirmedYieldQty, // Confirmed Quantity

       @UI.hidden: true
       ManufacturingOrderOperation.WorkCenterInternalID                                                                                as  ProductionResourceInternalID,

       OrderItem._Material,
       ManufacturingOrderOperation._MfgOrderType,
       ManufacturingOrderOperation._MfgOrderCategory,
       ManufacturingOrderOperation._MfgOrder,
       ManufacturingOrderOperation._MfgOrderSequence,
       ManufacturingOrderOperation._BusinessProcessEntryUnit,
       ManufacturingOrderOperation._OrdInternalBillOfOperations

}; 
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGORDEROPERATIONDURN",
"I_ORDERITEM",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDERCATEGORY",
"I_MFGORDERSEQUENCE",
"I_MFGORDERTYPE",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MFGORDEROPERATIONDURN",
"I_ORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/