C_PrmtHbRpldPurOrdApprvlEml

@AbapCatalog.sqlViewName: 'CPRHBRPLPOAPREML'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'PrmtHb Rpld PO Details for Workflow Approval Email'

@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: #OUTPUT_EMAIL_DATA_PROVIDER
@Metadata.ignorePropagatedAnnotations:true

define view C_PrmtHbRpldPurOrdApprvlEml
  as select from            I_WorkflowTask            as _Workflowtask

    left outer to many join I_WorkflowTaskApplObject  as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                                 and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                                 and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'PrmtHbRpldPurchaseOrder'
                                                                                 and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'

    left outer to one join  I_ProcmtHubPurOrdHdrAPI01 as _PurchaseOrder          on _PurchaseOrder.PurchaseOrder = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey1

{
  key _Workflowtask.WorkflowTaskInternalID,

      cast(substring(_WorkflowTaskApplObject.TechnicalWrkflwObject, 1 , 10 ) as ebeln )                             as PurchaseOrder,

      _PurchaseOrder.PurchaseOrderType                                                                              as PurchaseOrderType,
      
      _PurchaseOrder.ExtSourceSystem                                                                                as ExtSourceSystem,

      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as PrmtHbWrkflwTskCrtnUTCDte,

      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as PrmtHbWrkflwTskCrtnUTCTme,

      cast(tstmp_to_dats( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_led )    as PrmtHbWrkflwTskDuUTCDte,

      cast(tstmp_to_tims( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_let )    as PrmtHbWrkflwTskDuUTCTme,
      
      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1: Language = $session.system_language].WorkflowTaskResultReasonText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROCMTHUBPURORDHDRAPI01",
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT",
"I_WORKFLOWTASKDUEDATE",
"I_WORKFLOWTASKRESULT",
"I_WORKFLOWTASKRESULTREASON",
"I_WORKFLOWTASKRESULTREASONTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/