C_ProbSolvingProcExect

@AbapCatalog.sqlViewName: 'CPRSOLPROCEXCT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard']

@EndUserText.label: 'Problem-Solving Process'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M, 
        serviceQuality: #B },
    representativeKey: 'ProbSolvingProc',
    semanticKey:  [ 'ProbSolvingProc' ],

// Begin Draft 2.0

    compositionRoot: true,
    transactionalProcessingDelegated:true,
    draftEnabled:  true,
    createEnabled: false,
    updateEnabled: 'EXTERNAL_CALCULATION',
    deleteEnabled: true 
}

@Metadata.allowExtensions: true

define view C_ProbSolvingProcExect as select from I_ProbSolvingProcTP as _ProbSolvingProc

//=== child nodes

//===== defect reference

    association [0..*] to C_ProbSolvingProcDefectRef as _ProbSolvingProcDefectRef on $projection.ProbSolvingProc = _ProbSolvingProcDefectRef.ProbSolvingProc                                                                                   
//===== process step

    association [0..*] to C_ProbSolvingProcStepExect as _ProbSolvingProcStepExect on $projection.ProbSolvingProc = _ProbSolvingProcStepExect.ProbSolvingProc
//===== participants 

    association [0..*] to C_ProbSolvingProcPrtcpnt   as _ProbSolvingProcPrtcpnt   on $projection.ProbSolvingProc = _ProbSolvingProcPrtcpnt.ProbSolvingProc
//===== Problem Description Reference

    association [0..1] to C_ProbSolvingProcProbDesc  as _ProbSolvingProcProbDesc  on $projection.ProbSolvingProc = _ProbSolvingProcProbDesc.ProbSolvingProc
//===== Causes 

    association [0..*] to C_ProbSolvingProcCause     as _ProbSolvingProcCause     on $projection.ProbSolvingProc = _ProbSolvingProcCause.ProbSolvingProc
    association [0..*] to C_ProbSolvingProcCauseDsp  as _ProbSolvingProcCauseDsp  on $projection.ProbSolvingProc = _ProbSolvingProcCauseDsp.ProbSolvingProc
//===== Assessment

    association [0..1] to C_ProbSolvingProcAssmt     as _ProbSolvingProcAssmt     on $projection.ProbSolvingProc = _ProbSolvingProcAssmt.ProbSolvingProc

//==== Primary Defect Reference

    association [1..1] to C_ProbSolvingProcDefectRef as _ProbSolvingProcPrimaryDefRef on $projection.ProbSolvingProc = _ProbSolvingProcPrimaryDefRef.ProbSolvingProc
                                                                                      and _ProbSolvingProcPrimaryDefRef.DefectIsBaseOfProbSolvingProc = 'X'

    association [0..1] to I_ProductText as _ProductText on  $projection.Material = _ProductText.Product and
                                                            _ProductText.Language = $session.system_language
{

//=== key fields 

    key _ProbSolvingProc.ProbSolvingProc,
    
//=== data fields

        _ProbSolvingProc.ProbSolvingProcDesc,
        _ProbSolvingProc.ProbSolvingProcType,
       
        @ObjectModel.text.element: ['ProductName']
        @Consumption: {
                valueHelpDefinition: [ 
                            { entity:  { name:    'I_ProductVH',
                                         element: 'Product' }
                            }]   
        }
//        @ObjectModel.readOnly: true

        //UX Inc

        @Consumption.semanticObject: 'Material'
        _ProbSolvingProc.Material,
        
        @ObjectModel.readOnly: true
        @Consumption.filter.hidden: true
        _ProductText.ProductName,
        
        @Consumption: {
                valueHelpDefinition: [ 
                            { entity:  { name:    'I_PlantStdVH',
                                         element: 'Plant' }
                            }],
                semanticObject: 'Plant'  
        }
        _ProbSolvingProc.Plant,
        
//=== status

        _ProbSolvingProc.ProbSolvingProcLifecycleStatus,
        
        @Consumption.filter.hidden: true
        _ProbSolvingProc.ProbSolvingProcTsksArchivedSts,        

//=== administrative data

        @ObjectModel.readOnly: true
        @ObjectModel.foreignKey.association: [ { exclude } ] 
        _ProbSolvingProc.CreatedByUser,
        
        @ObjectModel.readOnly: true
        _ProbSolvingProc.ProbSolvingProcCreatedDateTime,        
        
        @ObjectModel.readOnly: true
        @ObjectModel.foreignKey.association: [ { exclude } ] 
        _ProbSolvingProc.LastChangedByUser,
        
        @ObjectModel.readOnly: true        
        _ProbSolvingProc.ProbSolvingProcLastChgdDteTme,

        @ObjectModel.readOnly: true        
        _ProbSolvingProc.ChangedDateTime,
        @ObjectModel.readOnly: true
        @Consumption.filter.hidden: true
        _ProbSolvingProc.MasterLanguage,

        @ObjectModel.readOnly: true
        @Consumption.filter.hidden: true
        _ProbSolvingProcPrimaryDefRef.Defect,
        @ObjectModel.readOnly: true
        @Consumption.filter.hidden: true
        _ProbSolvingProcPrimaryDefRef.DefectText,
    
//=== exposed associations

        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcDefectRef,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcStepExect,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcPrtcpnt,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcCause,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        _ProbSolvingProcProbDesc,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcCauseDsp,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
        @Consumption.filter.hidden: true
        _ProbSolvingProcAssmt,

        _ProbSolvingProcPrimaryDefRef,
        --@Consumption.filter.hidden: true
        --_ProbSolvingProc._Product,
        @Consumption.filter.hidden: true
        _Plant,
        @Consumption.filter.hidden: true
        _ProbSolvingProcLfcycSts,
        @Consumption.filter.hidden: true
        _ProbSolvingProc._CreatedByUserContactCard,
        @Consumption.filter.hidden: true
        _ProbSolvingProc._LastChangedByUserContactCard,
        @Consumption.filter.hidden: true
        _ProbSolvingProc._ProbSolvingProcType

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PROBSOLVINGPROCDEFECTREF",
"I_PROBSOLVINGPROCTP",
"I_PRODUCTTEXT"
],
"ASSOCIATED":
[
"C_PROBSOLVINGPROCASSMT",
"C_PROBSOLVINGPROCCAUSE",
"C_PROBSOLVINGPROCCAUSEDSP",
"C_PROBSOLVINGPROCDEFECTREF",
"C_PROBSOLVINGPROCPROBDESC",
"C_PROBSOLVINGPROCPRTCPNT",
"C_PROBSOLVINGPROCSTEPEXECT",
"I_PLANT",
"I_PROBSOLVINGPROCLFCYCSTS",
"I_PROBSOLVINGPROCTYPE",
"I_PRODUCTTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_PROBSOLVINGPROCTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/