C_PrmtHbRpldPurReqnItmAprvEml

@AbapCatalog.sqlViewName: 'CPURRQNITAPREML'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Purchase Requisition Itm Details for WF Approval Email'

@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: #OUTPUT_EMAIL_DATA_PROVIDER
@Metadata.ignorePropagatedAnnotations:true

define view C_PrmtHbRpldPurReqnItmAprvEml
  as select from            I_WorkflowTask               as _Workflowtask

    inner join I_WorkflowTaskApplObject     as _WorkflowTaskApplObject  on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                                     and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                                     and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'PrmtHbRpldPurchaseReqnItem'
                                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'

    left outer to one join  I_PrmtHbRpldPurReqnItemAPI01 as _PurchaseRequisitionItem on  _PurchaseRequisitionItem.ProcmtHubPurchaseRequisition = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey1
                                                                                     and _PurchaseRequisitionItem.ProcmtHubPurRequisitionItem  = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey2

    left outer to one join  I_User                       as _User                    on _User.UserID = _PurchaseRequisitionItem.ProcmtHubCreatedByUser
    left outer to one join  I_Supplier                   as _Supplier                on _Supplier.Supplier = _PurchaseRequisitionItem.ProcmtHubSupplier

{
  key _Workflowtask.WorkflowTaskInternalID,

      _PurchaseRequisitionItem.ProcmtHubPurchaseRequisition                                                         as ProcmtHubPurchaseRequisition,

      _PurchaseRequisitionItem.ProcmtHubPurRequisitionItem                                                          as ProcmtHubPurRequisitionItem,

      _PurchaseRequisitionItem.ProcmtHubPurRequisitionType                                                          as ProcmtHubPurRequisitionType,

      _PurchaseRequisitionItem.ProcurementHubSourceSystem                                                           as ProcurementHubSourceSystem,

      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as PrmtHbWrkflwTskCrtnUTCDte,

      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as PrmtHbWrkflwTskCrtnUTCTme,

      cast(tstmp_to_dats( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_led )    as PrmtHbWrkflwTskDuUTCDte,

      cast(tstmp_to_tims( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_let )    as PrmtHbWrkflwTskDuUTCTme,

      _PurchaseRequisitionItem.ProcmtHubSupplier,

      _User.UserDescription                                                                                         as CreatedByUserDescription,

      _Supplier.SupplierName,
      
      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReason,
      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReasonText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRMTHBRPLDPURREQNITEMAPI01",
"I_SUPPLIER",
"I_USER",
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKDUEDATE",
"I_WORKFLOWTASKRESULT",
"I_WORKFLOWTASKRESULTREASON",
"I_WORKFLOWTASKRESULTREASONTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/