C_ProcessOrderObjPgItem

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process Order Items'
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@Analytics: {dataCategory: #DIMENSION}
@ObjectModel.representativeKey: 'ManufacturingOrderItem'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderItem']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@UI.headerInfo.typeName: 'Item'
@UI.headerInfo.typeNamePlural: 'Items'
define view entity C_ProcessOrderObjPgItem
  as select from I_MfgOrderItem
  association [0..1] to I_StorageLocation as _StorageLocation on  $projection.ProductionPlant = _StorageLocation.Plant
                                                              and $projection.StorageLocation = _StorageLocation.StorageLocation
{
       //ITEMS

       @ObjectModel.foreignKey.association: '_MfgOrder'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
       @EndUserText.label: 'Process Order'
  key  ManufacturingOrder,
       @UI.lineItem: [{position:10}]
  key  ManufacturingOrderItem,         // ProductionOrderItem,

       @UI.hidden: true
       ProductionPlant,
       @Consumption.semanticObject: 'Material'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
       @UI.lineItem:[ {position: 20} ]
       @UI.identification:[ {type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display' } ]
       Material,                       // Material,

       @UI.lineItem: [{position:25}]
       cast( _Material._Text[1:Language = $session.system_language ].MaterialName as maktx) as MaterialName, //MaterialDescription    

       @UI.lineItem: [{position:30}]
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PlantVH', element: 'Plant' } }]
       MRPPlant,                       // PlanningPlant,

       @UI.lineItem: [{position:80}]
       MfgOrderItemActualDeliveryDate, // DeliveryDate,

       @Consumption.semanticObject: ''
       @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
       @UI.lineItem:[ {position: 50} ]
       MfgOrderItemPlannedTotalQty,    // TotalQuantity,

       @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
       @UI.lineItem: [{position:60}]
       MfgOrderItemPlannedScrapQty,    // ScrapQuantity,

       @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
       @UI.lineItem: [{position:70}]
       @EndUserText.label: 'Goods Receipt Quantity'
       MfgOrderItemGoodsReceiptQty,    // ReceiptQuantity,

       @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
       MfgOrderItemActualDeviationQty, // ExpectedVariance,

       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
       ProductionUnit,
       @UI.hidden: true              // Unit of Measure

       @ObjectModel.foreignKey.association: '_MRPArea'
       MRPArea,
       @UI.hidden: true
       StorageLocation,
       @UI.hidden: true
       ManufacturingOrderType,
       @UI.hidden: true
       ManufacturingOrderCategory,
       @UI.lineItem: [{position:40}]
       MfgOrderItemPlndDeliveryDate,
       _MRPArea,
       _ProductionPlant,
       _Material,
       _MfgOrder,
       _MRPPlant,
       _StorageLocation
};   
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGORDERITEM"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MRPAREA",
"I_PLANT",
"I_STORAGELOCATION"
],
"BASE":
[
"I_MFGORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/